R_ACMAPPLICATIONOVERVIEWDETTP

CDS View

Transaction Processing View App Overview

R_ACMAPPLICATIONOVERVIEWDETTP is a CDS View in S/4HANA. Transaction Processing View App Overview. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_ACMAppDocOverview view_entity projection CONSUMPTION Application Document Overview 
@AbapCatalog.sqlViewName: 'RACMAPPLDOC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel:{
              usageType: {
                dataClass: #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory: #L
              }
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Transaction Processing View App Overview'
define root view R_ACMApplicationOverviewDetTP

  as select from I_ACMApplicationOverviewDet
  composition [*] of R_ACMAppDocDPQSEvalDetTP    as _DPQSEvaluation
  composition [*] of R_ACMAppDocToleranceEvalTP  as _ToleranceEval
  composition [*] of R_ACMAppDocOptionalityDetTP as _OptionalityDet
  composition [*] of R_ACMAppDocStorageDetTP     as _StorageDet
  composition [*] of R_ACMAppDocWarehouseDetTP   as _WarehouseDet
  composition [*] of R_ACMAppDocQualityTP        as _Quality
  composition [*] of R_ACMAppDocUoMConversionTP  as _AppDocUoM
{
  key ApplicationDocument,
  key ReferenceApplicationItem,
      ContractApplicationUUID,
      ContractApplicationVersion,
      ApplicationDocType,
      ReferenceApplicationSide,
      ReferenceApplicationSubItem,
      DeliveryDate,
      TradingContractNumber,
      TradingContractItem,
      LoadDataCaptureObjId,
      ACMLoadDataCaptureEventKeyUUID,
      EventDate,
      Plant,
      BillOfLading,
      BillOfLadingDate,
      Material,
      Commodity,
      ACMScaleTicketNumber,
      ACMAppDocStatus,
      ACMAppDocSettlementStatus,
      ACMAppDocStorageStatus,
      Counterparty,
      ApplDocumentCreatedBy,
      ApplDocumentCreatedByName,
      ApplicationItemCreatedOnDate,
      ApplDocumentChangedBy,
      ApplDocumentChangedByName,
      ApplicationItemChangedOnDate,
      TradingContractType,
      CompanyCode,
      SalesOrganization,
      DistributionChannel,
      Division,
      PurchasingOrganization,
      PurchasingGroup,
      // LDC Unconverted Qty - Item_qty from the root item

      @Semantics.quantity.unitOfMeasure: 'ACMAppDocBaseUoM'
      ACMLoadDataCapQuantity,
      @Semantics.unitOfMeasure: true
      UnitOfMeasure,
      /* uom of LDC unconverted qty */
      // LDC Converted Qty

      @Semantics.quantity.unitOfMeasure: 'ACMAppDocBaseUoM'
      ACMLoadDataCaptureConvertQty,
      @Semantics.quantity.unitOfMeasure: 'ACMAppDocBaseUoM'
      ACMDecimalGrossQuantity,
      @Semantics.quantity.unitOfMeasure: 'ACMAppDocBaseUoM'
      ACMNetQuantity,
      @Semantics.quantity.unitOfMeasure: 'ACMAppDocBaseUoM'
      ACMOverfillQuantity,
      @Semantics.quantity.unitOfMeasure: 'ACMAppDocBaseUoM'
      ACMUnderFillQuantity,
      @Semantics.quantity.unitOfMeasure: 'ACMLoadDataCaptureUoM'
      ACMLoadDtaCaptureGrossQuantity,
      @Semantics.quantity.unitOfMeasure: 'ACMAppDocBaseUoM'
      ACMLoadDtaCaptrCnvrtdGrssQty,
      @Semantics.unitOfMeasure: true
      ACMAppDocBaseUoM,
      ACMApplOvwSpotFlag,
      ACMApplOvwSpotFlagDesc,
      ACMLoadDataCaptureUoM,

      //Association to child - DPQS

      _DPQSEvaluation,
      //Association to child - Tolerance Evaluation

      _ToleranceEval,
      //Association to child - Optionality Evaluation

      _OptionalityDet,
      //Association to child - Storage Details

      _StorageDet,
      //Association to child - Warehouse Details

      _WarehouseDet,
      //Association to child - Quality

      _Quality,
      //Association to child - UoM Quantity conversion

      _AppDocUoM
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACMAPPLICATIONOVERVIEWDET"
],
"ASSOCIATED":
[
"R_ACMAPPDOCDPQSEVALDETTP",
"R_ACMAPPDOCOPTIONALITYDETTP",
"R_ACMAPPDOCQUALITYTP",
"R_ACMAPPDOCSTORAGEDETTP",
"R_ACMAPPDOCTOLERANCEEVALTP",
"R_ACMAPPDOCUOMCONVERSIONTP",
"R_ACMAPPDOCWAREHOUSEDETTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More