A_ConditionContract

@EndUserText.label: 'Condition Contract'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType.serviceQuality: #C,
  usageType.dataClass: #TRANSACTIONAL,
  usageType.sizeCategory: #XXL,
  representativeKey: 'ConditionContract'
  }
@VDM: {
  viewType: #CONSUMPTION,
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
  }

define root view entity A_ConditionContract
  provider contract transactional_query
  as projection on R_ConditionContractTP
{
  key ConditionContract,
      CndnContrType,
      CndnContrProcVar,
      Supplier,
      Customer,
      CndnContrActvtnStatus,
      @Semantics.businessDate.from: true
      CndnContrValidFrom,
      @Semantics.businessDate.to: true
      CndnContrValidTo,
      CndnContrClassfctnType,
      DocumentReferenceID,
      CndnContrAssgmtRef,
      ExternalDocumentReferenceID,
      CndnContrExternalPartner,
      CndnContrSourceDocCat,
      CndnContrSourceDoc,
      CndnContrSourceDocItem,
      CndnContrSourceUUID,
      //      CreatedByUser,

      CreationUTCDateTime,
      //      LastChangedByUser,

      LastChangeUTCDateTime,
      CompanyCode,
      PurchasingOrganization,
      PurchasingGroup,
      SalesOrganization,
      DistributionChannel,
      Division,
      SalesGroup,
      SalesOffice,
      CndnContrSuplrSettlmtCat,
      CndnContrCustSettlmtCat,
      SettlmtProduct,
      CndnContrExtensionCalendar,
      PriorSupplier,
      BusVolTableGroup,
      AmountFieldGroup,
      FinalSettlmtCalendar,
      PartialSettlmtCalendar,
      DeltaSettlmtCalendar,
      DeltaAccrualSettlmtCalendar,
      AccrualClearingSettlmtCalendar,
      PrecedingConditionDocument                                                                           as PrecedingConditionContract,
      CndnContrUUID,
      CndnContrPurposeCat,
      @Semantics.currencyCode: true
      CndnContrCurrency,
      @Semantics.unitOfMeasure: true
      CndnContrUnit,
      cast( _CndnContrUnit.UnitOfMeasureISOCode as wcb_settlement_meins_iso preserving type )              as CndnContrUnitISOCode,
      cast( _CndnContrUnit.UnitOfMeasureSAPCode as wcb_settlement_meins_sapcode preserving type )          as CndnContrUnitSAPCode,
      @Semantics.unitOfMeasure: true
      CndnContrWeightUnit,
      cast( _CndnContrWeightUnit.UnitOfMeasureISOCode as wcb_settlement_gewei_iso preserving type )        as CndnContrWeightUnitISOCode,
      cast( _CndnContrWeightUnit.UnitOfMeasureSAPCode as wcb_settlement_gewei_sapcode preserving type )    as CndnContrWeightUnitSAPCode,
      @Semantics.unitOfMeasure: true
      CndnContrVolumeUnit,
      cast( _CndnContrVolumeUnit.UnitOfMeasureISOCode as wcb_settlement_voleh_iso preserving type )        as CndnContrVolumeUnitISOCode,
      cast( _CndnContrVolumeUnit.UnitOfMeasureSAPCode as wcb_settlement_voleh_sapcode preserving type )    as CndnContrVolumeUnitSAPCode,
      @Semantics.unitOfMeasure: true
      CndnContrPointsQtyUnit,
      cast( _CndnContrPointsQtyUnit.UnitOfMeasureISOCode as wcb_settlement_punei_iso preserving type )     as CndnContrPointsQtyUnitISOCode,
      cast( _CndnContrPointsQtyUnit.UnitOfMeasureSAPCode as wcb_settlement_punei_sapcode preserving type ) as CndnContrPointsQtyUnitSAPCode,
      ExchangeRate,
      ExchangeRateDate,
      ExchangeRateType,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount1Percent,
      CashDiscount2Days,
      CashDiscount2Percent,
      NetPaymentDays,
      PaymentMethod,
      AccrualUpdateIsRequired,
      SettlmtPartTxRegnNmbr,
      TaxCountry,
      SettlmtPartTxRegnCntry,

      /* Worker related fields */
      PersonWorkAgreement,
      CndnContrWorkerCostCenter,
      CndnContrWorkerSettlmtCat,

      /* --- Compositions --- */
      @ObjectModel.filter.enabled: false
      _CndnContrCndnRecord        : redirected to composition child A_CndnContrCndnRecord,
      _CndnContrBusVolSelCriteria : redirected to composition child A_CndnContrBusVolSelCriteria,
      _CndnContrSettlmtCal        : redirected to composition child A_CndnContrSettlmtCal,
      _CndnContrActiveStatus      : redirected to composition child A_CndnContrActiveStatus,

      /* --- Associations required for DCL --- */
      @Consumption.hidden: true
      _Customer,
      @Consumption.hidden: true
      _PriorSupplier,
      @Consumption.hidden: true
      _Supplier,
      @Consumption.hidden: true
      _PersonWorkAgreement

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_UNITOFMEASURE",
"R_CONDITIONCONTRACTTP"
],
"ASSOCIATED":
[
"A_CNDNCONTRACTIVESTATUS",
"A_CNDNCONTRBUSVOLSELCRITERIA",
"A_CNDNCONTRCNDNRECORD",
"A_CNDNCONTRSETTLMTCAL",
"I_CUSTOMER",
"I_PERSONWORKAGREEMENT_1",
"I_SUPPLIER",
"R_CNDNCONTRACTIVESTATUSTP",
"R_CNDNCONTRBUSVOLSELCRITERIATP",
"R_CNDNCONTRCNDNRECORDTP",
"R_CNDNCONTRSETTLMTCALTP"
],
"BASE":
[
"R_CONDITIONCONTRACTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/