R_CNDNCONTRTYPE

CDS View

Condition Contract Type

R_CNDNCONTRTYPE is a CDS View in S/4HANA. Condition Contract Type. It contains 1 fields. 13 CDS views read from this table.

Used by 13 CDS view(s) 1 fields

CDS Views using this table (13)

ViewTypeJoinVDMDescription
C_CndnContrTypeExtCommsnCreate view from CONSUMPTION External Commissions Type for Creation
I_CndnContrPersCommsnVH view_entity inner COMPOSITE Condition Contracts for Internal Commissions
I_CndnContrSlsRbteStdVH view_entity inner COMPOSITE Condition Contracts for Sales Rebates
I_CndnContrSuplrRbteStdVH view_entity inner COMPOSITE Condition Contracts for Supplier Rebates
I_CndnContrType view from BASIC Condition Contract Type
P_CndnContrType_SettleVH view from BASIC
R_CndnContrTypeCustomerVH view_entity from COMPOSITE Condition Contract Types for Customers
R_CndnContrTypeExtSlsCommsnVH view_entity from COMPOSITE Condition Contract Types for External Sales Commissions
R_CndnContrTypePersCommsnVH view_entity from COMPOSITE Condition Contract Types for Internal Commissions
R_CndnContrTypeRoyaltyVH view_entity from COMPOSITE Condition Contract Types for Royalty Agreements
R_CndnContrTypeSlsRebateVH view_entity from COMPOSITE Condition Contract Types for Sales Rebates
R_CndnContrTypeSuplrRebateVH view_entity from COMPOSITE Condition Contract Types for Supplier Rebates
R_CndnContrTypeSupplierVH view_entity from COMPOSITE Condition Contract Types for Suppliers

Fields (1)

KeyField CDS FieldsUsed in Views
KEY CndnContrType CndnContrType 1 
@AbapCatalog: {
    sqlViewName: 'RWLFCOCOTYPE',
    compiler.compareFilter: true,
    preserveKey: true
    }
@EndUserText.label: 'Condition Contract Type'
@AccessControl: {
    authorizationCheck: #MANDATORY,
    privilegedAssociations: ['_Text'],
    personalData.blocking: #('TRANSACTIONAL_DATA')
    }
@ObjectModel: {
    representativeKey: 'CndnContrType',
    usageType: {
      dataClass:      #CUSTOMIZING,
      serviceQuality: #B,
      sizeCategory:   #S
      }
    }
@ClientHandling: {
    type: #INHERITED,
    algorithm: #SESSION_VARIABLE
    }
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #SAP_INTERNAL_API
    }
//@Analytics: {

//    dataCategory: #DIMENSION,

//    dataExtraction.enabled: false,

//    internalName: #LOCAL

//}

@Metadata: {
    ignorePropagatedAnnotations: true,
    allowExtensions: false
    }

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view R_CndnContrType
  as select from twcbcontrtype

  association [0..*] to R_CndnContrTypeText         as _Text                     on $projection.CndnContrType = _Text.CndnContrType
  association [0..1] to I_CndnContrTypeBlockUsage   as _CndnContrTypeBlockUsage  on $projection.CndnContrTypeBlockUsage = _CndnContrTypeBlockUsage.CndnContrTypeBlockUsage
  association [0..1] to I_CndnContrPartnerCat       as _CndnContrPartnerCat      on $projection.CndnContrPartnerCat = _CndnContrPartnerCat.CndnContrPartnerCat
  association [0..1] to I_CndnContrChangeability    as _CndnContrChangeability   on $projection.CndnContrChangeability = _CndnContrChangeability.CndnContrChangeability
  association [0..1] to R_BusVolFldCombnSet         as _BusVolFldCombnSet        on $projection.BusVolFldCombnSet = _BusVolFldCombnSet.BusVolFldCombnSet
  association [0..1] to I_CndnContrClassfctnType    as _CndnContrClassfctnType   on $projection.CndnContrClassfctnType = _CndnContrClassfctnType.CndnContrClassfctnType
  association [0..1] to I_CndnContrItemCategory     as _CndnContrItemCategory    on $projection.CndnContrItemCategory = _CndnContrItemCategory.CndnContrItemCategory
  association [0..1] to I_CndnContrEligibleCat      as _CndnContrEligibleCat     on $projection.CndnContrEligibleCat = _CndnContrEligibleCat.CndnContrEligibleCat
  association [0..1] to I_CndnContrSettlmtType      as _CndnContrSettlmtType     on $projection.CndnContrSettlmtType = _CndnContrSettlmtType.CndnContrSettlmtType
  association [0..1] to I_CndnContrPrtlSettlmtCat   as _CndnContrPrtlSettlmtCat  on $projection.CndnContrPrtlSettlmtCat = _CndnContrPrtlSettlmtCat.CndnContrPrtlSettlmtCat
  association [0..1] to I_CndnContrAccrRvslCat      as _CndnContrAccrRvslCat     on $projection.CndnContrAccrRvslCat = _CndnContrAccrRvslCat.CndnContrAccrRvslCat
  association [0..1] to I_CndnContrElmntBehaviorGrp as _ApplElmntBehaviorGrp     on $projection.ApplElmntBehaviorGrp = _ApplElmntBehaviorGrp.ApplElmntBehaviorGrp
  association [0..1] to I_CnConMnlSettlmtAllwncCat  as _CnConMnlSettlmtAllwncCat on $projection.CnConMnlSettlmtAllwncCat = _CnConMnlSettlmtAllwncCat.CnConMnlSettlmtAllwncCat

