P_WIPREVDETAILBASIC

@AbapCatalog.sqlViewName: 'PDLIWIPRVBS'
@ClientDependent: true
@AbapCatalog.compiler.compareFilter: true
@VDM.private:true //= @VDM.private

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'WIP revenue details from DIP data'


@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

//Used by view P_Projectwiprevdetlbasic

//Selects from ad01dli, ad01dlisf and ad01wip_rev


define view P_Wiprevdetailbasic as

select cast ( a.poper as fis_jahrper_conv preserving type ) as  PostingPeriod,
       a.twaer as TransactionCurrency,
       a.meinh as UnitOfMeasure,
       a.kstar as CostElement,
       a.kostl as CostCenter,
       a.lstar as CostCtrActivityType,
       a.matnr as Material,
       a.prznr as BusinessProcess,
       a.pernr as PersonnelNumber,
       z.EmployeeFullName as EmployeeFullName,
       a.manual as ManualInvoiceItem,
       a.prctr as ProfitCenter,
       a.objnr as ControllingObject,
       a.belnr as ControllingDocument,
       a.docln as ControllingDocumentItem,
       a.bpcat as BillingDocumentCategory,
       a.billingplanitemusage as BillingPlanItemUsage,
       a.work_item_id as WorkItem,
       a.serv_org as EngagementProjectServiceOrg,
       a.bemot as AccountingIndicatorCode,
       a.rsrce as CostAnalysisResource,
       a.prs_work_period as CalendarMonth,
       c.ra_versn as ResultAnalysisVersion,
       cast ( c.rv_waers as waerk ) as SalesDocumentItemCurrency,
       c.hwaer as ControllingObjectCurrency,
       c.kwaer as ControllingAreaCurrency,
       cast ( c.rv_waers as pro_dw_revsim_waers ) as TransacCurrencyInvoiceSimln,
       c.rev_kstar as RevenueCostElement,
       c.rev_matnr as SoldMaterial,
       c.ra_objnr as ResultAnalysisControllingObj,
       c.ra_abgsl as ResultAnalysisInternalID,
       cast( sum(c.rev_wtg) as ad01rev_wtg ) as TransacCrcyInvoiceSimlnAmt,
       cast( sum(c.rev_wog) as ad01rev_wog ) as ObjectCrcyInvoiceSimlnAmt,
       cast( sum(c.rev_wkg) as ad01rev_wkg ) as CtrlgAreaCrcyInvoiceSimlnAmt
  from ad01dli as a
  inner join ad01wip_rev as c on a.dlinr = c.dlinr
  left outer join P_Projwipdetpernr as z on z.PersonnelNumber = a.pernr
  group by a.poper,
           a.twaer,
           a.meinh,
           a.kstar,
           a.kostl,
           a.lstar,
           a.matnr,
           a.prznr,
           a.pernr,
           a.manual,
           a.prctr,
           a.objnr,
           a.belnr,
           a.docln,
           a.bpcat,
           a.billingplanitemusage,
           a.work_item_id,
           a.serv_org,
           a.bemot,
           a.rsrce,
           a.prs_work_period,
           c.rv_waers,
           c.hwaer,
           c.kwaer,
           c.ra_versn,
           c.rv_waers,
           c.rev_kstar,
           c.rev_matnr,
           c.ra_objnr,
           c.ra_abgsl,
           z.EmployeeFullName
;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PROJWIPDETPERNR",
"AD01DLI",
"AD01WIP_REV"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/