ARun_ValAddedSrvcSDItmBsc

@ClientHandling.algorithm: #AUTOMATED
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #NOT_REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'ARUNVASSDITMBSC',
  compiler.compareFilter: true,
  preserveKey:true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
define view ARun_ValAddedSrvcSDItmBsc
  as select from    vbak                         as _SalesDocument
    inner join      vbap                         as _SalesDocumentItem          on _SalesDocument.vbeln = _SalesDocumentItem.vbeln
    left outer join I_SDDocumentCompletePartners as _SDDocumentCompletePartners on(
      _SalesDocumentItem.vbeln                        = _SDDocumentCompletePartners.SDDocument
      and _SDDocumentCompletePartners.SDDocumentItem  = '000000'
      and _SDDocumentCompletePartners.PartnerFunction = 'WE'
    )
    left outer join I_SDDocumentCompletePartners as _SDDocumentPartnersWE       on(
            _SalesDocumentItem.vbeln                  = _SDDocumentPartnersWE.SDDocument
            and _SalesDocumentItem.posnr              = _SDDocumentPartnersWE.SDDocumentItem
            and _SDDocumentPartnersWE.PartnerFunction = 'WE'
          )
    left outer join I_SDDocumentCompletePartners as _SDDocumentPartnersSP       on(
            _SalesDocumentItem.vbeln                  = _SDDocumentPartnersSP.SDDocument
            and _SalesDocumentItem.posnr              = _SDDocumentPartnersSP.SDDocumentItem
            and _SDDocumentPartnersSP.PartnerFunction = 'SP'
          )
{
  case _SalesDocument.vbtyp
  when 'C' then 'VC'
  when 'I' then 'VI'
  else ''
  end                                as RequirementType,
  _SalesDocumentItem.vbeln           as SalesDocument,
  _SalesDocumentItem.fsh_vas_prnt_id as ValAddedSrvcItemNumberInSD,
  _SalesDocumentItem.posnr           as SalesDocumentItem,
  _SalesDocument.auart               as OrderType,
  _SalesDocument.vkorg               as SalesOrganization,
  _SalesDocument.vtweg               as DistributionChannel,
  _SalesDocument.spart               as Division,
  _SalesDocumentItem.werks           as Plant,
  _SalesDocumentItem.matnr           as Material,
  case
  when _SDDocumentPartnersSP.Customer is not null then  _SDDocumentPartnersSP.Customer
  else _SalesDocument.kunnr
  end                                as SoldToParty,
  case
  when _SDDocumentPartnersWE.Customer is not null then _SDDocumentPartnersWE.Customer
  else _SDDocumentCompletePartners.Customer
  end                                as ShipToParty,
  _SalesDocumentItem.rfm_psst_group  as ShippingGroupNumber,
  case _SalesDocument.fsh_rereg
  when ' ' then '$$$$'
  else _SalesDocument.fsh_rereg
  end                                as ARunSupplyAssgmtReleaseRule,
  _SalesDocumentItem.grkor           as DeliveryGroup,
  case
  when  ( _SalesDocumentItem.umziz != 0 ) and
         ( _SalesDocumentItem.umzin != 0 )
         then _SalesDocumentItem.kwmeng * div(_SalesDocumentItem.umziz,_SalesDocumentItem.umzin)
         else _SalesDocumentItem.kwmeng
         end                         as RequestedRqmtQtyInBaseUnit
}
where
  _SalesDocumentItem.fsh_vas_rel = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SDDOCUMENTCOMPLETEPARTNERS",
"VBAK",
"VBAP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/