P_MAINTENANCEPLANCALLDATEBASIC

CDS View

Maintenance Plan Call Date

P_MAINTENANCEPLANCALLDATEBASIC is a CDS View in S/4HANA. Maintenance Plan Call Date. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_MaintenancePlanCallDate view from COMPOSITE Maintenance Plan Call Date 
@AbapCatalog.sqlViewName: 'PMPCALLDATBASIC'
@VDM: {
    viewType: #COMPOSITE,
    private:true
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Maintenance Plan Call Date'
@AbapCatalog.preserveKey:true 
define view P_MaintenancePlanCallDateBasic 
 as select from I_MaintPlanCallHistory
{
  key MaintenancePlan,
      min(MaintenanceCallNextPlannedDate)               as NextScheduledMaintCallDate,
      cast( '00000000' as eams_last_sched_call_date   ) as LastScheduledMaintCallDate,
      cast( '00000000' as eams_next_man_call_date )     as NextManualMaintCallDate,
      cast( '00000000' as eams_last_man_call_date )     as LastManualMaintCallDate
}
where
      MaintenanceCallNextPlannedDate > $session.system_date
  and SchedulingType != 'M'
group by
  MaintenancePlan

union

select from I_MaintPlanCallHistory
{
  key MaintenancePlan,
      cast( '00000000' as eams_next_sched_call_date   ) as NextScheduledMaintCallDate,
      max(MaintenanceCallNextPlannedDate)               as LastScheduledMaintCallDate,
      cast( '00000000' as eams_next_man_call_date )     as NextManualMaintCallDate,
      cast( '00000000' as eams_last_man_call_date )     as LastManualMaintCallDate
}
where
      MaintenanceCallNextPlannedDate <= $session.system_date
  and SchedulingType != 'M'
group by
  MaintenancePlan

union

select from I_MaintPlanCallHistory
{
  key MaintenancePlan,
      cast( '00000000' as eams_next_sched_call_date   ) as NextScheduledMaintCallDate,
      cast( '00000000' as eams_last_sched_call_date   ) as LastScheduledMaintCallDate,
      cast( '00000000' as eams_next_man_call_date )     as NextManualMaintCallDate,
      max(MaintenanceCallNextPlannedDate)               as LastManualMaintCallDate
}
where
      MaintenanceCallNextPlannedDate <= $session.system_date
  and SchedulingType                 = 'M'
group by
  MaintenancePlan

union

select from I_MaintPlanCallHistory
{
  key MaintenancePlan,
      cast( '00000000' as eams_next_sched_call_date   ) as NextScheduledMaintCallDate,
      cast( '00000000' as eams_last_sched_call_date   ) as LastScheduledMaintCallDate,
      min(MaintenanceCallNextPlannedDate)               as NextManualMaintCallDate,
      cast( '00000000' as eams_last_man_call_date )     as LastManualMaintCallDate
}
where
      MaintenanceCallNextPlannedDate > $session.system_date
  and SchedulingType                 = 'M'
group by
  MaintenancePlan;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTPLANCALLHISTORY"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More