A_CnsldtnDocumentType

@AbapCatalog:{
  sqlViewName: 'ACSDOCUMENTTYPE',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #C,
    sizeCategory: #S},
  representativeKey: 'ConsolidationDocumentType',
  sapObjectNodeType.name: 'ConsolidationDocumentType'
  }
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Consolidation Document Type'
@OData.entitySet.name: 'ConsolidationDocumentType'

define view A_CnsldtnDocumentType
  as select from I_CnsldtnDocumentTypeEnhcd10

  association [0..1] to A_CnsldtnPostingLevel     as _CnsldtnPostingLevel     on $projection.PostingLevel = _CnsldtnPostingLevel.PostingLevel

  association [0..*] to A_CnsldtnPostingLevelT    as _CnsldtnPostingLevelT    on $projection.PostingLevel = _CnsldtnPostingLevelT.PostingLevel

  association [0..*] to A_CnsldtnDocumentTypeT    as _CnsldtnDocumentTypeT    on $projection.ConsolidationDocumentType = _CnsldtnDocumentTypeT.ConsolidationDocumentType

  association [0..*] to A_CnsldtnBusinessApplT    as _CnsldtnBusinessApplT    on $projection.DocumentTypeBusinessAppl = _CnsldtnBusinessApplT.DocumentTypeBusinessAppl

  association [0..*] to A_CnsldtnBalanceCheckT    as _CnsldtnBalanceCheckT    on $projection.ConsolidationBalanceCheck = _CnsldtnBalanceCheckT.ConsolidationBalanceCheck

  association [0..1] to A_CnsldtnDimension        as _CnsldtnDimension        on $projection.ConsolidationDimension = _CnsldtnDimension.ConsolidationDimension

  association [0..*] to A_CnsldtnDocumentTypeHier as _CnsldtnDocumentTypeHier on $projection.ConsolidationDimension = _CnsldtnDocumentTypeHier.ConsolidationDimension

{

      @ObjectModel:{
        text.association: '_CnsldtnDocumentTypeT',
        sapObjectNodeTypeReference: 'ConsolidationDocumentType'
        }
  key ConsolidationDocumentType,

      @Consumption.hidden: true
      @ObjectModel.foreignKey.association: '_CnsldtnDimension'
      ConsolidationDimension,

      @ObjectModel:{
        foreignKey.association: '_CnsldtnPostingLevel',
        text.association: '_CnsldtnDocumentTypeT',
        sapObjectNodeTypeReference: 'ConsolidationPostingLevel'
        }
      PostingLevel,

      //TODO: add foreign key association

      @ObjectModel.text.association: '_CnsldtnBalanceCheckT'
      ConsolidationBalanceCheck,

      ConsolidationPostgItemAutoFlag,

      IsDocumentPostInTransCurrency,

      IsDocumentPostInLocalCurrency,

      IsDocumentPostInGroupCurrency,

      DocHasCreditDeferredTax,

      DocHasDebitDeferredTax,

      //TODO: add foreign key association

      @ObjectModel.text.association: '_CnsldtnBusinessApplT'
      DocumentTypeBusinessAppl,

      // associations

      @Consumption.hidden: true
      _CnsldtnBalanceCheckT, // required for text retrieval


      @Consumption.hidden: true
      _CnsldtnBusinessApplT, // required for text retrieval


      @Consumption.hidden: true
      _CnsldtnPostingLevel, // required for value help retrieval


      @Consumption.hidden: true
      _CnsldtnPostingLevelT, // required for text retrieval


      @Consumption.hidden: true
      _CnsldtnDimension, // required for value help retrieval


      _CnsldtnDocumentTypeHier, // required for navigation


      _CnsldtnDocumentTypeT // required for text retrieval and navigation

}
where
  ConsolidationDimension = 'Y1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNDOCUMENTTYPEENHCD10"
],
"ASSOCIATED":
[
"A_CNSLDTNBALANCECHECKT",
"A_CNSLDTNBUSINESSAPPLT",
"A_CNSLDTNDIMENSION",
"A_CNSLDTNDOCUMENTTYPEHIER",
"A_CNSLDTNDOCUMENTTYPET",
"A_CNSLDTNPOSTINGLEVEL",
"A_CNSLDTNPOSTINGLEVELT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/