P_MAINTENANCESINGLECYCLE

CDS View

P_MAINTENANCESINGLECYCLE is a CDS View in S/4HANA. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_MaintenanceSingleCycleTP view from TRANSACTIONAL Maintenance Single Cycle (Transactional Processing)
P_MaintPlanLastMsmtDoc view from COMPOSITE 
@VDM.private: true
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PMNTSINGLECYCLE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_MaintenanceSingleCycle
  as select from I_MaintenanceCycle
  association [1..1] to I_MaintenancePlan as _MaintenancePlan on _MaintenancePlan.MaintenancePlan = $projection.MaintenancePlan
{
  key MaintenancePlan,

      NumberOfControlTableEntities,

      ComparisonOperator,

      cast ( unit_conversion(
        quantity => MaintPlanCycleIntervalCount,
        source_unit => _UnitOfMeasure._Dimension.UnitOFMeasureSiUnit,
        target_unit => MaintenanceTaskPerformanceUnit,
        error_handling=> 'KEEP_UNCONVERTED'
      ) as abap.dec(22,0) ) as MaintPlanCycleIntervalCount,

      MaintenanceTaskPerformanceUnit,

      MaintPlanCycleDesc,

      Language,

      cast ( unit_conversion(
        quantity => MaintPlanCycleStartOffsetValue,
        source_unit => _UnitOfMeasure._Dimension.UnitOFMeasureSiUnit,
        target_unit => MaintenanceTaskPerformanceUnit,
        error_handling=> 'KEEP_UNCONVERTED'
      ) as abap.dec(22,0) ) as MaintPlanCycleStartOffsetValue,

      MeasuringPoint,

      MaintCycleNextPlndCntrRdng,

      EventSchedulingIsInactive,

      CycleSetSequence,

      CycleSetSequenceRepeatFactor,

      /* Associations - locally defined */
      _MaintenancePlan,

      /* Associations - inherited */
      _Language,
      _MeasuringPoint,
      _UnitOfMeasure
}
where
  _MaintenancePlan.MaintPlanSchedgIndicator <> '4'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCECYCLE",
"I_MAINTENANCEPLAN",
"I_UNITOFMEASURE",
"I_UNITOFMEASUREDIMENSION"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_MAINTENANCEPLAN",
"I_MEASURINGPOINT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_MAINTENANCECYCLE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More