P_RU_VATRETURNGENERALSECTION2

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'PRUVATRETGS2'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_RU_VATReturnGeneralSection2
  with parameters
    P_Date : datum

  as select from           P_RU_VATReturnGeneralSection1 as VatReturnGS

  //supplier data for section 2

    left outer to one join P_RU_SuplrCustAccDocItem      as BusinessPartnerItem on  BusinessPartnerItem.CompanyCode          = VatReturnGS.CompanyCode
                                                                                and BusinessPartnerItem.AccountingDocument   = VatReturnGS.SourceDocument
                                                                                and BusinessPartnerItem.FiscalYear           = VatReturnGS.SourceDocumentFiscalYear
                                                                                and BusinessPartnerItem.FinancialAccountType = 'K'
                                                                                and VatReturnGS.RU_VATReturnSectionType      = '2'

    left outer to one join I_RU_SupplierData             as SupplierData        on SupplierData.Supplier = BusinessPartnerItem.Supplier

    left outer to one join P_RU_SupplierOKTMOSingle      as SupplierOKTMO       on SupplierOKTMO.Supplier = SupplierData.Supplier

    left outer to one join P_RU_RptCategoryParamOnDate(
                           P_Date: $parameters.P_Date)   as RptgEntityCfg       on  RptgEntityCfg.StatryRptgEntity      = VatReturnGS.StatryRptgEntity
                                                                                and RptgEntityCfg.StatryRptCategory     = VatReturnGS.StatryRptCategory
                                                                                and RptgEntityCfg.ParameterName         = 'OKTMO'
                                                                                and VatReturnGS.RU_VATReturnSectionType = '2'

{
  VatReturnGS.CompanyCode,
  VatReturnGS.AccountingDocument,
  VatReturnGS.FiscalYear,
  VatReturnGS.TaxItem,
  VatReturnGS.PostingDate,
  VatReturnGS.TaxReportingDate,
  VatReturnGS.DocumentDate,
  VatReturnGS.IsReversal,
  VatReturnGS.IsReversed,
  VatReturnGS.CompanyCodeCurrency,
  VatReturnGS.Currency,
  VatReturnGS.BusinessTransactionType,
  VatReturnGS.AccountingDocumentType,

  VatReturnGS.TaxCode,
  VatReturnGS.DebitCreditCode,
  VatReturnGS.Sign,
  VatReturnGS.TransactionTypeDetermination,
  case when VatReturnGS.Sign = '+'
       then VatReturnGS.TaxBaseAmountInCoCodeCrcy
       else -VatReturnGS.TaxBaseAmountInCoCodeCrcy
  end                                                                                as TaxBaseAmountInCoCodeCrcy,
  case when VatReturnGS.Sign = '+'
       then VatReturnGS.TaxAmountInCoCodeCrcy
       else -VatReturnGS.TaxAmountInCoCodeCrcy
  end                                                                                as TaxAmountInCoCodeCrcy,

  // Section 2 - Supplier data

  coalesce( BusinessPartnerItem.Supplier, '')                                        as Supplier,
  SupplierData.BusinessPartner,
  SupplierData.SupplierName,
  SupplierData.BPIsOrganization                                                      as BusinessPartnerIsOrganization,
  SupplierData.IsNaturalPerson                                                       as BusinessPartnerIsNaturalPerson,
  SupplierData.RU_PartnerOrganizationINN,
  SupplierData.RU_PartnerOrganizationKPP,
  SupplierData.RU_PartnerPersonINN,
  SupplierData.FirstName,
  SupplierData.LastName,
  SupplierData.MiddleName,
  SupplierData.AuthorizationGroup,
  coalesce( SupplierOKTMO.RU_TerritoryClassfctnOKTMO, RptgEntityCfg.ParameterValue ) as RU_TerritoryClassfctnOKTMO,

  VatReturnGS.RU_VATReturnVersion,
  VatReturnGS.RU_VATReturnSectionType,
  VatReturnGS.RU_VATReturnSection,
  VatReturnGS.RU_VATReturnLine,
  VatReturnGS.VATReturnItemDescription,
  VatReturnGS.RU_VATSubScenarioVersion,
  VatReturnGS.RU_VATSubScenario,
  VatReturnGS.RU_VATScenario,

  VatReturnGS.SourceDocument,
  VatReturnGS.SourceDocumentFiscalYear,
  VatReturnGS.RevisionNumber,
  VatReturnGS.StatryRptgEntity,
  VatReturnGS.StatryRptCategory,
  VatReturnGS.StatryRptRunID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RU_SUPPLIERDATA",
"P_RU_RPTCATEGORYPARAMONDATE",
"P_RU_SUPLRCUSTACCDOCITEM",
"P_RU_SUPPLIEROKTMOSINGLE",
"P_RU_VATRETURNGENERALSECTION1"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/