R_WORKPERMITORDERTP

CDS View

Work Permit Assigned Orders

R_WORKPERMITORDERTP is a CDS View in S/4HANA. Work Permit Assigned Orders. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_WorkPermitOrder view_entity projection CONSUMPTION WorkPermitOrder
C_WorkPermitOrderTP view_entity projection CONSUMPTION Work Permit Assigned Orders 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Permit Assigned Orders'
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity R_WorkPermitOrderTP
  as select from I_WorkPermitOrder
  association        to parent R_WorkPermitTP        as _WorkPermit           on  $projection.WorkPermit = _WorkPermit.WorkPermit
  association [1..*] to R_WorkPermitOrderOperationTP as _MaintenanceOperation on  $projection.MaintenanceOrder = _MaintenanceOperation.MaintenanceOrder
                                                                              and $projection.WorkPermit       = _MaintenanceOperation.WorkPermit

{
  key MaintenanceOrderInternalID,
  key WorkPermitInternalID,      
      WorkPermit,
      @Consumption: {semanticObject: 'MaintenanceOrder'}
      MaintenanceOrder,
      MaintenanceOrderDesc,
      count( distinct _MaintenanceOperation.MaintOrderOperationCounter) as RowIndex,      
      MaintenancePlanningPlant,
      WorkPermitObjectType,
      WorkPermitOrderObjectType,
      MaintOrderRoutingNumber,
      MaintenanceOrderType,
      WrkPmtProcessingContext,
      MaintOrdCnctntdActvSystSts,      
      cast(' ' as abap.char( 4 ))                                       as MaintenanceOrderOperation,     
      /* Associations */
      _MaintenanceOrder,
      _WorkPermit,
      _MaintenanceOperation
}
group by
  MaintenanceOrderInternalID,
  WorkPermitInternalID,
  WorkPermit,
  MaintenanceOrder,
  MaintenanceOrderDesc,
  MaintenancePlanningPlant,
  WorkPermitObjectType,
  WorkPermitOrderObjectType,
  MaintOrderRoutingNumber,
  MaintenanceOrderType,
  WrkPmtProcessingContext,
  MaintOrdCnctntdActvSystSts
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKPERMITORDER",
"R_WORKPERMITORDEROPERATIONTP"
],
"ASSOCIATED":
[
"I_MAINTENANCEORDER",
"R_WORKPERMITORDEROPERATIONTP",
"R_WORKPERMITTP"
],
"BASE":
[
"I_WORKPERMITORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More