A_CreditMemoRequestSimulation

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@ObjectModel: {
   createEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Credit Memo Request Simulation'
define root view entity A_CreditMemoRequestSimulation
  as select from I_CreditMemoRequest as CreditMemoRequest
  composition [0..*] of A_CreditMemoReqItemSimulation as _Item
  composition [0..*] of A_CreditMemoReqPartnerSimln   as _Partner
  composition [0..*] of A_CreditMemoReqPrcgElmntSimln as _PricingElement
  association[0..1] to E_SalesDocumentBasic           as _Extension on $projection.CreditMemoRequest = _Extension.SalesDocument
{
      @ObjectModel.readOnly: true
  key CreditMemoRequest,
      CreditMemoRequestType,

      SalesOrganization,
      DistributionChannel,
      OrganizationDivision,

      SalesGroup,
      SalesOffice,
      SalesDistrict,

      SoldToParty,
      PurchaseOrderByCustomer,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchaseOrderTypeByCustomer'
      CustomerPurchaseOrderType,
      CustomerPurchaseOrderDate,

      CreditMemoRequestDate,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      TransactionCurrency,
      
      @ObjectModel.readOnly: true
      SDPricingProcedure,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
      SDDocumentReason,
      PricingDate,
      CustomerTaxClassification1,
      CustomerTaxClassification2,
      CustomerTaxClassification3,
      CustomerTaxClassification4,
      CustomerTaxClassification5,
      CustomerTaxClassification6,
      CustomerTaxClassification7,
      CustomerTaxClassification8,
      CustomerTaxClassification9,
      @ObjectModel.sapObjectNodeTypeReference: 'CustomerAccountAssignmentGroup'
      CustomerAccountAssignmentGroup,

      @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
      HeaderBillingBlockReason,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      IncotermsVersion,
      CustomerPaymentTerms,
      PaymentMethod,

      BillingDocumentDate,
      ServicesRenderedDate,

      ReferenceSDDocument,

      // Make association public

      _Item,
      _Partner,
      _PricingElement
}
where
  CreditMemoRequest.CreditMemoRequest = '0'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CREDITMEMOREQUEST"
],
"ASSOCIATED":
[
"A_CREDITMEMOREQITEMSIMULATION",
"A_CREDITMEMOREQPARTNERSIMLN",
"A_CREDITMEMOREQPRCGELMNTSIMLN"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/