ATOV_ARS_CLOUD_CUSTOM_DEV_OBJ

// ************************************************

// The view returns development objects created by the customer

// in S/4HANA Cloud or SAP Cloud Platform ABAP Environment

// it includes the installed Software Components

// it does not contain the deleted Key-User Objects

// focus of the view are all cloud systems - it is not reliable in on Premise

//

// E L E M E N T S

// OBJECT_TYPE Object directory type of the development object

//             as defined in table TADIR

//             Example: DDLS for a Data Definition

// OBJECT_NAME Object directory name of the development object

//             as defined in table TADIR

//             Example: Z_MY_CUSTOM_OBJECT

// ORIGIN      Origin of the development object

//             Values:

//             SCP = ABAP for Cloud Development: Custom Development

//             INS = ABAP for Cloud Development: Installed add-on

//             KUA = Key User App Extension Object

//             TMP = LOCAL $TMP Object (e.g. by Support Object user)

// ************************************************

@AbapCatalog.sqlViewName: 'ATO_ARS_CLD_CSTD'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Custom development and key user objects'

define view ATOV_ARS_CLOUD_CUSTOM_DEV_OBJ
  as select from    tadir

    inner join      tdevc                              on tdevc.devclass = tadir.devclass
    left outer join ATOV_ABAP_CLOUD_DEV_SWCMP as swcmp on swcmp.component = tdevc.dlvunit 
    //outer join to support SAP SWCMP w/o ABAP LANGUAGE_VERSION = 5

{
  key tadir.pgmid                          as pgmid,
  key tadir.object                         as object_type,
  key cast( tadir.obj_name as trobj_name ) as object_name, //Cast to longer trobj_name as ATO uses trobj_name


      case
      // Select key user objects from package TEST_YY*

      when tadir.devclass like 'TEST#_YY%' escape '#' then 'KUA' //Key User Item

      when tadir.devclass = '$TMP'                    then 'TMP' //LOCAL $TMP Object => mainly Support Object

      else case coalesce(swcmp.is_installed, 'N')
             when 'X' then 'INS' // ABAP for Cloud Development: Installed add-on

             when 'N' then ''    // SAP Object or legacy custom development

             else 'SCP'          // ABAP for Cloud Development: Custom Development Object

           end
      end                                  as origin
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ATOV_ABAP_CLOUD_DEV_SWCMP",
"TADIR",
"TDEVC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/