A_ChangeMaster_1

@AccessControl.authorizationCheck: #CHECK

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER

// set entity set name in OData for service backward compatibility

@OData.entitySet.name : 'A_ChangeMaster'

@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Change Number'
define root view entity A_ChangeMaster_1
  as select from I_ChangeMasterTP

  composition [1..*] of A_ChangeMasterAltDate_1       as _AlternativeDate
  composition [1..*] of A_ChangeMasterObjTypeAssgmt_1 as _ObjTypeAssignment
  composition [1..*] of A_ChangeMstrObjectMgmtRecord  as _ChangeMstrObjectMgmtRecord
  composition [1..*] of A_ChangeMstrObMgReMaterial    as _ChangeMstrObMgReMaterial
  composition [1..*] of A_ChangeMstrObMgReMatlBOM     as _ChangeMstrObMgReMatlBOM
  composition [1..*] of A_ChangeMstrObMgReDocInfoRecd as _ChangeMstrObMgReDocInfoRecd

  association [0..*] to A_ChangeMasterClass           as _Classification           on  $projection.ChangeNumber = _Classification.ChangeNumber
  association [0..*] to A_ChangeMasterCharc           as _Characteristics          on  $projection.ChangeNumber = _Characteristics.ChangeNumber
  association [0..1] to A_ChangeMasterStatus          as _ChangeNumberStatus       on  $projection.ChangeNumberStatus = _ChangeNumberStatus.ChangeNumberStatus

  // Access Control Management integration


  association [0..1] to A_LogAccMObjectTypeActive     as _LogAccMObjectTypeActive  on  _LogAccMObjectTypeActive.LogAccMObjectType = 'PLM_ECN'

  association [0..*] to A_LogAccMObjSecureIDAssgmt    as _LogAccMObjSecureIDAssgmt on  $projection.ChangeNumber                    = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                   and _LogAccMObjSecureIDAssgmt.LogAccMObjectType = 'PLM_ECN'
  association [0..*] to A_LogAccMObjectUserAuthzn     as _LogAccMObjectUserAuthzn  on  $projection.ChangeNumber                         = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                   and _LogAccMObjectUserAuthzn.LogAccMObjectType       = 'PLM_ECN'
                                                                                   and _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject = 'PLM_ECN'
                                                                                   and (
                                                                                      _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom    = '03'
                                                                                      or _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom = '*'
                                                                                    )
                                                                                   and _LogAccMObjectUserAuthzn.LogAccMUserAuthznField  = 'ACTVT'
                                                                                   and (
                                                                                      _LogAccMObjectUserAuthzn.LogAccMUserEntityID      = $session.user
                                                                                      or _LogAccMObjectUserAuthzn.UserID                = $session.user
                                                                                    )
{
  key ChangeNumber,

      ChangeNumberStatus,

      AuthorizationGroup,

      ChangeNumberFunction,
      IsTechnicallyReleased,

      ChangeNumberReleaseKey,
      ReasonForChangeText,
      ChangeNumberDescription,
      ChangeNumberValidFromDate,

      ChangeNumberCreationDate,

      ChangeNumberCreatedByUser,

      ChangeNumberLastChangedDate,

      ChangeNumberLastChangedByUser,

      IsUsedForDataDefinition,

      ChangeNumberIsMrkdForDeletion,

      ChangeNumberLastChgdDateTime,

      _ChangeNumberStatus,
      _AlternativeDate,
      _ObjTypeAssignment,
      _ChangeMstrObjectMgmtRecord,
      _ChangeMstrObMgReMaterial,
      _ChangeMstrObMgReMatlBOM,
      _ChangeMstrObMgReDocInfoRecd,
      _Classification,
      _Characteristics,

      // Access Control Management

      _LogAccMObjectTypeActive,
      _LogAccMObjectUserAuthzn,
      _LogAccMObjSecureIDAssgmt
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEMASTERTP"
],
"ASSOCIATED":
[
"A_CHANGEMASTERALTDATE_1",
"A_CHANGEMASTERCHARC",
"A_CHANGEMASTERCLASS",
"A_CHANGEMASTEROBJTYPEASSGMT_1",
"A_CHANGEMASTERSTATUS",
"A_CHANGEMSTROBJECTMGMTRECORD",
"A_CHANGEMSTROBMGREDOCINFORECD",
"A_CHANGEMSTROBMGREMATERIAL",
"A_CHANGEMSTROBMGREMATLBOM",
"A_LOGACCMOBJECTTYPEACTIVE",
"A_LOGACCMOBJECTUSERAUTHZN",
"A_LOGACCMOBJSECUREIDASSGMT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/