A_EnterpriseProject_2

//// Version 2 of the A_ENTERPRISEPROJECT - for C4P Harmonization project

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@ObjectModel: {

    usageType: {
      dataClass:       #MASTER,
      serviceQuality:  #C,
      sizeCategory:    #XL
    }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Project'
@OData.entitySet.name : 'A_EnterpriseProject'
define root view entity A_EnterpriseProject_2
  provider contract transactional_query
  as projection on I_EnterpriseProjectTP_2 as EnterpriseProject
  association [1..1] to  E_PPM_Project  as _ProjectHeaderExtension on $projection.ProjectUUID = _ProjectHeaderExtension.ProjectUUID
  association [1..1] to E_PPM_EngagementProject        as _EngagementProjectExtension on $projection.ProjectUUID = _EngagementProjectExtension.ProjectUUID
{
  key ProjectUUID,
      @Consumption.hidden: true
      ProjectSummaryTaskUUID,
      ProjectInternalID,
      @ObjectModel.text.element: ['ProjectDescription']
      Project,
      @Consumption.hidden: true
      ProjectCategory,
      @Semantics.text: true      
      ProjectDescription,
      //CE2202 CODELISTS SOTs reference for  'ProjectType'

       @ObjectModel.sapObjectNodeTypeReference: 'ProjectType'
      EnterpriseProjectType,
      @ObjectModel.sapObjectNodeTypeReference: 'EnterpriseProjectPriority'
      PriorityCode,
      ProjectStartDate,
      ProjectEndDate,
      ActualStartDate,
      ActualEndDate,  
      //2008 C4P Harmonization Start

      CustomerUUID,    
      EnterpriseProjectServiceOrg,
      EntProjectIsConfidential,
      RestrictedTimePosting,      
      @ObjectModel.sapObjectNodeTypeReference: 'EntProjectProcessingStatus'
      ProcessingStatus,
      ResponsibleCostCenter,
      ProfitCenter,
      //CE2202 CODELISTS SONT reference for  'ProjectProfileCode'

      @ObjectModel.sapObjectNodeTypeReference: 'ProjectProfileCode'
      ProjectProfileCode,
      FunctionalArea,
      CompanyCode,
      ControllingArea,
      Plant,
      Location,
      TaxJurisdiction,
      ProjectCurrency,
      //CE2202 CODELISTS SONT reference for  'BdgtAvailabilityControlProfile'

      @ObjectModel.sapObjectNodeTypeReference: 'BdgtAvailabilityControlProfile'
      AvailabilityControlProfile,
      AvailabilityControlIsActive,
      FunctionalLocation,
      IsBillingRelevant,
      InvestmentProfile,
      LastChangeDateTime,
      ProjectLastChangedDateTime,
      LastChangedByUser,
      //2102 SD EPPM N:1 flag

      EntProjIsMultiSlsOrdItmsEnbld,
      //CE2308 RA Key Changes

      ResultAnalysisInternalID,
      CostingSheet,

      _EnterpriseProjectElement : redirected to composition child A_EnterpriseProjectElement_2,
      _EnterpriseProjectJVA     : redirected to composition child A_EnterpriseProjectJVA_2,
      _EntProjectPublicSector   : redirected to composition child A_EntProjectPublicSector_2,
      _EntProjBlkFunc           : redirected to composition child A_EnterpriseProjBlkFunc_2,
      _EntProjRole              : redirected to composition child A_EnterpriseProjectRole,
      _EntProjTeamMember        : redirected to composition child A_EnterpriseProjectTeamMember,
      @Consumption.hidden:true
      _EnterpriseProjectForUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENTERPRISEPROJECTTP_2"
],
"ASSOCIATED":
[
"A_ENTERPRISEPROJBLKFUNC_2",
"A_ENTERPRISEPROJECTELEMENT_2",
"A_ENTERPRISEPROJECTJVA_2",
"A_ENTERPRISEPROJECTROLE",
"A_ENTERPRISEPROJECTTEAMMEMBER",
"A_ENTPROJECTPUBLICSECTOR_2",
"I_ENTERPRISEPROJECTELEMENTTP_2",
"I_ENTERPRISEPROJECTFORUSER",
"I_ENTERPRISEPROJECTJVATP_2",
"I_ENTPROJECTPUBLICSECTORTP_2",
"R_ENTERPRISEPROJECTROLETP",
"R_ENTPROJECTBLOCKFUNCTIONTP_2",
"R_ENTPROJECTTEAMMEMBERTP"
],
"BASE":
[
"I_ENTERPRISEPROJECTTP_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/