R_CAPROVIDERCONTRACTTP

CDS View

Contract Accounting Provider Contract

R_CAPROVIDERCONTRACTTP is a CDS View in S/4HANA. Contract Accounting Provider Contract. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_CAProviderContract view_entity projection CONSUMPTION Contract Accounting Provider Contract
C_CAProviderContractTP view_entity projection CONSUMPTION Contract Accounting Provider Contract 
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.sapObjectNodeType.name: 'ContrAcctgProviderContract'

@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Contract Accounting Provider Contract'

define root view entity R_CAProviderContractTP
  as select from I_CAProviderContractHeader

  composition [0..*] of R_CAProviderContractItemTP     as _CAProviderContractItem
  composition [0..*] of R_CAProviderContractTechRsceTP as _CAProviderContractTechRsce
  composition [0..*] of R_CAProviderContractExtRefTP   as _CAProviderContractExtRef

{

  key CAProviderContract,

      CAProviderContractName,

      BusinessPartner,

      CompanyCode,

      CreationDate,

      CreationTime,

      @Semantics.dateTime: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_FKK_VT_TMSTMP_FILTER_TRANSF'
      @Consumption.filter.selectionType: #INTERVAL
      cast(dats_tims_to_tstmp(CreationDate,
                              CreationTime,
                              abap_system_timezone($session.client, 'NULL'),
                              $session.client, 'NULL') as vdm_creationdatetime) as CreationDateTime,

      CreatedByUser,

      LastChangeDate,

      LastChangeTime,

      @Semantics.dateTime: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_FKK_VT_TMSTMP_FILTER_TRANSF'
      @Consumption.filter.selectionType: #INTERVAL
      cast(dats_tims_to_tstmp(LastChangeDate,
                              LastChangeTime,
                              abap_system_timezone($session.client, 'NULL'),
                              $session.client, 'NULL') as vdm_lastchangedon)    as LastChangeDateTime,

      LastChangedByUser,

      IsMarkedForDeletion,

      CAProviderContractExtReference,
      
      @Semantics.timeZoneReference: 'TimeZoneID'
      CAPrvdrContrStartDateTime,

      @Semantics.timeZoneReference: 'TimeZoneID'
      CAPrvdrContrEndDateTime,

      CAAuthorizationGroup,
      
      @Semantics.timeZone: true
      TimeZoneID,

      CAProviderContractCategory,

      CAProviderContractMigrtnStatus,

      CAProviderContractType,

      CAProviderContractStatus,

      CAProviderContractSender,

      PrvdrContrEarliestEndDateTime,

      MinNrOfMonthsForContractPeriod,

      NrOfMonthsForContractRenewal,

      NrOfDaysForContrNoticePeriod,

      @Feature: 'BF:UTI_INVOICING'
      BudgetBillingPlanType,

      /* association */
      _CAProviderContractItem,
      _CAProviderContractTechRsce,
      _CAProviderContractExtRef,

      _BusinessPartner,
      _CompCode,
      _ProviderContractType,
      _ProviderContractStatus,
      _ProviderContractSender,
      _ProviderContractCategory,
      _CAAuthorizationGroup,
      _CreatedByUser,
      _LastChangedByUser,
      _TimeZone

}

where CAProviderContractCategory = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CAPROVIDERCONTRACTHEADER"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CAAUTHORIZATIONGROUP",
"I_COMPANYCODE",
"I_PROVIDERCONTRACTCATEGORY",
"I_PROVIDERCONTRACTSENDER",
"I_PROVIDERCONTRACTSTATUS",
"I_PROVIDERCONTRACTTYPE",
"I_TIMEZONE",
"I_USER",
"R_CAPROVIDERCONTRACTEXTREFTP",
"R_CAPROVIDERCONTRACTITEMTP",
"R_CAPROVIDERCONTRACTTECHRSCETP"
],
"BASE":
[
"I_CAPROVIDERCONTRACTHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More