A_CnsldtnPartnerSegmentHier

@AbapCatalog:{
  sqlViewName: 'ACSPARTSEGMENTH',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL}
  }
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Combined Partner Segment - Hier Node'
@OData.entitySet.name: 'PartnerSegmentHier'

define view A_CnsldtnPartnerSegmentHier
  as select from I_CnsldtnSegmentHierNode

  association [0..1] to A_CnsldtnPartnerSegment   as _CnsldtnPartnerSegment     on  $projection.Segment = _CnsldtnPartnerSegment.Segment

  association [0..*] to A_CnsldtnPartSegmentHierT as _CnsldtnPartSegmentHierT   on  $projection.ConsolidationSegmentHierarchy = _CnsldtnPartSegmentHierT.ConsolidationSegmentHierarchy
                                                                                and $projection.HierarchyNode                 = _CnsldtnPartSegmentHierT.HierarchyNode
                                                                                and $projection.Segment                       = ''

  association [0..*] to A_CnsldtnPartSegmentHierT as _CnsldtnPartSegmentHierT_2 on  $projection.ConsolidationSegmentHierarchy = _CnsldtnPartSegmentHierT_2.ConsolidationSegmentHierarchy
                                                                                and $projection.HierarchyNode                 = _CnsldtnPartSegmentHierT_2.HierarchyNode
                                                                                and $projection.ValidityEndDate               = _CnsldtnPartSegmentHierT_2.ValidityEndDate
                                                                                and $projection.Segment                       = ''

  association [0..*] to A_CnsldtnPartnerSegmentT  as _CnsldtnPartnerSegmentT    on  $projection.Segment = _CnsldtnPartnerSegmentT.Segment

{
  key cast(left(ConsolidationSegmentHierarchy, 40) as fincs_hryid_segment preserving type ) as ConsolidationSegmentHierarchy,

      @ObjectModel.text.association: '_CnsldtnPartSegmentHierT_2'
  key HierarchyNode,

      @Semantics.businessDate.to: true
  key ValidityEndDate,

      ParentNode,

      @Semantics.businessDate.from: true
      ValidityStartDate,

      @ObjectModel.text.association: '_CnsldtnPartnerSegmentT'
      cast(Segment as fincs_psegment preserving type )                                      as Segment,

      // STS - compatible ATC cleanup change - to be removed

      cast(HierarchyNodeSequence as abap.char( 56 ) )                                       as SequenceNumber,
      // STS - compatible ATC cleanup change - to be removed


      // STS - compatible ATC cleanup change

      HierarchyNodeSequence,
      // STS - compatible ATC cleanup change


      HierarchyNodeLevel,
      NodeType,

      @Consumption.hidden: true

      //this cast is semantically wrong, only for compatibility wrt. length

      //in the underlying I-View it was corrected

      cast('CS01' as fincs_hryid)                                                           as MDHierType,
      @Consumption.hidden: true
      cast('CS01' as hrytype)                                                               as HierarchyType,


      _CnsldtnPartnerSegment,
      _CnsldtnPartnerSegmentT,
      _CnsldtnPartSegmentHierT,
      _CnsldtnPartSegmentHierT_2
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNSEGMENTHIERNODE"
],
"ASSOCIATED":
[
"A_CNSLDTNPARTNERSEGMENT",
"A_CNSLDTNPARTNERSEGMENTT",
"A_CNSLDTNPARTSEGMENTHIERT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/