P_REALTIMEMFGORDER

CDS View

P_REALTIMEMFGORDER is a CDS View in S/4HANA. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
P_RealTimeMfgOrderPostedKPI view from COMPOSITE
P_RealTimeMfgOrderToBePostKPI1 view from COMPOSITE 
@AbapCatalog.sqlViewName: 'PRTMORD'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'Event-based Order'

@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel.representativeKey: 'OrderID'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.preserveKey:true

define view P_RealTimeMfgOrder
  with parameters
    P_FiscalPeriodEndDate      : budat
  as select from           P_RealTimeMfgOrder1            as _Order
    inner join             P_RealTimeMfgReleasedOrder     as _Status      on _Status.ControllingObject = _Order.ControllingObject
    left outer to one join P_EvtBsdDistrPostgRule         as _PostingRule on _PostingRule.OrderID = _Order.OrderID
    left outer to one join R_EventBasedResultAnalysisKey  as _RAKey       on _RAKey.ResultAnalysisInternalID = _Order.ResultsAnalysisKey

{
  key _Order.OrderID,
      _Order.OrderDescription,
      _Order.ControllingObject,
      _Order.OrderType,
      _Order.OrderCategory,
      _Order.ControllingArea,
      _Order.CompanyCode,

      _Order.Plant,
      _Order.ProfitCenter,
      _Order.ResultsAnalysisKey,

      _Order.ActualReleasedDate,
      _Order.TechCompDate,
      _Order.MfgOrderHasMultipleItems,
      _PostingRule.RcvrObjectType,
      _RAKey.WIPIsForNonMaterialReceiver,

      _Order.Material,
      _Order.ProductionUnit,

     // _PeriodForCC.FiscalPeriodEndDate,


      // for joint-produciton ordr, the order's delivery date is determined from the latest delivery date of all items

       _Order.MaxDeliveryDate as DeliveryDate,

      _Order.RealTimeVarianceIsActive,

      // if the order has both DLV(I0012) and TECO(I0045) statues, TECO would be retrieved but DLV takes priority than TECO

      case when _Order.IsCompletelyDelivered = 'X'
                and _Order.MaxDeliveryDate <= $parameters.P_FiscalPeriodEndDate then 'I0012' //Delivered

           when _Order.TechCompDate is not initial
                and _Order.TechCompDate <= $parameters.P_FiscalPeriodEndDate then 'I0045'    //TECO         

           else 'I0002' // Open

      end                      as StatusCode

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_EVTBSDDISTRPOSTGRULE",
"P_REALTIMEMFGORDER1",
"P_REALTIMEMFGRELEASEDORDER",
"R_EVENTBASEDRESULTANALYSISKEY"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More