A_DocumentInfoRecordCharc

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ANGCDIRCLFN3'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Classification Characteristics'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@Consumption.filter.businessDate.at: true
define view A_DocumentInfoRecordCharc 
  with parameters  
    @Consumption.hidden: true
    @Semantics.businessDate.at: true
    P_KeyDate:sydate
  as select from I_ClfnObjectCharcForKeyDate(P_KeyDate: $parameters.P_KeyDate) as Characteristics
    join A_DocumentInfoRecord as DocumentInfoRecord on
      Characteristics.ClfnObjectID = DocumentInfoRecord.DocumentInfoRecord
  
    association [1..1] to A_DocumentInfoRecord as _DocumentInfoRecord on
      $projection.DocumentInfoRecordDocType = _DocumentInfoRecord.DocumentInfoRecordDocType and
      $projection.DocumentInfoRecordDocNumber = _DocumentInfoRecord.DocumentInfoRecordDocNumber and
      $projection.DocumentInfoRecordDocVersion = _DocumentInfoRecord.DocumentInfoRecordDocVersion and
      $projection.DocumentInfoRecordDocPart = _DocumentInfoRecord.DocumentInfoRecordDocPart
    association [0..*] to A_DocumentInfoRecordCharcValue as _Valuation on
      $projection.DocumentInfoRecordDocType = _Valuation.DocumentInfoRecordDocType and
      $projection.DocumentInfoRecordDocNumber = _Valuation.DocumentInfoRecordDocNumber and
      $projection.DocumentInfoRecordDocVersion = _Valuation.DocumentInfoRecordDocVersion and
      $projection.DocumentInfoRecordDocPart = _Valuation.DocumentInfoRecordDocPart and
      $projection.CharcInternalID = _Valuation.CharcInternalID and
      $projection.ClassType = _Valuation.ClassType
    association [1..*] to A_DocumentInfoRecordClassCharc as _ClassCharacteristics on
      $projection.DocumentInfoRecordDocType = _ClassCharacteristics.DocumentInfoRecordDocType and
      $projection.DocumentInfoRecordDocNumber = _ClassCharacteristics.DocumentInfoRecordDocNumber and
      $projection.DocumentInfoRecordDocVersion = _ClassCharacteristics.DocumentInfoRecordDocVersion and
      $projection.DocumentInfoRecordDocPart = _ClassCharacteristics.DocumentInfoRecordDocPart and
      $projection.CharcInternalID = _ClassCharacteristics.CharcInternalID and
      $projection.ClassType = _ClassCharacteristics.ClassType
  {
    key DocumentInfoRecord.DocumentInfoRecordDocType,
    key DocumentInfoRecord.DocumentInfoRecordDocNumber,
    key DocumentInfoRecord.DocumentInfoRecordDocVersion,
    key DocumentInfoRecord.DocumentInfoRecordDocPart,
    key CharcInternalID,
    key ClassType,
    
    $parameters.P_KeyDate as KeyDate,
    
    @Consumption.hidden: true
    _Characteristic(P_KeyDate: $parameters.P_KeyDate).CharcMaintAuthGrp,
    
    @Consumption.filter.businessDate.at: true
    _Valuation,
    _DocumentInfoRecord,
    _ClassCharacteristics
  }
    where
      ClfnObjectTable = 'DRAW' and
      ClfnObjectType = 'O'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"A_DOCUMENTINFORECORD",
"I_CLFNCHARACTERISTICFORKEYDATE",
"I_CLFNOBJECTCHARCFORKEYDATE"
],
"ASSOCIATED":
[
"A_DOCUMENTINFORECORD",
"A_DOCUMENTINFORECORDCHARCVALUE",
"A_DOCUMENTINFORECORDCLASSCHARC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/