R_COLLECTIONSINVOICETP
Collections Invoices
R_COLLECTIONSINVOICETP is a CDS View in S/4HANA. Collections Invoices. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_CollectionsInvoiceTP | view_entity | projection | CONSUMPTION | Collections Invoice |
@AccessControl: { authorizationCheck: #CHECK,
personalData: { blocking: #BLOCKED_DATA_EXCLUDED },
privilegedAssociations: [ '_CollectionsInvoiceNote',
'_LinkedDisputeCase',
'_LinkedPromiseToPay',
'_LinkedResubmission' ] }
@EndUserText: { label: 'Collections Invoices' }
@VDM: { viewType: #TRANSACTIONAL,
lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ObjectModel: { usageType: { serviceQuality: #X,
sizeCategory: #L,
dataClass: #TRANSACTIONAL },
semanticKey: [ 'CollectionSegment', 'CompanyCode', 'FiscalYear', 'AccountingDocument', 'AccountingDocumentItem' ],
representativeKey: 'AccountingDocument',
sapObjectNodeType: { name: 'JournalEntry' } }
define root view entity R_CollectionsInvoiceTP
as select from I_CollectionsInvoice
// VDM Associations
association [0..*] to I_CollectionsInvoiceNote as _CollectionsInvoiceNote on $projection.CompanyCode = _CollectionsInvoiceNote.CompanyCode
and $projection.AccountingDocument = _CollectionsInvoiceNote.AccountingDocument
and $projection.FiscalYear = _CollectionsInvoiceNote.FiscalYear
and $projection.AccountingDocumentItem = _CollectionsInvoiceNote.AccountingDocumentItem
// Accounting Document Item
association [0..1] to I_OperationalAcctgDocItem as _OperationalAcctgDocItem on $projection.CompanyCode = _OperationalAcctgDocItem.CompanyCode
and $projection.FiscalYear = _OperationalAcctgDocItem.FiscalYear
and $projection.AccountingDocument = _OperationalAcctgDocItem.AccountingDocument
and $projection.AccountingDocumentItem = _OperationalAcctgDocItem.AccountingDocumentItem
// Dispute Case
association [0..*] to I_CollsInvoiceRelatedDsputCase as _LinkedDisputeCase on $projection.CompanyCode = _LinkedDisputeCase.CompanyCode
and $projection.AccountingDocument = _LinkedDisputeCase.AccountingDocument
and $projection.FiscalYear = _LinkedDisputeCase.FiscalYear
and $projection.AccountingDocumentItem = _LinkedDisputeCase.AccountingDocumentItem
// Promise To Pay
association [0..*] to I_CollsInvoiceRelatedPrms2P as _LinkedPromiseToPay on $projection.CompanyCode = _LinkedPromiseToPay.CompanyCode
and $projection.AccountingDocument = _LinkedPromiseToPay.AccountingDocument
and $projection.FiscalYear = _LinkedPromiseToPay.FiscalYear
and $projection.AccountingDocumentItem = _LinkedPromiseToPay.AccountingDocumentItem
// Resubmission
association [0..*] to I_CollsInvoiceRelatedResubmsn as _LinkedResubmission on $projection.CompanyCode = _LinkedResubmission.CompanyCode
and $projection.AccountingDocument = _LinkedResubmission.AccountingDocument
and $projection.FiscalYear = _LinkedResubmission.FiscalYear
and $projection.AccountingDocumentItem = _LinkedResubmission.AccountingDocumentItem
// Payment Prediction
association [0..1] to I_CollsInvcPaytDelayPrediction as _CollsInvcPaytDelayPrediction on $projection.CompanyCode = _CollsInvcPaytDelayPrediction.CompanyCode
and $projection.AccountingDocument = _CollsInvcPaytDelayPrediction.AccountingDocument
and $projection.FiscalYear = _CollsInvcPaytDelayPrediction.FiscalYear
and $projection.AccountingDocumentItem = _CollsInvcPaytDelayPrediction.AccountingDocumentItem
// Extension Include View
association [1] to E_CollectionsInvoice as _Extension on $projection.CollectionSegment = _Extension.CollectionSegment
and $projection.CompanyCode = _Extension.CompanyCode
and $projection.AccountingDocument = _Extension.AccountingDocument
and $projection.FiscalYear = _Extension.FiscalYear
and $projection.AccountingDocumentItem = _Extension.AccountingDocumentItem
{
// VDM Fields
key CollectionSegment,
key CompanyCode,
key FiscalYear,
key AccountingDocument,
key AccountingDocumentItem,
Customer,
BranchAccount,
DocumentDate,
PostingDate,
DunningLevel,
LastDunningDate,
NetDueDate,
Reference1InDocumentHeader,
Reference2InDocumentHeader,
PaymentMethod,
FinancialAccountType,
cast ( OverdueDays as coll_pr_days_in_arrears ) as OverdueDays,
cast ( CashDiscount1Days as coll_pr_due_for_cashdisc_1 preserving type ) as CashDiscount1Days,
AmountInTransactionCurrency,
PaidAmount,
DunnedAmount,
OpenAmountInDocumentCurrency,
@Semantics: { amount: { currencyCode: 'TransactionCurrency' } }
cast ( CashDiscountAmtInTransacCrcy as coll_pr_cash_discount_amt ) as CashDiscountAmtInTransacCrcy,
TransactionCurrency,
PaymentDate,
DunningBlockingReason,
SpecialGLCode,
cast( OperationalGLAccount as coll_pr_gl_account preserving type ) as OperationalGLAccount,
FiscalPeriod,
BillingDocument,
PostingKey,
DocumentItemText,
ReferenceDocumentLogicalSystem,
LastDunningDurationInDays,
CaseStatus,
CaseStatusName,
CaseReason,
ReasonCodeName,
PromiseToPayStatus,
DisputeCase,
PromiseToPay,
NumberOfResubmissions,
NumberOfDaysSinceResubmission,
ArrangedAmount,
PromisedAmount,
cast( PromiseToPayLevel as coll_pr_p2p_level ) as PromiseToPayLevel,
PromiseToPayDueDate,
DisputedAmount,
CreditedAmount,
DocumentReferenceID,
ObjectKey,
Country,
ResubmissionUUID,
ResubmissionDueDate,
ResubmissionReason,
CaseUniqueID,
LatePaymentRisk,
// Exposed Associations
_CollectionSegment,
_CompanyCode,
_Customer,
_BranchAccount,
_BillingDocument,
_DunningBlockingReasonCode,
_SpecialGLCode,
_PostingKey,
_PromiseToPayStatus,
_LinkedDisputeCase,
_LinkedResubmission,
_LinkedPromiseToPay,
_CollectionsInvoiceNote,
_PaymentMethod,
_OperationalAcctgDocItem,
_CollsInvcPaytDelayPrediction
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COLLECTIONSINVOICE"
],
"ASSOCIATED":
[
"I_BILLINGDOCUMENT",
"I_COLLECTIONSEGMENT",
"I_COLLECTIONSINVOICENOTE",
"I_COLLSINVCPAYTDELAYPREDICTION",
"I_COLLSINVOICERELATEDDSPUTCASE",
"I_COLLSINVOICERELATEDPRMS2P",
"I_COLLSINVOICERELATEDRESUBMSN",
"I_COLLSPROMISETOPAYSTATUS",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_DUNNINGBLOCKINGREASONCODE",
"I_OPERATIONALACCTGDOCITEM",
"I_PAYMENTMETHOD",
"I_POSTINGKEY",
"I_SPECIALGLCODE"
],
"BASE":
[
"I_COLLECTIONSINVOICE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/