A_ChangeMaster

@AbapCatalog.sqlViewName: 'ACHANGEMASTER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER

@ObjectModel: {
   compositionRoot: true,
   representativeKey: 'ChangeNumber'
}

@VDM.viewType: #BASIC

@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Change Number Header Data'
define view A_ChangeMaster
  as select from I_ChangeMaster
  association [0..1] to A_ChangeMasterStatus        as _ChangeNumberStatus on $projection.ChangeNumberStatus = _ChangeNumberStatus.ChangeNumberStatus
  association [0..*] to A_ChangeMasterAltDate       as _AlternativeDate    on $projection.ChangeNumber = _AlternativeDate.ChangeNumber
  association [0..*] to A_ChangeMasterObjTypeAssgmt as _ObjTypeAssignment  on $projection.ChangeNumber = _ObjTypeAssignment.ChangeNumber
  
  // Access Control Management integration


  association [0..1] to A_LogAccMObjectTypeActive      as _LogAccMObjectTypeActive      on  _LogAccMObjectTypeActive.LogAccMObjectType = 'PLM_ECN'

  association [0..*] to A_LogAccMObjSecureIDAssgmt     as _LogAccMObjSecureIDAssgmt     on  $projection.ChangeNumber                    = _LogAccMObjSecureIDAssgmt.LogAccMObjectID
                                                                                        and _LogAccMObjSecureIDAssgmt.LogAccMObjectType = 'PLM_ECN'
  association [0..*] to A_LogAccMObjectUserAuthzn      as _LogAccMObjectUserAuthzn      on  $projection.ChangeNumber                         = _LogAccMObjectUserAuthzn.LogAccMObjectID
                                                                                        and _LogAccMObjectUserAuthzn.LogAccMObjectType       = 'PLM_ECN'
                                                                                        and _LogAccMObjectUserAuthzn.LogAccMUserAuthznObject = 'PLM_ECN'
                                                                                        and (
                                                                                           _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom    = '03'
                                                                                           or _LogAccMObjectUserAuthzn.LogAccMUserAuthznFrom = '*'
                                                                                         )
                                                                                        and _LogAccMObjectUserAuthzn.LogAccMUserAuthznField  = 'ACTVT'
                                                                                        and (
                                                                                           _LogAccMObjectUserAuthzn.LogAccMUserEntityID      = $session.user
                                                                                           or _LogAccMObjectUserAuthzn.UserID                = $session.user
                                                                                         )
  
{
  key ChangeNumber,

      ChangeNumberStatus,

      AuthorizationGroup,

      ChangeNumberFunction,
      IsTechnicallyReleased,
      ChangeNumberReleaseKey,
      ReasonForChangeText,
      ChangeNumberDescription,
      ChangeNumberValidFromDate,
      ChangeNumberCreationDate,
      ChangeNumberCreatedByUser,
      ChangeNumberLastChangedDate,
      ChangeNumberLastChangedByUser,

      IsUsedForDataDefinition,

      ChangeNumberIsMrkdForDeletion,

      _ChangeNumberStatus,
      _AlternativeDate,
      _ObjTypeAssignment,
      
   // Access Control Management     

      _LogAccMObjectTypeActive,   
      _LogAccMObjectUserAuthzn,      
      _LogAccMObjSecureIDAssgmt
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEMASTER"
],
"ASSOCIATED":
[
"A_CHANGEMASTERALTDATE",
"A_CHANGEMASTEROBJTYPEASSGMT",
"A_CHANGEMASTERSTATUS",
"A_LOGACCMOBJECTTYPEACTIVE",
"A_LOGACCMOBJECTUSERAUTHZN",
"A_LOGACCMOBJSECUREIDASSGMT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/