A_DebitMemoRequest

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Debit Memo Request Header'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ADEBITMEMOREQ',
    preserveKey: true,
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'Debitmemorequest',
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_DebitMemoRequest
  as select from I_DebitMemoRequest as DebitMemoRequest

  association [0..*] to A_DebitMemoRequestItem  as _Item           on _Item.DebitMemoRequest = $projection.DebitMemoRequest

  association [0..*] to A_DebitMemoReqPartner   as _Partner        on _Partner.DebitMemoRequest = $projection.DebitMemoRequest

  association [0..*] to A_DebitMemoReqPrcgElmnt as _PricingElement on _PricingElement.DebitMemoRequest = $projection.DebitMemoRequest
  
  association [0..*] to A_DebitMemoReqText as _Text on _Text.DebitMemoRequest = $projection.DebitMemoRequest
  association [0..*] to A_DebitMemoReqSubsqntProcFlow    as _SubsequentProcFlowDoc  on _SubsequentProcFlowDoc.DebitMemoRequest = $projection.DebitMemoRequest

  //Extensibility

  association [0..1] to E_SalesDocumentBasic    as _Extension      on $projection.DebitMemoRequest = _Extension.SalesDocument

{

  key DebitMemoRequest,
  
      
      DebitMemoRequestType,

      SalesOrganization,
      DistributionChannel,
      OrganizationDivision,

      SalesGroup,
      SalesOffice,
      SalesDistrict,

      SoldToParty,

      @ObjectModel.readOnly: true
      CreationDate,

      @ObjectModel.readOnly: true
      CreatedByUser,

      @ObjectModel.readOnly: true
      LastChangeDate,

      @ObjectModel.readOnly: true
      case tstmp_is_valid(LastChangeDateTime)
        when 0 then cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else LastChangeDateTime
      end as LastChangeDateTime,

      PurchaseOrderByCustomer,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchaseOrderTypeByCustomer'
      CustomerPurchaseOrderType,
      CustomerPurchaseOrderDate,

      DebitMemoRequestDate,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      @Semantics.currencyCode: true
      TransactionCurrency,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
      SDDocumentReason,
      PricingDate,
      CustomerTaxClassification1,
      CustomerTaxClassification2,
      CustomerTaxClassification3,
      CustomerTaxClassification4,
      CustomerTaxClassification5,
      CustomerTaxClassification6,
      CustomerTaxClassification7,
      CustomerTaxClassification8,
      CustomerTaxClassification9, 
      
      @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
      HeaderBillingBlockReason,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      IncotermsVersion,
      CustomerPaymentTerms,
      PaymentMethod,

      BillingDocumentDate,
      ServicesRenderedDate,

      ReferenceSDDocument,
      
      @ObjectModel.readOnly: true
      ReferenceSDDocumentCategory,

      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDProcessStatus'
      @ObjectModel.readOnly: true
      OverallSDProcessStatus,

      @ObjectModel.sapObjectNodeTypeReference: 'TotalCreditCheckStatus'
      @ObjectModel.readOnly: true
      TotalCreditCheckStatus,

      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocumentRejectionSts'
      @ObjectModel.readOnly: true
      OverallSDDocumentRejectionSts,

      @ObjectModel.sapObjectNodeTypeReference: 'OverallOrdReltdBillgStatus'
      @ObjectModel.readOnly: true
      OverallOrdReltdBillgStatus,
      
      AccountingDocExternalReference,
      AssignmentReference,
      // Expose own associations

      _Item,
      _Partner,
      _PricingElement,
      _Text,
      _SubsequentProcFlowDoc
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DEBITMEMOREQUEST"
],
"ASSOCIATED":
[
"A_DEBITMEMOREQPARTNER",
"A_DEBITMEMOREQPRCGELMNT",
"A_DEBITMEMOREQSUBSQNTPROCFLOW",
"A_DEBITMEMOREQTEXT",
"A_DEBITMEMOREQUESTITEM",
"E_SALESDOCUMENTBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/