ACE_ACDOCA_MIG_ACCR

@AbapCatalog.sqlViewName: 'ACEV_MIG_ACCR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #X
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Get original source from ACDOCA'
@AbapCatalog.preserveKey:true

define view ACE_ACDOCA_MIG_ACCR
  as select from acdoca
{
  key rldnr,
  key rbukrs,
  key gjahr,
  key belnr,
  key docln,
      acrobjtype,
      acrlogsys,
      cast ( acritmtype as ace_itemtype ) as acritmtype,
      acrobj_id,
      acrsobj_id,
      cast( ( cast( acdoca.gjahr as abap.int4 ) - 1 ) as abap.char( 40 ) ) as pre_gjahr,
      slalittype,
      case slalittype
        when '09001' then wsl
        when '09002' then wsl
        when '09003' then (-1)*wsl
        when '09004' then (-1)*wsl
        when '09005' then wsl
      end                                                                  as valtbp,
      rwcur                                                                as currency,
      cast( case slalittype
        when '09001' then 'I'
        when '09002' then 'U'
        when '09003' then 'P'
        when '09004' then 'C'
        when '09005' then 'F'
      end as ace_transtype )                                               as transtype,
      bldat                                                                as effdate,
      budat                                                                as podate,
      poper,
      ryear                                                                as poyear,
      awtyp,
      concat( awref, aworg )                                               as awkey,
      awsys,
      timestamp,
      mig_source

}
where
       acrobj_id  <> ''
  and  acrsobj_id <> ''
  and  acrobjtype <> ''
  and  acritmtype <> ''
  and(
       slalittype =  '09001'
    or slalittype =  '09002'
    or slalittype =  '09003'
    or slalittype =  '09004'
    or slalittype =  '09005'
  )
  and mig_source = 'D'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ACDOCA"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/