R_BUDGETPERIODCORETP

CDS View

Budget Period in Core using RAP

R_BUDGETPERIODCORETP is a CDS View in S/4HANA. Budget Period in Core using RAP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_BudgetPeriodCore view_entity projection COMPOSITE Budget Period 
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Budget Period in Core using RAP'
@ObjectModel.usageType: { 
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #MASTER
}
@ObjectModel.sapObjectNodeType.name: 'BudgetPeriod'
@Metadata.ignorePropagatedAnnotations:true  
define root view entity R_BudgetPeriodCoreTP
  as select from I_BudgetPeriod as budgetpd
  composition [0..*] of R_BudgetPeriodCoreTextTP as _Text
  association [0..1] to E_BudgetPeriod as _Extension    on $projection.BudgetPeriod = _Extension.BudgetPeriod
  association [0..1] to I_User         as _user_created on $projection.CreatedByUser = _user_created.UserID
  association [0..1] to I_User         as _user_changed on $projection.LastChangedByUser = _user_changed.UserID
{

      
  key budgetpd.BudgetPeriod,
      @Semantics.businessDate.from: true
      budgetpd.ValidityStartDate,
      @Semantics.businessDate.to: true
      budgetpd.ValidityEndDate,
      budgetpd.BudgetPeriodExpirationDate,
      budgetpd.BudgetPeriodReversalDate,
      budgetpd.BudgetPeriodAuthznGrp,
      @Semantics.user.createdBy: true
      budgetpd.CreatedByUser,
      case
            when _user_created.UserDescription is initial then CreatedByUser
            else _user_created.UserDescription end                           as CreatedByUserDescription,
      budgetpd.CreationDate,
     @Semantics.user.lastChangedBy: true
      budgetpd.LastChangeUser                                                as LastChangedByUser,
      case
       when _user_changed.UserDescription is initial then LastChangeUser
       else _user_changed.UserDescription end                                as LastChangedByUserDescription,
      @Semantics.systemDate.lastChangedAt: true
      budgetpd.LastChangeDate,
      budgetpd.BudgetPeriodPeriodicity,
      budgetpd._FundPeriodicity,
      budgetpd._Text[1:Language = $session.system_language].BudgetPeriodName as BudgetPeriodName,
      _Text

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUDGETPERIOD",
"I_BUDGETPERIODTEXT",
"I_USER"
],
"ASSOCIATED":
[
"I_FUNDPERIODICITY",
"R_BUDGETPERIODCORETEXTTP"
],
"BASE":
[
"I_BUDGETPERIOD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More