P_PLANNEDORDERQUICKVIEW
P_PLANNEDORDERQUICKVIEW is a CDS View in S/4HANA. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_PlannedOrderQuickView | view | from | COMPOSITE | Planned Order Data |
@AbapCatalog.sqlViewName: 'PPPPLNDORDER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XL, dataClass: #MASTER}
@VDM.private: true
@VDM.viewType: #BASIC
@AbapCatalog.preserveKey:true
define view P_PlannedOrderQuickView
with parameters
P_MRPElementCategory : delkz
as select from I_PlannedOrder as _PlannedOrder
left outer to one join I_ProductSupplyPlanning as _ProductSupplyPlanning on _PlannedOrder.Material = _ProductSupplyPlanning.Product
and _PlannedOrder.MRPPlant = _ProductSupplyPlanning.Plant
association [0..1] to P_DDMRPController as _MRPCtrlr on $projection.MRPPlant = _MRPCtrlr.Plant
and $projection.MRPController = _MRPCtrlr.MRPController
association [0..1] to I_RoundingPrfText as _RoundingProfile on $projection.RoundingProfile = _RoundingProfile.MaterialRoundingProfile
and $projection.MRPPlant = _RoundingProfile.Plant
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_ProductionVersion as _ProdVersion
on $projection.Material = _ProdVersion.Material
and $projection.MRPPlant = _ProdVersion.Plant
and $projection.ProductionVersion = _ProdVersion.ProductionVersion
{
key PlannedOrder,
Material,
MRPPlant,
FixedSupplier as Supplier,
MaterialProcurementCategory,
//Internal Contact
ProductionSupervisor,
_ProductionSupervisor.ProductionSupervisorName as ProductionSupervisorName,
_PurchasingDocument.PurchasingGroup as PurchasingGroup,
_PurchasingDocument._PurchasingGroup.PurchasingGroupName as PurchasingGroupName,
concat_with_space(_PurchasingDocument._PurchasingGroup.PhoneNumberExtension, _PurchasingDocument._PurchasingGroup.PhoneNumber, 1) as PurchasingGroupPhoneNumber,
_PurchasingDocument._PurchasingGroup.EmailAddress as PurchasingGroupEmailAddress,
MRPController,
_MRPCtrlr.MRPControllerName as MRPControllerName,
_MRPCtrlr.InternalContactName as InternalContactPersonName,
_MRPCtrlr.PhoneNumber as InternalContactPhoneNumber,
_MRPCtrlr.EmailAddress as InternalContactEmailAddress,
// Vendor
_Supplier.SupplierName as SupplierName,
_Supplier.SupplierFullName as SupplierFullName,
_Supplier.PhoneNumber1 as ContactPersonPhoneNumber,
_Supplier._CurrentDfltEmailAddress.EmailAddress as ContactPersonEmailAddress,
//Supplying Plant
case $parameters.P_MRPElementCategory
when 'PA' then ProductionPlant
when 'U3' then MRPPlant
else ''
end as SupplyingPlant,
//Planned Order
MaterialProcurementType,
_MatlProcurementType._Text[1: Language = $session.system_language ].MaterialProcurementTypeName as MaterialProcurementTypeName,
case
when MaterialProcurementCategory = 'F'
then
case
when MaterialProcurementType = '0'
then MaterialProcurementCategory
else MaterialProcurementType
end
else MaterialProcurementCategory
end as ProcurementType,
_MatlProcurementCategory._Text[1: Language = $session.system_language ].MaterialProcurementCatName as MaterialProcurementCatName,
PlannedOrderOpeningDate,
PlndOrderPlannedStartDate,
PlndOrderPlannedEndDate,
MaterialGoodsReceiptDuration,
PlannedTotalQtyInBaseUnit as PlndOrderPlannedTotalQty,
PlannedOrderType,
_PlannedOrderType._Text[1: Language = $session.system_language ].PlannedOrderTypeName as PlannedOrderTypeName,
PlannedScrapQtyInBaseUnit as PlndOrderPlannedScrapQty,
GoodsReceiptQtyInBaseUnit as GoodsReceiptQty,
_PlannedOrder.BaseUnit as BaseUnit,//alias added as Supplyplanning also have BaseUnit now
ProductionPlant,
_ProductionPlant.PlantName as ProductionPlantName,
ProductionVersion,
_ProductionVersion.ProductionVersionText as ProductionVersionText,
_ProdVersion.ProductionLine as ProductionLine,
(PlannedTotalQtyInBaseUnit - PlannedScrapQtyInBaseUnit - GoodsReceiptQtyInBaseUnit) as OpenQuantity,
//Procurement Data
MaterialPlannedDeliveryDurn,
_ProductSupplyPlanning.FixedLotSizeQuantity as FixedLotSizeQuantity,
_ProductSupplyPlanning.MinimumLotSizeQuantity as MinimumLotSizeQuantity,
_ProductSupplyPlanning.MaximumLotSizeQuantity as MaximumLotSizeQuantity,
_ProductSupplyPlanning.LotSizeRoundingQuantity as LotSizeRoundingQuantity,
_ProductSupplyPlanning.RoundingProfile as RoundingProfile,
_RoundingProfile[1: Language = $session.system_language ].MaterialRoundingProfileName as MaterialRoundingProfileName,
_ProductSupplyPlanning.InHouseProductionTime as MaterialPlannedProductionDurn,
_ProductSupplyPlanning.TotalReplenishmentLeadTime as TotalReplenishmentLeadDuration,
//Related Objects
SalesOrder,
SalesOrderItem,
Customer,
_Customer,
_WBSElement.WBSElement as WBSElement
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_MATLPROCUREMENTCATEGORY",
"I_MATLPROCUREMENTCATEGORYTEXT",
"I_MATLPROCUREMENTTYPE",
"I_MATLPROCUREMENTTYPETEXT",
"I_PLANNEDORDER",
"I_PLANNEDORDERTYPE",
"I_PLANNEDORDERTYPETEXT",
"I_PLANT",
"I_PRODUCTIONSUPERVISOR",
"I_PRODUCTIONVERSION",
"I_PRODUCTSUPPLYPLANNING",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGGROUP",
"I_ROUNDINGPRFTEXT",
"I_SUPPLIER",
"I_WBSELEMENTBYINTERNALKEY",
"P_DDMRPCONTROLLER"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_PRODUCTIONVERSION",
"I_ROUNDINGPRFTEXT",
"I_SUPPLIER",
"P_DDMRPCONTROLLER"
],
"BASE":
[
"I_PLANNEDORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/