P_OPERATIONACTIVITYCOMPONENT

@AbapCatalog.sqlViewName: 'PMPEOACOMP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #CUSTOMIZING}
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view P_OperationActivityComponent
  as select from P_OperationActivityCompUnion  as OperationActivityCompUnion
    inner join   I_MatlPlntCompAssembleControl as MfgOrderProductPlant on  OperationActivityCompUnion.Material = MfgOrderProductPlant.Product
                                                                       and OperationActivityCompUnion.Plant    = MfgOrderProductPlant.Plant


  association [0..1] to I_StorageLocation            as _StorageLocation            on  $projection.Plant           = _StorageLocation.Plant
                                                                                    and $projection.StorageLocation = _StorageLocation.StorageLocation
  association [1..1] to I_MatlCompAssembleControl    as _MatlCompAssembleControl    on  $projection.MatlCompAssembleControl = _MatlCompAssembleControl.MatlCompAssembleControl
  association [0..1] to I_BillOfMaterialItemCategory as _BOMItemCategory            on  $projection.BOMItemCategory = _BOMItemCategory.BillOfMaterialItemCategory
  association [0..1] to I_BOMItmMfgRefStrucItmAssgmt as _BOMItmMfgRefStrucItmAssgmt on  $projection.MfgRefStrucBOMLeafAssgmtUUID = _BOMItmMfgRefStrucItmAssgmt.MfgRefStrucBOMLeafAssgmtUUID
  association [0..1] to I_MfgRefStrucItemWithDetails as _MfgRefStrucItemWithDetails on  $projection.MfgRefStructureItemDetailUUID = _MfgRefStrucItemWithDetails.MfgRefStructureItemUUID
                                                                                    and $projection.MfgRefStrucItmDetIsContextual = ''
  association [0..1] to I_MfgRefHierItemWithDetails  as _MfgRefHierItemWithDetails  on  $projection.MfgRefStructureItemDetailUUID = _MfgRefHierItemWithDetails.MfgRefHierarchyItemUUID
                                                                                    and $projection.MfgRefStrucItmDetIsContextual = 'X'
{
  key OperationActivityCompUnion.OpActyNtwkInstance,
  key OperationActivityCompUnion.OpActyNtwkElement,
  key OperationActivityCompUnion.Reservation,
  key OperationActivityCompUnion.ReservationItem,
  key OperationActivityCompUnion.RecordType,
  key cast(OperationActivityCompUnion.Material as mpe_component_matnr preserving type )                           as Material,
  key OperationActivityCompUnion.Plant,           --> Coming from RESB (for planned assemblies) or goods movement (for unplanned assemblies)
      OperationActivityCompUnion.StorageLocation,
      OperationActivityCompUnion.ProductionPlant, --> Coming from AUFK (for planned assemblies only)
      OperationActivityCompUnion.AssemblySequenceNumber,
      OperationActivityCompUnion.BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(round(fltp_to_dec( OperationActivityCompUnion.MfgOrderComponentUsageQuantity as abap.dec(13,4) ), 3)
        as mpe_usage_qty )                                                                                        as MfgOrderComponentUsageQuantity,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(round(fltp_to_dec( OperationActivityCompUnion.RequiredQuantity as abap.dec(13,4) ), 3)
        as co_menge )                                                                                             as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(case OperationActivityCompUnion.MaterialCompIsVariableSized
      -- Variable-size item: Assembly typically has to be done in PC, but base unit e.g. is square meter
          when 'X' then OperationActivityCompUnion.QuantityInEntryUnit
          else OperationActivityCompUnion.MaterialComponentQuantity
        end as mpe_consumed_qty preserving type)                                                                  as MaterialComponentQuantity, --ConsumedQuantity
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast(OperationActivityCompUnion.MaterialComponentQuantity as mpe_consumed_qty_in_base_unit preserving type) as ResvnItmWithdrawnQtyInBaseUnit,
      OperationActivityCompUnion.QuantityInEntryUnit,
      OperationActivityCompUnion.EntryUnit,
      cast( OperationActivityCompUnion.MatlCompIsMarkedForBackflush as boolean preserving type )                  as MatlCompIsMarkedForBackflush,
      OperationActivityCompUnion.IsBulkMaterialComponent,
      OperationActivityCompUnion.GoodsMovementIsAllowed,
      OperationActivityCompUnion.MaterialComponentIsMissing,
      OperationActivityCompUnion.ReservationIsFinallyIssued,
      OperationActivityCompUnion.MatlCompDiscontinuationType,
      -- Variable-Size Item Fields
      OperationActivityCompUnion.MaterialCompIsVariableSized,
      OperationActivityCompUnion.VariableSizeItemUnit,
      OperationActivityCompUnion.FormulaKey,
      OperationActivityCompUnion.VariableSizeDimension1,
      OperationActivityCompUnion.VariableSizeDimension2,
      OperationActivityCompUnion.VariableSizeDimension3,
      OperationActivityCompUnion.VariableSizeDimensionUnit,
      OperationActivityCompUnion.VariableSizeComponentQuantity,
      OperationActivityCompUnion.VariableSizeComponentUnit,
      -- Related / Leading Reservations
      OperationActivityCompUnion.RelatedReservation,
      OperationActivityCompUnion.RelatedReservationItem,
      OperationActivityCompUnion.RelatedRecordType,
      OperationActivityCompUnion.RelatedOpActyNtwkInstance,
      OperationActivityCompUnion.RelatedOpActyNtwkElement,
      OperationActivityCompUnion.LeadingReservation,
      OperationActivityCompUnion.LeadingReservationItem,
      OperationActivityCompUnion.LeadingReservationRecordType,
      OperationActivityCompUnion.LeadingOpActyNtwkInstance,
      OperationActivityCompUnion.LeadingOpActyNtwkElement,
      MfgOrderProductPlant.SerialNumberProfile,
      MfgOrderProductPlant.SerialNumberIsRqdForAssembly,
      MfgOrderProductPlant.StockCheckMessageType,
      MfgOrderProductPlant.IsBatchManagementRequired,
      cast(case
        when OperationActivityCompUnion.MatlCompIsMarkedForBackflush = 'X' then 4
        when OperationActivityCompUnion.IsBulkMaterialComponent = 'X' then 5
        else MfgOrderProductPlant.MatlCompAssembleControl
      end as mpe_comp_assemble_control preserving type )                                                          as MatlCompAssembleControl,
      -- Additional data needed for corresponding association
      OperationActivityCompUnion.BillOfMaterialCategory,
      OperationActivityCompUnion.BillOfMaterial,
      cast( OperationActivityCompUnion.BillOfMaterialInternalID as mpe_exec_stnum preserving type )               as BillOfMaterialInternalID,
      OperationActivityCompUnion.BillOfMaterialVariant,
      OperationActivityCompUnion.BillOfMaterialVersion,
      OperationActivityCompUnion.InheritedBOMItemNode,
      OperationActivityCompUnion.BOMItemCategory,
      OperationActivityCompUnion.BOMItem,
      OperationActivityCompUnion.BOMItemInternalChangeCount,
      OperationActivityCompUnion.BOOOpBOMItemInternalID,
      OperationActivityCompUnion.LogicalComponent,
      OperationActivityCompUnion.MfgRefStrucBOMLeafAssgmtUUID,
      OperationActivityCompUnion.MfgRefStructureItemDetailUUID,
      OperationActivityCompUnion.MfgRefStrucItmDetIsContextual,
      OperationActivityCompUnion.MatlCompInstceAssyIsRequired,

      _StorageLocation,
      _MatlCompAssembleControl,
      _BOMItemCategory,
      _BOMItmMfgRefStrucItmAssgmt,
      _MfgRefStrucItemWithDetails,
      _MfgRefHierItemWithDetails
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATLPLNTCOMPASSEMBLECONTROL",
"P_OPERATIONACTIVITYCOMPUNION"
],
"ASSOCIATED":
[
"I_BILLOFMATERIALITEMCATEGORY",
"I_BOMITMMFGREFSTRUCITMASSGMT",
"I_MATLCOMPASSEMBLECONTROL",
"I_MFGREFHIERITEMWITHDETAILS",
"I_MFGREFSTRUCITEMWITHDETAILS",
"I_STORAGELOCATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/