R_BATCHCHARACTERISTICTP

CDS View

Batch Characteristic

R_BATCHCHARACTERISTICTP is a CDS View in S/4HANA. Batch Characteristic. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_BatchCharc view_entity projection CONSUMPTION Batch Characteristics
I_BatchCharacteristicTP_2 view_entity projection TRANSACTIONAL Batch Characteristic 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@EndUserText.label: 'Batch Characteristic'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view entity R_BatchCharacteristicTP
  as select from I_ClfnObjectCharcForKeyDate(P_KeyDate: $session.system_date) as ObjectCharc
    inner join   I_BatchDistinct                                              as Batch on ObjectCharc.ClfnObjectInternalID = Batch.ClfnObjectInternalID

  composition [0..*] of R_BatchCharacteristicValueTP as _BatchCharacteristicValueTP

  association to parent R_BatchTP as _BatchTP on  $projection.Material              = _BatchTP.Material
                                              and $projection.BatchIdentifyingPlant = _BatchTP.BatchIdentifyingPlant
                                              and $projection.Batch                 = _BatchTP.Batch
                        
{
  key Batch.Material,
  key Batch.Plant as BatchIdentifyingPlant,
  key Batch.Batch,
  key ObjectCharc.CharcInternalID,

      case when Batch.LastChangeDateTime = 0 or Batch.LastChangeDateTime is null
        then cast('20170331120000' as lobm_last_changed)
        else Batch.LastChangeDateTime
      end         as LastChangeDateTime,

      _BatchTP,
      _BatchCharacteristicValueTP,
      
      --Needed for DCL inheritance
      @Consumption.hidden: true
      ObjectCharc.ClassInternalID,
      @Consumption.hidden: true
      ObjectCharc.ClassType,
      @Consumption.hidden: true
      ObjectCharc._Characteristic,
      @Consumption.hidden: true
      ObjectCharc._Class
}
where ObjectCharc.ClfnObjectType  = 'O'
  and (ObjectCharc.ClfnObjectTable = 'MCH1' or ObjectCharc.ClfnObjectTable = 'MCHA')
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BATCHDISTINCT",
"I_CLFNOBJECTCHARCFORKEYDATE"
],
"ASSOCIATED":
[
"I_CLFNCHARACTERISTICFORKEYDATE",
"I_CLFNCLASSFORKEYDATE",
"R_BATCHCHARACTERISTICVALUETP",
"R_BATCHTP"
],
"BASE":
[
"I_CLFNOBJECTCHARCFORKEYDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More