ACE_ACEPSOIT_BASIC

@AbapCatalog.sqlViewName: 'ACEV_ACEPSOITBSC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'basic view for ACEPSOIT'
define view ACE_ACEPSOIT_BASIC
  as select from    acepsoit
    left outer join acesobj  on  acepsoit.mandt = acesobj.mandt
                             and acepsoit.comp  = acesobj.comp
                             and acepsoit.bukrs = acesobj.bukrs
                             and acepsoit.objid = acesobj.objid
                             and acepsoit.subid = acesobj.subid
    left outer join acedsoh on acedsoh.mandt = acepsoit.mandt
                                and acedsoh.comp = acepsoit.comp
                                and acedsoh.bukrs = acepsoit.bukrs
                                and acedsoh.objid = acepsoit.objid
                                and acedsoh.subid = acepsoit.subid
                                and acedsoh.date_to = '99991231'
    left outer join tacecomp on  acepsoit.comp = tacecomp.comp
    left outer join acac_objects on acac_objects.mandt = acesobj.mandt
                                and acac_objects.bukrs = acesobj.bukrs
                                and acac_objects.ref_key = acesobj.ref_key
                                and acac_objects.ref_subkey = acesobj.ref_subkey
{
  key acepsoit.mandt,
  key acepsoit.comp,
  key acepsoit.bukrs,
  key gjahr,
  key acepsoit.objid,
  key acepsoit.subid,
  key acrtype,
  key accrule,
  key docnr,
      valcum,
      valtbp,
      currency,
      transtype,
      effdate,
      podate,
      poper,
      poyear,
      runid,
      case when acepsoit.awkey <> '' and acepsoit.awkey <> 'NOT_RELEVANT' and acepsoit.awkey <> 'LEGACY' and acepsoit.awtyp = ''  then tacecomp.awtyp
      else acepsoit.awtyp
      end as awtyp,
      awkey,
      awsys,
      acepsoit.timestmp,
      reversal_doc,
      reversed_doc,
      cast( substring( awkey, 1, 10) as awref ) as awref,
      cast( substring( awkey, 11, 8) as aworg ) as aworg,
      acesobj.ref_key,
      acesobj.ref_subkey,
      acac_objects.acac_objtype,
      acedsoh.vality_from as life_start_date
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ACAC_OBJECTS",
"ACEDSOH",
"ACEPSOIT",
"ACESOBJ",
"TACECOMP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/