P_RTPC_REM_ORDERTOBEPOSTEDKPI

@AbapCatalog.sqlViewName: 'PRTPCREMOTBPK'
@AbapCatalog.compiler.compareFilter: true
//@AbapCatalog.preserveKey:true

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'To be posted Event-Based REM orders KPI'

@VDM.viewType: #COMPOSITE
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
define view P_RTPC_REM_OrderToBePostedKPI
  with parameters
    P_FiscalPeriodStartDate : budat,
    P_FiscalPeriodEndDate   : budat
  as select from           P_RTPC_REM_Order                 as _Order
    left outer to one join P_RTPC_REM_UnsettledActualCost(P_FiscalPeriodStartDate   : $parameters.P_FiscalPeriodStartDate,
                                                          P_FiscalPeriodEndDate     : $parameters.P_FiscalPeriodEndDate
                                                          ) as _Doc on _Doc.OrderID = _Order.OrderID
{
  key _Order.OrderID           as OrderID,
  key _Doc.Ledger              as Ledger,
      _Order.OrderDescription  as OrderDescription,
      _Order.ControllingObject as ControllingObject,
      _Order.ControllingArea   as ControllingArea,
      _Order.CompanyCode       as CompanyCode,
      _Order.OrderType         as OrderType,
      _Order.Material          as Material,
      _Order.Plant             as Plant,
      _Order.OrderCategory     as OrderCategory,
      _Order.ProfitCenter      as ProfitCenter,
      'I0002'                  as StatusCode,
      _Order.ProductionVersion as ProductionVersion,

      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      AmountInGlobalCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      AmountInFreeDefinedCurrency1,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      AmountInFreeDefinedCurrency2,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      AmountInFreeDefinedCurrency3,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      AmountInFreeDefinedCurrency4,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      AmountInFreeDefinedCurrency5,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      AmountInFreeDefinedCurrency6,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      AmountInFreeDefinedCurrency7,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      AmountInFreeDefinedCurrency8,

      CompanyCodeCurrency,
      GlobalCurrency,
      FreeDefinedCurrency1,
      FreeDefinedCurrency2,
      FreeDefinedCurrency3,
      FreeDefinedCurrency4,
      FreeDefinedCurrency5,
      FreeDefinedCurrency6,
      FreeDefinedCurrency7,
      FreeDefinedCurrency8
}
where
       AmountInCompanyCodeCurrency != 0
    or AmountInGlobalCurrency != 0
    or AmountInFreeDefinedCurrency1 != 0
    or AmountInFreeDefinedCurrency2 != 0
    or AmountInFreeDefinedCurrency3 != 0
    or AmountInFreeDefinedCurrency4 != 0
    or AmountInFreeDefinedCurrency5 != 0
    or AmountInFreeDefinedCurrency6 != 0
    or AmountInFreeDefinedCurrency7 != 0
    or AmountInFreeDefinedCurrency8 != 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_RTPC_REM_ORDER",
"P_RTPC_REM_UNSETTLEDACTUALCOST"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/