ATOV_COL

@AbapCatalog.sqlViewName: 'ATO_V_C'
@ClientHandling:{ type: #INHERITED, algorithm: #SESSION_VARIABLE }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Collections'
define view ATOV_COL as  select from ato_cols as Collection

left outer join ato_setup as original_setup on 
     original_setup.original_systname = Collection.original_systname 

  association [1]    to ATOV_COL_COUNT_VERSION      as Version_Counter           on  Version_Counter.collection_id = Collection.collection_id

  association [*]    to ATOV_COL_VER                as Collection_Versions       on  Collection_Versions.collection_id = Collection.collection_id

  association [0..1] to ATOV_COL_VER                as Latest_Collection_Version on  Latest_Collection_Version.collection_id     = Collection.collection_id
                                                                                 and Latest_Collection_Version.is_latest_version = 'X'

  association [0..1] to ATOV_COL_STATUS_DESCRIPTION as Collection_Status         on  Collection_Status.code = Collection.status

  association [0..1] to ATOV_COL_MERGE              as Collection_Merge          on  Collection_Merge.MergedCollectionId = Collection.collection_id

  association [1] to ATOV_USER as Changed_By_Description on Changed_By_Description.name = Collection.last_changed_by 

  association [1] to ATOV_USER as Created_By_Description on Created_By_Description.name = Collection.created_by
   
{
  key Collection.collection_id,
      Collection.original_system_type,
      Collection.last_changed_by         as changed_by,
      Collection.last_changed_at         as changed_at,
      Collection.created_by              as created_by,
      Collection.created_at              as created_at,
      Collection.status                  as status,
      Collection_Status.description      as status_description,
      Collection.description_text        as description,
      Collection.category                as category,
      Collection.collection_type         as collection_type,
      Collection.dev_namespace           as dev_namespace,
      Collection.original_systname       as original_systname,
      Collection.export_locked           as export_locked,
      Collection.add_item_locked         as add_item_locked,
      Collection.notify_locked           as notify_locked,
      Collection.project_id              as project_id,
      Collection.project_description     as project_description,
      Collection.client                  as client,
      case ( COALESCE( original_setup.original_systname, '' ))  when '' 
           then ' '
           else 'X'
      end as is_original_system,              
      /* Associations */
      Version_Counter,
      Collection_Versions,
      Latest_Collection_Version,
      Changed_By_Description.description as changed_by_description,
      Created_By_Description.description as created_by_description       
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ATOV_COL_STATUS_DESCRIPTION",
"ATOV_USER",
"ATO_COLS",
"ATO_SETUP"
],
"ASSOCIATED":
[
"ATOV_COL_COUNT_VERSION",
"ATOV_COL_MERGE",
"ATOV_COL_STATUS_DESCRIPTION",
"ATOV_COL_VER",
"ATOV_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/