R_BKRELSHPDOCACCTSELECTIONTP

CDS View

Bank Account Selections of Bank Document

R_BKRELSHPDOCACCTSELECTIONTP is a CDS View in S/4HANA. Bank Account Selections of Bank Document. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_BkRelshpDocAcctSelectionTP view_entity projection CONSUMPTION Bank Account Selections of Bank Doc 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Bank Account Selections of Bank Document'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM: { usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ],
        viewType:  #TRANSACTIONAL,
        lifecycle.contract.type: #SAP_INTERNAL_API }
define view entity R_BkRelshpDocAcctSelectionTP as select from I_BkRelshpDocBkAcctSelection
association        to parent R_BankRelationshipDocTP as _BankRelationshipDocument        on  $projection.BankRelationshipDocumentUUID = _BankRelationshipDocument.BankRelationshipDocumentUUID
association [0..*] to I_BkRelshpDocSelFieldText  as _BkRltnDocSelectionFieldText  on $projection.BkRltnDocBkAcctSelectionField = _BkRltnDocSelectionFieldText.BkRltnDocBkAcctSelectionField
{
  
  key BkRltnDocBkAcctSelectionUUID,
  key BankRelationshipDocumentUUID,
      BkRltnDocBkAcctSelectionField,
      BkRltnDocBkAcctSelectionSign,
      BkRltnDocBkAcctSelectionOption,
      BkRltnDocBkAcctSelLowValue,
      BkRltnDocBkAcctSelHighValue,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.lastChangedBy: true  
      LastChangedByUser,
      @Semantics.systemDateTime.localInstanceLastChangedAt:true
      LocalLastChangeDateTime,
      
      // Indicator for context dependent value help

      case when BkRltnDocBkAcctSelectionField = 'BankAccountCurrency' then cast ( 'X' as abap_boolean preserving type )
      else cast ( ' ' as abap_boolean preserving type ) end                                        as SelectionFieldIsCurrency,
      
      case when BkRltnDocBkAcctSelectionField = 'BankCountry' or BkRltnDocBkAcctSelectionField = 'CompanyCodeCountry' then cast ( 'X' as abap_boolean preserving type )
      else cast ( ' ' as abap_boolean preserving type ) end                                        as SelectionFieldIsCountry,
      
      case when BkRltnDocBkAcctSelectionField = 'CompanyCode' then cast ( 'X' as abap_boolean preserving type )
      else cast ( ' ' as abap_boolean preserving type ) end                                        as SelectionFieldIsCompanyCode,
      
      case when BkRltnDocBkAcctSelectionField = 'Bank' then cast ( 'X' as abap_boolean preserving type )
      else cast ( ' ' as abap_boolean preserving type ) end                                        as SelectionFieldIsBankKey,
      
      case when BkRltnDocBkAcctSelectionField = 'BankGroup' then cast ( 'X' as abap_boolean preserving type )
      else cast ( ' ' as abap_boolean preserving type ) end                                        as SelectionFieldIsBankGroup,
      
      // Text field for selection field

      cast ( '' as fclm_brm_doc_description ) as BkRltnDocBkAcctSelLowText,
      cast ( '' as fclm_brm_doc_description ) as BkRltnDocBkAcctSelHighText,
      
      //Associations

      _BankRelationshipDocument,     
      _BkRltnDocSelectionFieldText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BKRELSHPDOCBKACCTSELECTION"
],
"ASSOCIATED":
[
"I_BKRELSHPDOCSELFIELDTEXT",
"R_BANKRELATIONSHIPDOCTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More