R_SOURCINGPROJECT

@ClientHandling.algorithm: #SESSION_VARIABLE

@AbapCatalog: { sqlViewName: 'RSRCGPROJ',
                compiler.compareFilter: true,
                preserveKey: true
}

@AccessControl.authorizationCheck: #MANDATORY

@ObjectModel:{
               representativeKey: 'SourcingProjectUUID',
               semanticKey: ['SourcingProject','SourcingProjectVersion'], 
               sapObjectNodeType.name: 'SourcingProject',  
               usageType: {
                 dataClass: #TRANSACTIONAL,
//               Service Quality A/B needed

                 serviceQuality: #A,
                 sizeCategory: #M
              }
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Sourcing Project'
define view R_SourcingProject
  as select from mmsrcgproj

  association [0..*] to R_SourcingProjectItem       as _SourcingProjectItem       on $projection.SourcingProjectUUID = _SourcingProjectItem.SourcingProjectUUID

  association [0..*] to I_SourcingProjectQuotation  as _SourcingProjectQuotation  on $projection.SourcingProjectUUID = _SourcingProjectQuotation.SourcingProjectUUID

  association [0..*] to I_SrcgProjAllowedCurrency   as _SrcgProjAllowedCurrency   on $projection.SourcingProjectUUID = _SrcgProjAllowedCurrency.SourcingProjectUUID

  association [0..*] to R_SrcgProjAllwdSuplrContact as _SrcgProjAllwdSuplrContact on $projection.SourcingProjectUUID = _SrcgProjAllwdSuplrContact.SourcingProjectUUID

  association [0..*] to I_SourcingProjectMilestone  as _SourcingProjectMilestone  on $projection.SourcingProjectUUID = _SourcingProjectMilestone.SourcingProjectUUID

  //foreign key associations

  association [0..1] to I_Currency                  as _DocumentCurrency          on $projection.DocumentCurrency = _DocumentCurrency.Currency
  association [0..1] to I_CompanyCode               as _CompanyCode               on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_MaterialGroup             as _MaterialGroup             on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_PurchasingGroup           as _PurchasingGroup           on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_PurchasingOrganization    as _PurchasingOrganization    on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  association [0..1] to I_SourcingProjectType       as _SourcingProjectType       on $projection.SourcingProjectType = _SourcingProjectType.SourcingProjectType
  association [0..1] to I_SourcingProjectPhase      as _SourcingProjectPhase      on $projection.SourcingProjectPhase = _SourcingProjectPhase.SourcingProjectPhase
  association [0..1] to I_SrcgProjLifecycleStatus   as _SrcgProjLifecycleStatus   on $projection.SrcgProjLifecycleStatus = _SrcgProjLifecycleStatus.SrcgProjLifecycleStatus

  association [0..1] to I_SrcgProjPubdSuplrListBP   as _SrcgProjPubdSuplrListBP   on $projection.SourcingProjectUUID = _SrcgProjPubdSuplrListBP.SourcingProjectUUID
  //tbd

  association [0..1] to I_UserContactCard           as _CreatedByUser             on $projection.CreatedByUser = _CreatedByUser.ContactCardID
  association [0..1] to I_UserContactCard           as _ChangedByUser             on $projection.LastChangedByUser = _ChangedByUser.ContactCardID
  association [0..1] to I_EmplContactCard           as _PurchaserResponsible      on $projection.PurchaserRespWorkAgreement = _PurchaserResponsible.PersonWorkAgreement
  association [0..1] to R_SourcingProject           as _SourceSourcingProject     on $projection.SourceSourcingProjectUUID = _SourceSourcingProject.SourcingProjectUUID
{
  key sourcingprojectuuid                 as SourcingProjectUUID,
      sourcingproject                     as SourcingProject,
      sourcingprojectversion              as SourcingProjectVersion,

      @ObjectModel.foreignKey.association: '_SourcingProjectType'
      sourcingprojecttype                 as SourcingProjectType,
      sourcingprojectname                 as SourcingProjectName,
      srcgprojlifecyclestatus             as SrcgProjLifecycleStatus,
      srcgprojapprovalstatus              as SrcgProjApprovalStatus,
      sourcingprojectphase                as SourcingProjectPhase,
      srcgprojrevisionsts                 as SrcgProjRevisionSts,
      srcgprojactvtnsts                   as SrcgProjActvtnSts,
      srcgprojpubgsts                     as SrcgProjPubgSts,

      sourcingsupplierlistuuid            as SourcingSupplierListUUID,

      cast(
           concat_with_space(sourcingprojectname,
                             concat('V',
                                    cast(sourcingprojectversion as abap.char(10))
                                    ),
                             1
          ) as vdm_srcgprojversionconcat) as SrcgProjVersionConcatenated,

      companycode                         as CompanyCode,
      purchasinggroup                     as PurchasingGroup,
      purchasingorganization              as PurchasingOrganization,
      mmsrcgproj.materialgroup            as MaterialGroup,

//      @Semantics.currencyCode: true

      @ObjectModel.foreignKey.association: '_DocumentCurrency'
      documentcurrency                    as DocumentCurrency,

//      @Semantics.amount.currencyCode: 'DocumentCurrency'

      srcgprojtotaltargetamount           as SrcgProjTotalTargetAmount,

      purchaserrespworkagreement          as PurchaserRespWorkAgreement,

      qtnlatestsubmissiondatetime         as QtnLatestSubmissionDateTime,

      @Semantics.user.lastChangedBy: true
      lastchangedbyuser                   as LastChangedByUser,
      @Semantics.user.createdBy: true
      createdbyuser                       as CreatedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime                  as LastChangeDateTime,

      @Semantics.systemDateTime.createdAt: true
      creationdatetime                    as CreationDateTime,

      incotermsclassification             as IncotermsClassification,
      incotermstransferlocation           as IncotermsTransferLocation,

      incotermsversion                    as IncotermsVersion,
      incotermslocation1                  as IncotermsLocation1,
      incotermslocation2                  as IncotermsLocation2,

      paymentterms                        as PaymentTerms,
      cashdiscount1days                   as CashDiscount1Days,
      cashdiscount2days                   as CashDiscount2Days,
      cashdiscount1percent                as CashDiscount1Percent,
      cashdiscount2percent                as CashDiscount2Percent,
      netpaymentdays                      as NetPaymentDays,

      /* @Semantics.amount.currencyCode: 'DocumentCurrency'
       @DefaultAggregation:#NONE
       targetamount                        as TargetAmount,*/

      srcgprojpubgdtetme                  as SrcgProjPubgDteTme,
      srcgprojcancdtetme                  as SrcgProjCancDteTme,
      srcgprojattchsareforbidden          as SrcgProjAttchsAreForbidden,
      srcgprojnotesareforbidden           as SrcgProjNotesAreForbidden,

      srcgprojfollowondocumentcat         as SrcgProjFollowOnDocumentCat,
      srcgprojfollowondocumenttype        as SrcgProjFollowOnDocumentType,
      purcontrvaliditystartdate           as PurContrValidityStartDate,
      purcontrvalidityenddate             as PurContrValidityEndDate,

      exchangeratetype                    as ExchangeRateType,

      sourcingorigin                      as SourcingOrigin, 
      sourcingscenario                    as SourcingScenario,     
      externalsourcingprojectref          as ExternalSourcingProjectRef,
      logicalsystem                       as LogicalSystem,
      shippinginstruction                 as ShippingInstruction,
      sourcesourcingprojectuuid           as SourceSourcingProjectUUID,
      procurementplanningbundleuuid       as ProcurementPlanningBundleUUID,
      centralpurchasecontract             as CentralPurchaseContract,
      sourcingprojectversioningrsn        as SourcingProjectVersioningRsn,
      srcgprojpaymenttermismanual         as SrcgProjPaymentTermIsManual,
      srcgprojearliestcndnseldate         as SrcgProjEarliestCndnSelDate,
      srcgprojcancellationrsn             as SrcgProjCancellationRsn,
      
      /* Associations */
      _SourcingProjectItem,
      _SourcingProjectQuotation,
      _SrcgProjAllowedCurrency,
      _SrcgProjAllwdSuplrContact,
      _SourcingProjectMilestone,
      //foreign key associations

      _CompanyCode,
      _MaterialGroup,
      _PurchasingGroup,
      _PurchasingOrganization,
      _DocumentCurrency,
      _SourcingProjectType,
      _SourcingProjectPhase,
      _SrcgProjPubdSuplrListBP,
      _SrcgProjLifecycleStatus,
      //tbd

      _CreatedByUser,
      _ChangedByUser,
      _PurchaserResponsible,
      _SourceSourcingProject
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MMSRCGPROJ"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_EMPLCONTACTCARD",
"I_MATERIALGROUP",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SOURCINGPROJECTMILESTONE",
"I_SOURCINGPROJECTPHASE",
"I_SOURCINGPROJECTQUOTATION",
"I_SOURCINGPROJECTTYPE",
"I_SRCGPROJALLOWEDCURRENCY",
"I_SRCGPROJLIFECYCLESTATUS",
"I_SRCGPROJPUBDSUPLRLISTBP",
"I_USERCONTACTCARD",
"R_SOURCINGPROJECTITEM",
"R_SRCGPROJALLWDSUPLRCONTACT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/