R_CRDTMBUSINESSPARTNERTP

CDS View

Maintain Business Partner in Credit Mgmt

R_CRDTMBUSINESSPARTNERTP is a CDS View in S/4HANA. Maintain Business Partner in Credit Mgmt. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_CrdtMBusinessPartner view_entity projection CONSUMPTION Business Partners
C_CrdtMBusinessPartnerTP view_entity projection CONSUMPTION Maintain Business Partner in Credit Mgmt
I_CrdtMBusinessPartnerTP view_entity projection TRANSACTIONAL Business Partners - TP 
@EndUserText.label: 'Maintain Business Partner in Credit Mgmt'

//@AbapCatalog: { sqlViewName:            'RCRDTMBPTP',

//                compiler.compareFilter: true,

//                preserveKey:            true

//              }


@ObjectModel: { usageType: { dataClass:      #MASTER,
                             sizeCategory:   #L,
                             serviceQuality: #X
                           },
                semanticKey:       ['BusinessPartner'],  //Enable semantic (intend-based) navigation

                representativeKey:  'BusinessPartner',
                sapObjectNodeType.name: 'CreditMgmtBusinessPartner'
              }

@VDM: { viewType:                #TRANSACTIONAL,
        lifecycle.contract.type: #SAP_INTERNAL_API
      }

@AccessControl: { authorizationCheck:     #CHECK,
                  personalData.blocking:  #BLOCKED_DATA_EXCLUDED //data privacy, hide data from blocked business partners

                }

define root view entity R_CrdtMBusinessPartnerTP
  as select from I_CrdtMBusinessPartner 

  composition [0..*] of R_CreditMgmtAccountTP        as _CreditMgmtAccountTP // BO-internal association names seem to be subject to naming rules and ATC

  composition [0..*] of R_CrdtMBusPartnerRatingTP    as _CrdtMBusPartnerRatingTP
  composition [0..*] of R_CrdtMBPCollateralTP        as _CrdtMBPCollateralTP
  composition [0..*] of R_CrdtMBPCreditInsuranceTP   as _CrdtMBPCreditInsuranceTP
  composition [0..*] of R_CrdtMBPSpprsdCheckStepTP   as _CrdtMBPSpprsdCheckStepTP
  composition [0..*] of R_CrdtMBPNegativeEventTP     as _CrdtMBPNegativeEventTP
  composition [0..*] of R_CrdtMFmlaScoreEvalResultTP as _CrdtMFmlaScoreEvalResultTP


  association [0..*] to R_CrdtMBPRelationshipTP      as _CrdtMBPRelationshipTP  on  _CrdtMBPRelationshipTP.BusinessPartner = $projection.BusinessPartner

  association [0..*] to R_CreditDecisionDocumentTP   as _CreditDecisionDocument on  _CreditDecisionDocument.BusinessPartner = $projection.BusinessPartner
                                                                                and _CreditDecisionDocument.CaseSystemStatus != '009'

  association [0..*] to R_CreditLimitRequestTP       as _CreditLimitRequest     on  _CreditLimitRequest.BusinessPartner = $projection.BusinessPartner
                                                                                and _CreditLimitRequest.CaseSystemStatus != '009'

  association [1]    to I_RblsMgmtBPToCustomer       as _Customer            on _Customer.BusinessPartner = $projection.BusinessPartner

  // Extension Include View

  association [1]    to E_CrdtMBusinessPartner       as _Extension           on  $projection.BusinessPartner = _Extension.BusinessPartner


{
  key BusinessPartner,
      CrdtMgmtBusinessPartnerGroup,

      CreditWorthinessScoreValue,
      CrdtWrthnssScoreValdtyEndDate,
      CrdtWorthinessScoreLastChgDate,
      CalcdCrdtWorthinessScoreValue,

      CreditRiskClass,
      CalculatedCreditRiskClass,
      CreditRiskClassLastChangeDate,

      CreditCheckRule,
      CreditScoreAndLimitCalcRule,

      CustBusinessRelshpStartYear,

      BPLastChangeDateTime,

      MainCreditSegment,
      // used for integration of NotesReuse component

      cast( hextobin( '00000000000000000000000000000000' ) as nte_id ) as CrdtMAccountNoteUUID,

      /* Associations */
      _CreditMgmtAccountTP,
      _CrdtMBPRelationshipTP,
      _CrdtMBusPartnerRatingTP,
      _CreditDecisionDocument,
      _CreditLimitRequest,
      _CrdtMFmlaScoreEvalResultTP,

      _CrdtMBPCollateralTP,
      _CrdtMBPNegativeEventTP,
      _CrdtMBPSpprsdCheckStepTP,
      _CrdtMBPCreditInsuranceTP,

      _BusinessPartner,
      _Customer,
      _CreditMgmtBPAddress,

      _MainCreditSegment,
      _MainCreditSegmentAccount, // needed for limit and utilization


      _CrdtMBusPartnerGroup,
      _RiskClass,
      _CalcRiskClass,
      _CheckRule,
      _CalcRule
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CRDTMBUSINESSPARTNER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CRDTMBUSPARTNERGROUP",
"I_CRDTSCOREANDLMTCALCRULE",
"I_CREDITCHECKRULE",
"I_CREDITMANAGEMENTSEGMENT",
"I_CREDITMGMTBPADDRESS",
"I_CREDITRISKCLASS",
"I_RBLSMGMTBPTOCUSTOMER",
"R_CRDTMBPCOLLATERALTP",
"R_CRDTMBPCREDITINSURANCETP",
"R_CRDTMBPNEGATIVEEVENTTP",
"R_CRDTMBPRELATIONSHIPTP",
"R_CRDTMBPSPPRSDCHECKSTEPTP",
"R_CRDTMBUSPARTNERRATINGTP",
"R_CRDTMFMLASCOREEVALRESULTTP",
"R_CREDITDECISIONDOCUMENTTP",
"R_CREDITLIMITREQUESTTP",
"R_CREDITMGMTACCOUNT",
"R_CREDITMGMTACCOUNTTP"
],
"BASE":
[
"I_CRDTMBUSINESSPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More