@AbapCatalog.sqlViewName: 'ATOV_PREF_SUPP_U'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Supported Adaptation Types per Namespace'
// Only use content types that support templates for Development Namespaces
define view ATOV_PREFIX_ADAPT_TYPE_SUP_U
as select from ato_prefix_set as prefix
left outer join EITV_EXP_ITEM_TYPE as content_type on content_type.item_type = content_type.item_type
and content_type.locked = ' '
inner join ato_adapt_typest as content_type_text on content_type.item_type = content_type_text.adaptation_type
and content_type_text.language = $session.system_language
{
content_type_text.adaptation_type,
prefix.dev_prefix as namespace,
content_type_text.description as adaptation_type_descr
}
where
prefix.category <> 'K'
and prefix.category <> 'L'
and prefix.category <> 'G'
and prefix.category <> 'S'
union
// Key user namespace in Cloud (Dev System)
select from ato_prefix_set as prefix
inner join ato_setup as setup on setup.setup_type = 'C'
and setup.ato_mode <> 'G'
left outer join ATOV_ADAPT_TYPES_FILTER_LOCKED as content_type on content_type.adaptation_type = content_type.adaptation_type
and content_type.col_supported = 'X'
and content_type.locked = ' '
inner join ato_adapt_typest as content_type_text on content_type.adaptation_type = content_type_text.adaptation_type
and content_type_text.language = $session.system_language
{
content_type_text.adaptation_type,
prefix.dev_prefix as namespace,
content_type_text.description as adaptation_type_descr
}
where
prefix.category = 'K'
union
// Key user namespace in Cloud (Prod System)
select from ato_prefix_set as prefix
inner join ato_setup as setup on setup.setup_type = 'C'
and setup.ato_mode <> 'G'
left outer join ATOV_ADAPT_TYPES_FILTER_LOCKED as content_type on content_type.adaptation_type = content_type.adaptation_type
and content_type.col_supported = 'X'
and content_type.non_ext_dev_supported = 'X'
and content_type.locked = ' '
inner join ato_adapt_typest as content_type_text on content_type.adaptation_type = content_type_text.adaptation_type
and content_type_text.language = $session.system_language
{
content_type_text.adaptation_type,
prefix.dev_prefix as namespace,
content_type_text.description as adaptation_type_descr
}
where
prefix.category = 'L'
union
// Key user namespace in Steampunk (Dev System)
select from ato_prefix_set as prefix
inner join ato_setup as setup on setup.setup_type = 'C'
and setup.ato_mode = 'G'
left outer join ATOV_ADAPT_TYPES_FILTER_LOCKED as content_type on content_type.adaptation_type = content_type.adaptation_type
and content_type.gcts_supported = 'X'
and content_type.locked = ' '
inner join ato_adapt_typest as content_type_text on content_type.adaptation_type = content_type_text.adaptation_type
and content_type_text.language = $session.system_language
{
content_type_text.adaptation_type,
prefix.dev_prefix as namespace,
content_type_text.description as adaptation_type_descr
}
where
prefix.category = 'K'
union
// Key user namespace in Steampunk (Prod System)
select from ato_prefix_set as prefix
inner join ato_setup as setup on setup.setup_type = 'C'
and setup.ato_mode = 'G'
left outer join ATOV_ADAPT_TYPES_FILTER_LOCKED as content_type on content_type.adaptation_type = content_type.adaptation_type
and content_type.gcts_supported = 'X'
and content_type.non_ext_dev_supported = 'X'
and content_type.locked = ' '
inner join ato_adapt_typest as content_type_text on content_type.adaptation_type = content_type_text.adaptation_type
and content_type_text.language = $session.system_language
{
content_type_text.adaptation_type,
prefix.dev_prefix as namespace,
content_type_text.description as adaptation_type_descr
}
where
prefix.category = 'L'
union
select from ato_prefix_set as prefix
// if_ato_item_type_factory~does_type_support_abapgit must also be adopted if new item types are allowed
left outer join ato_adapt_typest as content_type_text on content_type_text.adaptation_type = 'CFDF'
and content_type_text.language = $session.system_language
{
content_type_text.adaptation_type,
prefix.dev_prefix as namespace,
content_type_text.description as adaptation_type_descr
}
where
prefix.category = 'G'
or prefix.category = 'S'
union
// Key user namespace in OnPrem
select from ATOV_PK_NAMESPACE as prefix // ato_prefix_set is currently not filled in onPrem
inner join ato_setup as setup on setup.setup_type = 'P'
left outer join ATOV_ADAPT_TYPES_FILTER_LOCKED as content_type on content_type.adaptation_type = content_type.adaptation_type
and content_type.pk_supported = 'X'
and content_type.locked = ' '
inner join ato_adapt_typest as content_type_text on content_type.adaptation_type = content_type_text.adaptation_type
and content_type_text.language = $session.system_language
{
content_type_text.adaptation_type,
prefix.prefix as namespace,
content_type_text.description as adaptation_type_descr
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ATOV_ADAPT_TYPES_FILTER_LOCKED",
"ATOV_PK_NAMESPACE",
"EITV_EXP_ITEM_TYPE",
"ATO_ADAPT_TYPEST",
"ATO_PREFIX_SET",
"ATO_SETUP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/