@AbapCatalog.sqlViewName: 'PPEPDSTA'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view P_PE_PurDmstcSuplrTaxAggrgd
as select from P_PE_PurDmstcSuplrTaxItem as PurchaseTaxItem
{
key PurchaseTaxItem.CompanyCode,
key PurchaseTaxItem.AccountingDocument,
key PurchaseTaxItem.FiscalYear,
PurchaseTaxItem.ReportingDate,
PurchaseTaxItem.ODNDocumentClass,
PurchaseTaxItem.CompanyCodeCurrency,
PurchaseTaxItem.TransactionCurrency,
PurchaseTaxItem.CountryCurrency,
PurchaseTaxItem.ExchangeRateType,
PurchaseTaxItem.ExchangeRateEffectiveDate,
PurchaseTaxItem.PE_OriginalDocumentDate,
PurchaseTaxItem.PE_OriginalDocumentType,
PurchaseTaxItem.PE_OriginalDocumentSeries,
PurchaseTaxItem.PE_OriginalDocumentNumber,
PurchaseTaxItem.FiscalPeriod,
PurchaseTaxItem.Ledger,
PurchaseTaxItem.PE_CompanyCodeTaxNumber,
PurchaseTaxItem.CompanyCodeName,
PurchaseTaxItem.CalendarYearMonth,
PurchaseTaxItem.DocumentNetDueDate,
PurchaseTaxItem.DocumentDate,
PurchaseTaxItem.PE_DocumentSerialNumber,
PurchaseTaxItem.PE_OfficialDocumentNumber,
PurchaseTaxItem.PE_OfficialDocumentType,
PurchaseTaxItem.TaxNumberType,
PurchaseTaxItem.TaxNumber1,
PurchaseTaxItem.SupplierName,
PurchaseTaxItem.ReferenceDocumentFiscalYear,
@Semantics.amount.currencyCode: 'CountryCurrency'
sum( PurchaseTaxItem.TaxBaseAmount ) as TaxBaseAmount,
@Semantics.amount.currencyCode: 'CountryCurrency'
sum( PurchaseTaxItem.TaxAmount ) as TaxAmount,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '5' and PurchaseTaxItem.TaxDeclnAmountType = 'B'
then
abs( PurchaseTaxItem.TaxBaseAmount )
else 0
end )
as fipe_tax_base_taxable_sales) as PE_TxBaseTxblSlsAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '55' and PurchaseTaxItem.TaxDeclnAmountType = 'T'
then
abs( PurchaseTaxItem.TaxAmount )
else 0
end )
as fipe_tax_amount_taxable_sales) as PE_TaxForTxblSlsAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '10' and PurchaseTaxItem.TaxDeclnAmountType = 'B'
then
abs( PurchaseTaxItem.TaxBaseAmount )
else 0
end )
as fipe_tx_base_txbl_nontxbl_sale) as PE_BaseTxblNonAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '60' and PurchaseTaxItem.TaxDeclnAmountType = 'T'
then
abs( PurchaseTaxItem.TaxAmount )
else 0
end )
as fipe_tx_amt_txbl_nontxbl_sale) as PE_TaxTxblNonTxblAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '15' and PurchaseTaxItem.TaxDeclnAmountType = 'B'
then
abs( PurchaseTaxItem.TaxBaseAmount )
else 0
end )
as fipe_tax_base_nontaxable_sales) as PE_TxBaseNonTxblAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '65' and PurchaseTaxItem.TaxDeclnAmountType = 'T'
then
abs( PurchaseTaxItem.TaxAmount )
else 0
end )
as fipe_tax_amt_nontaxable_sales) as PE_TxNonTxblSalesAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '20' and PurchaseTaxItem.TaxDeclnAmountType = 'B'
then
abs( PurchaseTaxItem.TaxBaseAmount )
else 0
end )
as fipe_nontaxable_base_amount) as PE_NonTxblBaseAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '70' and PurchaseTaxItem.TaxDeclnAmountType = 'T'
then
abs( PurchaseTaxItem.TaxAmount )
else 0
end )
as fipe_selective_acqn_amount) as PE_SelectiveAcqnAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '75' and PurchaseTaxItem.TaxDeclnAmountType = 'T'
then
abs( PurchaseTaxItem.TaxAmount )
else 0
end )
as fipe_tax_amount_plastic_bag) as PE_TxOnPlasticBagAmtInCtryCrcy,
@Semantics.amount.currencyCode: 'CountryCurrency'
cast( sum( case
when PurchaseTaxItem.TaxBox = '80' and PurchaseTaxItem.TaxDeclnAmountType = 'T'
then
abs( PurchaseTaxItem.TaxAmount )
when PurchaseTaxItem.TaxBox = '80' and PurchaseTaxItem.TaxDeclnAmountType = 'B'
then
abs( PurchaseTaxItem.TaxBaseAmount )
else 0
end )
as fipe_other_taxes_charges) as PE_OthTxAndChrgsAmtInCtryCrcy
}
group by
PurchaseTaxItem.CompanyCode,
PurchaseTaxItem.AccountingDocument,
PurchaseTaxItem.FiscalYear,
PurchaseTaxItem.ReportingDate,
PurchaseTaxItem.ODNDocumentClass,
PurchaseTaxItem.CompanyCodeCurrency,
PurchaseTaxItem.CountryCurrency,
PurchaseTaxItem.TransactionCurrency,
PurchaseTaxItem.ExchangeRateType,
PurchaseTaxItem.ExchangeRateEffectiveDate,
PurchaseTaxItem.PE_OriginalDocumentDate,
PurchaseTaxItem.PE_OriginalDocumentType,
PurchaseTaxItem.PE_OriginalDocumentSeries,
PurchaseTaxItem.PE_OriginalDocumentNumber,
PurchaseTaxItem.FiscalPeriod,
PurchaseTaxItem.Ledger,
PurchaseTaxItem.PE_CompanyCodeTaxNumber,
PurchaseTaxItem.CompanyCodeName,
PurchaseTaxItem.CalendarYearMonth,
PurchaseTaxItem.DocumentNetDueDate,
PurchaseTaxItem.DocumentDate,
PurchaseTaxItem.PE_DocumentSerialNumber,
PurchaseTaxItem.PE_OfficialDocumentNumber,
PurchaseTaxItem.PE_OfficialDocumentType,
PurchaseTaxItem.TaxNumberType,
PurchaseTaxItem.TaxNumber1,
PurchaseTaxItem.SupplierName,
PurchaseTaxItem.ReferenceDocumentFiscalYear
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_PE_PURDMSTCSUPLRTAXITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/