A_CnsldtnProfitCenterHier

@AbapCatalog:{
  sqlViewName: 'ACSPRFTCNTRHIER',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #L},
  representativeKey: 'HierarchyNode'
  }
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Combined Profit Center - Hierarchy Node'
@OData.entitySet.name: 'ProfitCenterHier'

define view A_CnsldtnProfitCenterHier
  as select from I_CnsldtnProfitCenterHierNode

  association [0..*] to A_CnsldtnProfitCenterHierT   as _CnsldtnProfitCenterHierT   on  $projection.ControllingArea               = _CnsldtnProfitCenterHierT.ControllingArea
                                                                                    and $projection.AdditionalMasterDataHierarchy = _CnsldtnProfitCenterHierT.AdditionalMasterDataHierarchy
                                                                                    and $projection.HierarchyNode                 = _CnsldtnProfitCenterHierT.HierarchyNode
                                                                                    and $projection.ProfitCenter                  = ''

  association [0..*] to A_CnsldtnProfitCenterHierT   as _CnsldtnProfitCenterHierT_2 on  $projection.ControllingArea               = _CnsldtnProfitCenterHierT_2.ControllingArea
                                                                                    and $projection.AdditionalMasterDataHierarchy = _CnsldtnProfitCenterHierT_2.AdditionalMasterDataHierarchy
                                                                                    and $projection.HierarchyNode                 = _CnsldtnProfitCenterHierT_2.HierarchyNode
                                                                                    and $projection.ValidityEndDate               = _CnsldtnProfitCenterHierT_2.ValidityEndDate
                                                                                    and $projection.ProfitCenter                  = ''

  association [0..1] to A_CnsldtnProfitCenter        as _CnsldtnProfitCenter        on  $projection.ControllingArea = _CnsldtnProfitCenter.ControllingArea
                                                                                    and $projection.ProfitCenter    = _CnsldtnProfitCenter.ProfitCenter

  association [1..1] to A_CnsldtnControllingArea     as _CnsldtnControllingArea     on  $projection.ControllingArea = _CnsldtnControllingArea.ControllingArea

  association [0..*] to A_CnsldtnProfitCenterT       as _CnsldtnProfitCenterT       on  $projection.ProfitCenter    = _CnsldtnProfitCenterT.ProfitCenter
                                                                                    and $projection.ControllingArea = _CnsldtnProfitCenterT.ControllingArea

  association [1..1] to A_CnsldtnProfitCenterHierDir as _CnsldtnProfitCenterHierDir on  $projection.AdditionalMasterDataHierarchy = _CnsldtnProfitCenterHierDir.AdditionalMasterDataHierarchy
                                                                                    and $projection.ValidityEndDate               = _CnsldtnProfitCenterHierDir.ValidityEndDate

{
      @ObjectModel.foreignKey.association: '_CnsldtnControllingArea'
  key ControllingArea                                                                            as ControllingArea,

      @ObjectModel.foreignKey.association: '_CnsldtnProfitCenterHierDir'
  key cast(left(ConsolidationPrftCtrHierarchy, 40) as fincs_hryid_profitcenter preserving type ) as AdditionalMasterDataHierarchy,

      @ObjectModel.text.association: '_CnsldtnProfitCenterHierT_2'
  key HierarchyNode                                                                              as HierarchyNode,

      @Semantics.businessDate.to: true
  key ValidityEndDate                                                                            as ValidityEndDate,

      ParentNode,
      HierarchyVersion,

      @Semantics.businessDate.from: true
      ValidityStartDate,

      @EndUserText.label: 'Profit Center'
      @ObjectModel.text.association: '_CnsldtnProfitCenterT'
      ProfitCenter,

      // STS - compatible ATC cleanup change - to be removed

      cast(HierarchyNodeSequence as abap.char( 56 ) )                                            as SequenceNumber,

      HierarchyNodeSequence,

      HierarchyNodeLevel,
      NodeType,

      @Consumption.hidden: true
      cast( 'CS04' as hrytype preserving type )                                                  as MDHierType,

      @Consumption.hidden: true
      cast( 'CS04' as hrytype preserving type )                                                  as HierarchyType,


      @Consumption.hidden: true
      _CnsldtnProfitCenterHierDir,

      _CnsldtnControllingArea,
      _CnsldtnProfitCenter,
      _CnsldtnProfitCenterT,
      _CnsldtnProfitCenterHierT,
      _CnsldtnProfitCenterHierT_2
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNPROFITCENTERHIERNODE"
],
"ASSOCIATED":
[
"A_CNSLDTNCONTROLLINGAREA",
"A_CNSLDTNPROFITCENTER",
"A_CNSLDTNPROFITCENTERHIERDIR",
"A_CNSLDTNPROFITCENTERHIERT",
"A_CNSLDTNPROFITCENTERT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/