A_DisputeCaseAsProcessor

@EndUserText: { label: 'Dispute Cases As Processor' }
@ObjectModel: { representativeKey: 'DisputeCaseUUID',
                semanticKey:       [ 'CaseID',
                                     'Customer',
                                     'CompanyCode' ],
                usageType:         { dataClass: #TRANSACTIONAL,
                                     sizeCategory: #L,
                                     serviceQuality: #A } }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@VDM: { viewType: #CONSUMPTION,
        lifecycle: { contract: { type: #PUBLIC_REMOTE_API } },
        usage:    { type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] } }
@Metadata: { ignorePropagatedAnnotations: true }

define root view entity A_DisputeCaseAsProcessor
  provider contract transactional_query
  as projection on R_DisputeCaseTP as DisputeCase

  // VDM Associations

//  association to A_Customer as _Customer on $projection.Customer = _Customer.Customer


{

          // VDM Fields

  key     DisputeCaseUUID,
          DisputeCaseCoordinator,
          DisputeCaseRootCause,
          CaseProcessingDeadlineDate,

          @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
          OriginalAmount,

          @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
          DisputedAmount,

          @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
          PaidAmount,

          @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
          CreditedAmount,

          @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
          WriteOffAmount,

          @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
          ManuallyClearedAmount,

          @Semantics: { currencyCode: true }
          DisputeCaseCurrency,

          @Semantics: { amount: { currencyCode: 'CustomerDisputedCurrency' } }
          CustomerDisputedAmount,

          @Semantics: { currencyCode: true }
          CustomerDisputedCurrency,

          ContactPerson,
          ContactPersonName,
          ContactPersonEmailAddress,
          ContactPersonPhoneNumber,
          ContactPersonFaxNumber,
          ContactPersonFaxCountry,
          Customer,
          CompanyCode,
          DisputeCaseExternalApplication,
          CaseType,
          CaseID,
          CaseExternalReference,
          CaseCreatedBy,
          CaseCreatedOn,
          CaseLastChangedBy,
          CaseLastChangedOn,
          CaseClosedBy,
          CaseClosedTime,
          CasePlannedCloseDate,
          CaseProcessor,
          CaseResponsible,
          CaseTitle,
          CaseEscalationReason,
          CaseCategory,
          CasePriority,
          CaseAuthorizationLevel,
          CaseStatusProfile,
          CaseStatus,
          CaseSystemStatus,
          CaseReason,
          _CaseTypes.CaseAttributeProfile as DisputeCaseAttributeProfile,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_DISPUTE_VE' }
  virtual BusinessPartner : bu_partner,

          // VDM Associations

          @Consumption.hidden: true          
          _Customer


}

where
      CaseProcessor = $session.user
  and CaseSystemStatus != '003'
  and CaseSystemStatus != '007'
  and CaseSystemStatus != '008'
  and CaseSystemStatus != '009'
  and CaseSystemStatus != '013'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CASETYPES",
"R_DISPUTECASETP"
],
"ASSOCIATED":
[
"I_CUSTOMER"
],
"BASE":
[
"R_DISPUTECASETP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/