P_SRVCTRANSACTIONISSUEITEMC003

@AbapCatalog:
    {
        sqlViewName: 'PSRVCISSITMC003',
        compiler.compareFilter: true,
        preserveKey: true,
        dataMaintenance: #DISPLAY_ONLY
    }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM:
    {
        private: true,
        viewType: #COMPOSITE
    }
define view P_SrvcTransactionIssueItemC003
  as select distinct from I_ServiceDocumentItemEnhcd     as Item

    inner join            I_ServiceDocumentItemSuccssr_2 as Link      on  Link.ServiceDocumentItemObjectType  = Item.ServiceDocumentItemObjectType
                                                                      and Link.ServiceDocumentItemCharUUID    = Item.ServiceDocumentItemCharUUID
                                                                      and Link.ServiceDocumentItmRelationType = 'VONA'           // Predecessor/Sucessor Relationship

    inner join            I_ServiceDocumentItemEnhcd     as Successor on  Successor.ServiceDocumentItemObjectType = Link.ServiceDocItmSuccssrBusObjType
                                                                      and Successor.ServiceDocumentItemCharUUID   = Link.ServiceDocItmSuccssrCharUUID
                                                                      and Successor.ServiceObjectType             = 'BUS2000117' // Successor is a service confirmation

                                                                      and Successor.ServiceDocumentItemIsOpen     = 'X'          // Successor Item is open

{
  key Item.ServiceObjectType,
  key Item.ServiceDocument,
  key Item.ServiceDocumentItem,
  key cast ( 'C001' as crms4_service_issue )   as CustMgmtIssue,
  key cast ( 'C003' as crms4_srvc_conf_issue ) as SrvcConfIssue,

      Item._ServiceDocument.ServiceDocumentType,
      Item._ServiceDocument.SoldToPartyCountry as Country,
      Item._ServiceDocument.Region,
      Item._ServiceDocument.ServiceRisk,
      Item._ServiceDocument.ServiceDocumentProblemCategory,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      Item._ServiceDocument.TransactionCurrency,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      Item.ServiceDocItemGrossAmount           as SrvcOrdGrossAmount,
      Item.Industry,

      // Organization Unit fields

      Item.ServiceOrganization,
      Item.SalesOrganization,
      Item.SalesOffice,
      Item.SalesGroup,
      Item.DistributionChannel,
      Item.Division,

      // Sales related fields (ex. BP)

      Item.SoldToPartyCountry,
      Item.SoldToPartyRegion,
      Item.SoldToParty,
      Item.ResponsibleEmployee,
      Item.ContactPerson,
      Item.ServiceTeam,
      Item.ServiceEmployee,

      // Status fields

      Item.ServiceDocItemRejectionReason,
      Item.ServiceDocumentItemStatus,
      Item.ServiceDocumentItemHasError,
      Item.BillingBlockReason,
      Item.ServiceDocItemBillingStatus,
      Item.SrvcDocItmIsReleasedForBilling,
      Item.SrvcDocItemTransferStatus,
      Item.RefInHouseRepairIsExisting,

      // Various attributes

      Item.RequestedServiceStartDateTime,
      Item.RequestedServiceEndDateTime,
      Item.PlannedServiceStartDateTime,
      Item.PlannedServiceEndDateTime,

      //SLA Dueby

      Item.SrvcDocItemSLADueByDateTime,
      Item.ResponseProfile,
      Item.ServiceProfile,
      Item.ServiceFirstResponseByDateTime,

      Item.RefBusinessSolutionOrder,
      Item.RefBusinessSolutionOrderItem,

      Item._ServiceDocument._TransactionCurrency
}
where
      Item.ServiceObjectType                           =  'BUS2000116' // Service Order

  and Item._ServiceDocument.ServiceDocumentIsRejected  <> 'X'          // Service transaction is not rejected

  and Item._ServiceDocument.ServiceDocumentIsReleased  =  'X'          // Service Order is Released

  and Item._ServiceDocument.ServiceDocumentIsQuotation <> 'X'          // Service Order is not a quotation

  and Item.RefInHouseRepairIsExisting                  is initial
  and Item._ServiceDocument.ServiceDocumentTemplateType = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTENHCD",
"I_SERVICEDOCUMENTITEMENHCD",
"I_SERVICEDOCUMENTITEMSUCCSSR_2"
],
"ASSOCIATED":
[
"I_CURRENCY"
],
"BASE":
[
"I_SERVICEDOCUMENTENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/