{
      @ObjectModel.text.association: '_Text'
  key contract_type                                                       as CndnContrType,
      bo_type                                                             as SAPObjectType,

      @ObjectModel.foreignKey.association: '_CndnContrTypeBlockUsage'
      type_block                                                          as CndnContrTypeBlockUsage,
      @ObjectModel.foreignKey.association: '_CndnContrPartnerCat'
      owner_type                                                          as CndnContrPartnerCat,
      @ObjectModel.foreignKey.association: '_CndnContrEligibleCat'
      eligible_type                                                       as CndnContrEligibleCat,
      @ObjectModel.foreignKey.association: '_CndnContrClassfctnType'
      category                                                            as CndnContrClassfctnType,
      @Semantics.booleanIndicator: true
      no_condition                                                        as CndnContrHasNoConditions,
      @ObjectModel.foreignKey.association: '_CndnContrSettlmtType'
      cast( rebate_type as wb2_rebate_type_fio preserving type )          as CndnContrSettlmtType,
      @ObjectModel.foreignKey.association: '_CndnContrChangeability'
      ui_change                                                           as CndnContrChangeability,
      @ObjectModel.foreignKey.association: '_BusVolFldCombnSet'
      busvolbase_type                                                     as BusVolFldCombnSet,
      @ObjectModel.foreignKey.association: '_CndnContrPrtlSettlmtCat'
      settl_part_type                                                     as CndnContrPrtlSettlmtCat,
      @ObjectModel.foreignKey.association: '_CndnContrItemCategory'
      contract_items                                                      as CndnContrItemCategory,
      @ObjectModel.foreignKey.association: '_CndnContrAccrRvslCat'
      accr_rev_type                                                       as CndnContrAccrRvslCat,
      @ObjectModel.foreignKey.association: '_ApplElmntBehaviorGrp'
      visibility_group                                                    as ApplElmntBehaviorGrp,
      cast( man_settl_docs as wb2_mnl_settlmt_allowance preserving type ) as CnConMnlSettlmtAllwncCat,


      /* Associations */
      _Text,
      _CndnContrTypeBlockUsage,
      _CndnContrPartnerCat,
      _CndnContrClassfctnType,
      _CndnContrChangeability,
      _BusVolFldCombnSet,
      _CndnContrItemCategory,
      _CndnContrEligibleCat,
      _CndnContrSettlmtType,
      _CndnContrPrtlSettlmtCat,
      _CndnContrAccrRvslCat,
      _ApplElmntBehaviorGrp,
      _CnConMnlSettlmtAllwncCat

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TWCBCONTRTYPE"
],
"ASSOCIATED":
[
"I_CNCONMNLSETTLMTALLWNCCAT",
"I_CNDNCONTRACCRRVSLCAT",
"I_CNDNCONTRCHANGEABILITY",
"I_CNDNCONTRCLASSFCTNTYPE",
"I_CNDNCONTRELIGIBLECAT",
"I_CNDNCONTRELMNTBEHAVIORGRP",
"I_CNDNCONTRITEMCATEGORY",
"I_CNDNCONTRPARTNERCAT",
"I_CNDNCONTRPRTLSETTLMTCAT",
"I_CNDNCONTRSETTLMTTYPE",
"I_CNDNCONTRTYPEBLOCKUSAGE",
"R_BUSVOLFLDCOMBNSET",
"R_CNDNCONTRTYPETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More