R_DIRECTACTIVITYALLOCATIONTP

CDS View

Direct Activity Allocation

R_DIRECTACTIVITYALLOCATIONTP is a CDS View in S/4HANA. Direct Activity Allocation. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_DirectActivityAllocation view_entity projection CONSUMPTION Direct Activity Allocation Header
C_DirectActivityAllocationTP view_entity projection CONSUMPTION Direct Activity Allocation
I_DirectActivityAllocationTP_2 view_entity projection TRANSACTIONAL Direct Activity Allocation - TP 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_CreatedByContactCard']
@EndUserText.label: 'Direct Activity Allocation'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.sapObjectNodeType.name: 'AccountingActivityAllocation'
@ObjectModel.usageType:{
    serviceQuality: #C,
    sizeCategory: #XXL,
    dataClass: #MIXED
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

define root view entity R_DirectActivityAllocationTP
  as select from R_DirectActivityAllocation as _Header

  composition [1..*] of R_DrctActivityAllocationItemTP    as _Item

  association [0..1] to I_ControllingArea              as _ControllingArea              on  $projection.ControllingAreaForEdit = _ControllingArea.ControllingArea

  association [0..1] to I_UserContactCard              as _CreatedByContactCard         on  $projection.AccountingDocCreatedByUser = _CreatedByContactCard.ContactCardID

  association [1..1] to R_CostAcctgDocStsDomainValTxt  as _ControllingDocumentStatusTxt on  $projection.ControllingDocumentStatus  = _ControllingDocumentStatusTxt.ControllingDocumentStatus
                                                                                        and _ControllingDocumentStatusTxt.Language = $session.system_language
                                                                                        
  association [1..1] to R_CostAcctgDocPostgTypeText    as _AllocationPostingTypeTxt     on  $projection.AllocationPostingType  = _AllocationPostingTypeTxt.AllocationPostingType
                                                                                        and _AllocationPostingTypeTxt.Language = $session.system_language
                                                                                                                                                             
  association [0..1] to I_ReferenceDocumentTypeText    as _ReferenceDocumentTypeText    on  $projection.ReferenceDocumentType   = _ReferenceDocumentTypeText.ReferenceDocumentType
                                                                                        and _ReferenceDocumentTypeText.Language = $session.system_language
                                                                                        
  association [0..1] to I_ControllingBusTransacTypeT   as _BusinessTransactionTypeText  on  $projection.ControllingBusTransacType = _BusinessTransactionTypeText.BusinessTransactionType
                                                                                        and _BusinessTransactionTypeText.Language = $session.system_language

  association [0..1] to I_BusTransactionCategoryText   as _BusTransactionCategoryText   on  $projection.BusinessTransactionCategory = _BusTransactionCategoryText.BusinessTransactionCategory
                                                                                        and _BusTransactionCategoryText.Language    = $session.system_language
  
  association [1..1] to I_AccountingDocumentTypeText   as _AccountingDocumentTypeText   on $projection.AccountingDocumentType = _AccountingDocumentTypeText.AccountingDocumentType
                                                                                        and _AccountingDocumentTypeText.Language = $session.system_language
  //association [1..1] to R_RepostCostAcctgCreatedByUser as _RepostCostAcctgCreatedByUser on  $projection.AccountingDocCreatedByUser = _RepostCostAcctgCreatedByUser.AccountingDocCreatedByUser 

{
  key FiscalYear,
  key ReferenceDocument,
  key ControllingArea,
  key ReferenceDocumentType,
  key ReferenceDocumentContext,
      
      @ObjectModel.editableFieldFor: 'FiscalYear'
      FiscalYear as FiscalYearForEdit,
      @ObjectModel.editableFieldFor: 'ReferenceDocument'
      ReferenceDocument as ReferenceDocumentForEdit,
      @ObjectModel.editableFieldFor: 'ControllingArea'
      ControllingArea as ControllingAreaForEdit,
      @ObjectModel.editableFieldFor: 'ReferenceDocumentType'
      ReferenceDocumentType as ReferenceDocumentTypeForEdit,
      @ObjectModel.editableFieldFor: 'ReferenceDocumentContext'
      ReferenceDocumentContext as ReferenceDocumentContextFoEd,

      AccountingDocumentHeaderText,
      DocumentDate,
      PostingDate,
      FiscalPeriod,
      FiscalYearPeriod,
      AccountingDocumentCreationDate,
      AccountingDocCreatedByUser,
      IsReversal,
      IsReversed,
      ControllingDocumentStatus,
      CtrlgOverheadStatusCriticality,
      AllocationPostingType,
      ExchangeRateDate,
      PredecessorReferenceDocument,
      ReversalReferenceDocument,
      ReversedReferenceDocument,
      SuccessorReferenceDocument,
      GlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      TotalAmountInGlobalCurrency,
      ControllingBusTransacType,
      BusinessTransactionCategory,
      AccountingDocumentType,
      cast('' as fis_gjahr_no_conv) as ReferenceFiscalYear,
      cast('' as costaccountingdocumentaction) as CostAccountingDocumentAction,
      cast('' as costacctgdocumentactionsource) as CostAcctgDocumentActionSource,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true       
      cast(0.0000000 as abp_lastchange_tstmpl) as LocalLastChangeDateTime,
      @Semantics.systemDateTime.lastChangedAt: true   
      cast(0.0000000 as vdm_lastchangedon) as LastChangeDateTime,
      
      /* Associations */
      _Item,
      _ControllingArea,
      _CreatedByContactCard,
      _ControllingDocumentStatusTxt, 
      _AllocationPostingTypeTxt,
      _BusinessTransactionTypeText,
      _ReferenceDocumentTypeText,
      _BusTransactionCategoryText,
      _AccountingDocumentTypeText
      //_RepostCostAcctgCreatedByUser


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_DIRECTACTIVITYALLOCATION"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPETEXT",
"I_BUSTRANSACTIONCATEGORYTEXT",
"I_CONTROLLINGAREA",
"I_CONTROLLINGBUSTRANSACTYPET",
"I_REFERENCEDOCUMENTTYPETEXT",
"I_USERCONTACTCARD",
"R_COSTACCTGDOCPOSTGTYPETEXT",
"R_COSTACCTGDOCSTSDOMAINVALTXT",
"R_DRCTACTIVITYALLOCATIONITEMTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More