A_CustomField

@AbapCatalog.sqlViewName: 'ACUSTOMFIELD'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED // TODO: Authorization check?

@EndUserText.label: 'Custom Field'
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

define view A_CustomField
  as select from cfd_w_rep                            as Header
  inner join P_CustomFieldLatestVersion               as _LatestVersion          on  _LatestVersion.name              = Header.name
  inner join P_CustomFieldStatus                      as _Status                 on  _Status.name                     = Header.name      
  inner join cfd_w_rep_bus                            as _PrimaryBusinessContext on  _PrimaryBusinessContext.name     = Header.name 
                                                                                 and _PrimaryBusinessContext.version  = Header.version
                                                                                 and _PrimaryBusinessContext.is_added = ''
  inner join tadir                                    as _MasterLanguage         on  _MasterLanguage.pgmid            = 'R3TR'
                                                                                 and _MasterLanguage.object           = 'CFDF'
                                                                                 and _MasterLanguage.obj_name         = Header.name                                                                     
  association [1..*] to A_CustomFieldBusinessContext  as _BusinessContext        on  _BusinessContext.CustomFieldID   = Header.external_name
  association [0..*] to A_CustomFieldCDSUsage         as _CDSUsage               on  _CDSUsage.CustomFieldID          = Header.external_name
  association [0..*] to A_CustomFieldODataUsage       as _ODataUsage             on  _ODataUsage.CustomFieldID        = Header.external_name
  association [0..*] to A_CustomFieldBusinessScenario as _BusinessScenario       on  _BusinessScenario.CustomFieldID  = Header.external_name
  association [0..*] to A_CustomFieldDynproUsage      as _DynproUsage            on  _DynproUsage.CustomFieldID       = Header.external_name  
  association [0..*] to A_CustomFieldSOAPUsage        as _SOAPUsage              on  _SOAPUsage.CustomFieldID         = Header.external_name  
  association [0..*] to A_CustomFieldUIText           as _UIText                 on  _UIText.CustomFieldID            = Header.external_name
  association [0..*] to A_CustomFieldCodeListValue    as _CodeListValue          on  _CodeListValue.CustomFieldID     = Header.external_name    
  association [0..*] to A_CustomFieldUIExtendedText   as _UIExtendedText         on  _UIExtendedText.CustomFieldID    = Header.external_name   
 {
  key Header.external_name                                                             as CustomFieldID,
      Header.name                                                                      as TransportOrganizerItemName,
      _Status.Status                                                                   as Status,
      _PrimaryBusinessContext.business_context                                         as BusinessContext,
      _MasterLanguage.masterlang                                                       as MasterLanguage,
      cast( case when Header.type = #CFD_FIELD_TYPE.AMOUNT        then 'Amount'
                 when Header.type = #CFD_FIELD_TYPE.ASC_TO_STD or
                      Header.type = #CFD_FIELD_TYPE.ASC_TO_CBO    then 'Association'       
                 when Header.type = #CFD_FIELD_TYPE.BOOLEAN       then 'Boolean'       
                 when Header.type = #CFD_FIELD_TYPE.DATE          then 'Date'
                 when Header.type = #CFD_FIELD_TYPE.EMAIL         then 'EmailAddress'
                 when Header.type = #CFD_FIELD_TYPE.LIST          then 'CodeList'
                 when Header.type = #CFD_FIELD_TYPE.NUMBER        then 'Number'
                 when Header.type = #CFD_FIELD_TYPE.NUMC_TEXT     then 'NumericalText'
                 when Header.type = #CFD_FIELD_TYPE.PHONE         then 'Phone'                      
                 when Header.type = #CFD_FIELD_TYPE.QUANTITY      then 'Quantity'
                 when Header.type = #CFD_FIELD_TYPE.TEXT          then 'Text'
                 when Header.type = #CFD_FIELD_TYPE.TIME          then 'Time'
                 when Header.type = #CFD_FIELD_TYPE.TIMESTAMP     then 'Timestamp'           
                 when Header.type = #CFD_FIELD_TYPE.URL           then 'WebAddress'                      
                 else Header.type end as abap.char( 255 ) )                            as Type,
      cast( Header.length as abap.int4 )                                               as Length,
      cast( Header.scale  as abap.int4 )                                               as Scale,
      Header.associated_business_object                                                as AssociatedBusinessObject,
      cast( case when Header.aggregation = #CFD_FIELD_AGGREGATION.'MAX'  then 'Maximum'
                 when Header.aggregation = #CFD_FIELD_AGGREGATION.'MIN'  then 'Minimum'
                 when Header.aggregation = #CFD_FIELD_AGGREGATION.'NONE' then 'None'
                 when Header.aggregation = #CFD_FIELD_AGGREGATION.'SUM'  then 'Sum'
                 else Header.aggregation end as abap.char( 255 ) )                     as Aggregation,
      Header.code_list_uppercase_only                                                  as CodeListUppercaseOnly,            
      Header.created_by                                                                as CreatedBy,
      dats_tims_to_tstmp( Header.created_on, Header.created_at, 
                          'UTC', $session.client, 'NULL' )                             as CreatedAt, 
      Header.last_changed_by                                                           as ChangedBy,
      dats_tims_to_tstmp( Header.last_changed_on, Header.last_changed_at,   
                          'UTC', $session.client, 'NULL' )                             as ChangedAt, 
      _BusinessContext,
      _CDSUsage,
      _ODataUsage,
      _BusinessScenario,
      _DynproUsage,
      _SOAPUsage,      
      _UIText,
      _CodeListValue,
      _UIExtendedText      
 }
 where Header.version        = _LatestVersion.Version
   and _LatestVersion.origin = #CFD_FIELD_ORIGIN.' '   // consider only Custom Fields (not ABAP Managed Fields)

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_CUSTOMFIELDLATESTVERSION",
"P_CUSTOMFIELDSTATUS",
"CFD_W_REP",
"CFD_W_REP_BUS",
"TADIR"
],
"ASSOCIATED":
[
"A_CUSTOMFIELDBUSINESSCONTEXT",
"A_CUSTOMFIELDBUSINESSSCENARIO",
"A_CUSTOMFIELDCDSUSAGE",
"A_CUSTOMFIELDCODELISTVALUE",
"A_CUSTOMFIELDDYNPROUSAGE",
"A_CUSTOMFIELDODATAUSAGE",
"A_CUSTOMFIELDSOAPUSAGE",
"A_CUSTOMFIELDUIEXTENDEDTEXT",
"A_CUSTOMFIELDUITEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/