P_FIXEDASSETVALUEWTHDETN
P_FIXEDASSETVALUEWTHDETN is a CDS View in S/4HANA. 3 CDS views read from this table.
CDS Views using this table (3)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| P_FixedAssetValue | view | from | COMPOSITE | |
| P_FixedAssetValueForToFsclPerd | view | from | COMPOSITE | |
| P_FixedAssetValueForToFsclPerd | view | union_all | COMPOSITE |
@AbapCatalog: {sqlViewName: 'PFASSETVALDTN', preserveKey: true}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
define view P_FixedAssetValueWthDetn
with parameters
P_AssetAccountingKeyFigureSet : faa_key_figure_set
as select from I_FixedAssetLineItem as lineitems
left outer join I_AssetKeyFigureTransTypeDetn as determination on determination.AssetAccountingKeyFigureSet = :P_AssetAccountingKeyFigureSet
and determination.AssetTransactionType = lineitems.AssetTransactionType
association [0..1] to I_FixedAssetForLedger as _FixedAssetForLedger on _FixedAssetForLedger.CompanyCode = $projection.CompanyCode
and _FixedAssetForLedger.MasterFixedAsset = $projection.MasterFixedAsset
and _FixedAssetForLedger.FixedAsset = $projection.FixedAsset
and _FixedAssetForLedger.Ledger = $projection.Ledger
{
key lineitems.AssetDepreciationArea,
key lineitems.CompanyCode,
key lineitems.FiscalYear,
key lineitems.MasterFixedAsset,
key lineitems.FixedAsset,
key lineitems.AccountingDocument,
key lineitems.TransactionSubitem,
key lineitems.Ledger,
key lineitems.FiscalPeriod,
key lineitems.SubLedgerAcctLineItemType,
key lineitems.AssetAcctTransClassfctn,
key DebitCreditCode,
LedgerFiscalYear,
FiscalYearVariant,
FiscalYearPeriod,
DepreciationFiscalPeriod,
case when determination.AssetTransactionType is not null
then determination.AssetAcctAnlytlTransClassfctn
else
lineitems.AssetAcctTransClassfctn
end as AssetAcctAnlytlTransClassfctn,
lineitems.LedgerGroup,
lineitems.ChartOfAccounts,
lineitems.CountryChartOfAccounts,
lineitems.GLAccount,
lineitems.AlternativeGLAccount,
lineitems.GroupMasterFixedAsset,
lineitems.GroupFixedAsset,
lineitems.FinancialAccountType,
lineitems.ChartOfDepreciation,
lineitems.AccountingDocumentCreationDate,
lineitems.CreationTime,
lineitems.AccountingDocCreatedByUser,
lineitems.JointVentureCostRecoveryCode,
lineitems.CostCenter,
lineitems.Plant,
lineitems.BusinessArea,
lineitems.PersonnelNumber,
lineitems.FinancialManagementArea,
lineitems.Fund,
lineitems.GrantID,
lineitems.FunctionalArea,
lineitems.BudgetPeriod,
lineitems.ProfitCenter,
lineitems.Segment,
lineitems.FundsCenter,
lineitems.AssetTransactionType,
/* Dedicated properties which moved with the redesign of the asset master from ANLA to FAAT_MD_LD */
/* -> I_FixedAssetForLedger selects based on the business function from the correct table */
_FixedAssetForLedger.AssetDeactivationDate,
lineitems.ReferenceDocumentItem,
lineitems.ReferenceDocumentType,
lineitems.LogicalSystem,
lineitems.ReferenceDocument,
lineitems.ReferenceDocumentContext,
lineitems.ReversalReferenceDocument,
lineitems.ReversalReferenceDocumentCntxt,
lineitems.ReversalTransactionSubitem,
lineitems.IsReversal,
lineitems.IsReversed,
lineitems.DocumentDate,
lineitems.PostingDate,
lineitems.AssetValueDate,
lineitems.AccountingDocumentType,
lineitems.AssignmentReference,
lineitems.DocumentItemText,
lineitems.IsStatisticalDocument,
lineitems.GLBusinessTransactionType,
lineitems.PartnerMasterFixedAsset,
lineitems.PartnerFixedAsset,
@Semantics.currencyCode:true
lineitems.CompanyCodeCurrency,
@Semantics.currencyCode:true
lineitems.GlobalCurrency,
@Semantics.currencyCode:true
lineitems.FreeDefinedCurrency1,
@Semantics.currencyCode:true
lineitems.FreeDefinedCurrency2,
@Semantics.currencyCode:true
lineitems.FreeDefinedCurrency3,
@Semantics.currencyCode:true
lineitems.FreeDefinedCurrency4,
@Semantics.currencyCode:true
lineitems.FreeDefinedCurrency5,
@Semantics.currencyCode:true
lineitems.FreeDefinedCurrency6,
@Semantics.currencyCode:true
lineitems.FreeDefinedCurrency7,
@Semantics.currencyCode:true
lineitems.FreeDefinedCurrency8,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
cast(lineitems.AmountInCompanyCodeCurrency as fins_vhcur12) as ActualAmountInCompanyCodeCrcy,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
cast(lineitems.AmountInGlobalCurrency as fins_vhcur12) as ActualAmountInGlobalCurrency,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
cast(lineitems.AmountInFreeDefinedCurrency1 as fins_vhcur12) as ActualAmountInFreeDfndCrcy1,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
cast(lineitems.AmountInFreeDefinedCurrency2 as fins_vhcur12) as ActualAmountInFreeDfndCrcy2,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
cast(lineitems.AmountInFreeDefinedCurrency3 as fins_vhcur12) as ActualAmountInFreeDfndCrcy3,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
cast(lineitems.AmountInFreeDefinedCurrency4 as fins_vhcur12) as ActualAmountInFreeDfndCrcy4,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
cast(lineitems.AmountInFreeDefinedCurrency5 as fins_vhcur12) as ActualAmountInFreeDfndCrcy5,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
cast(lineitems.AmountInFreeDefinedCurrency6 as fins_vhcur12) as ActualAmountInFreeDfndCrcy6,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
cast(lineitems.AmountInFreeDefinedCurrency7 as fins_vhcur12) as ActualAmountInFreeDfndCrcy7,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
cast(lineitems.AmountInFreeDefinedCurrency8 as fins_vhcur12) as ActualAmountInFreeDfndCrcy8,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
cast('0' as fins_vhcur12) as PlanAmountInCompanyCodeCrcy,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
cast('0' as fins_vhcur12) as PlanAmountInGlobalCurrency,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
cast('0' as fins_vhcur12) as PlanAmountInFreeDefinedCrcy1,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
cast('0' as fins_vhcur12) as PlanAmountInFreeDefinedCrcy2,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
cast('0' as fins_vhcur12) as PlanAmountInFreeDefinedCrcy3,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
cast('0' as fins_vhcur12) as PlanAmountInFreeDefinedCrcy4,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
cast('0' as fins_vhcur12) as PlanAmountInFreeDefinedCrcy5,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
cast('0' as fins_vhcur12) as PlanAmountInFreeDefinedCrcy6,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
cast('0' as fins_vhcur12) as PlanAmountInFreeDefinedCrcy7,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
cast('0' as fins_vhcur12) as PlanAmountInFreeDefinedCrcy8,
@Semantics.unitOfMeasure:true
BaseUnit,
@DefaultAggregation: #SUM
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
Quantity,
cast ('' as boolean) as IsPlanningDocument
}
union all select from I_FixedAssetPlanValue as planvalues
association [0..1] to I_FixedAssetForLedger as _FixedAssetForLedger on _FixedAssetForLedger.CompanyCode = $projection.CompanyCode
and _FixedAssetForLedger.MasterFixedAsset = $projection.MasterFixedAsset
and _FixedAssetForLedger.FixedAsset = $projection.FixedAsset
and _FixedAssetForLedger.Ledger = $projection.Ledger
{
key planvalues.AssetDepreciationArea,
key planvalues.CompanyCode,
key planvalues.FiscalYear,
key planvalues.MasterFixedAsset,
key planvalues.FixedAsset,
key cast('' as belnr_d) as AccountingDocument,
key cast('' as fins_subta) as TransactionSubitem,
key planvalues.Ledger,
key planvalues.FiscalPeriod,
key planvalues.SubLedgerAcctLineItemType,
key planvalues.AssetAcctTransClassfctn,
key cast('' as shkzg) as DebitCreditCode,
cast('0000' as gjahr_pos) as LedgerFiscalYear,
cast('' as periv ) as FiscalYearVariant,
cast('0000000' as jahrper) as FiscalYearPeriod,
planvalues.FiscalPeriod as DepreciationFiscalPeriod,
planvalues.AssetAcctTransClassfctn as AssetAcctAnlytlTransClassfctn,
planvalues.LedgerGroup,
cast('' as ktopl) as ChartOfAccounts,
cast('' as ktop2) as CountryChartOfAccounts,
cast('' as fagl_hkont) as GLAccount,
cast('' as fis_altkt_skb1) as AlternativeGLAccount,
planvalues.GroupMasterFixedAsset,
planvalues.GroupFixedAsset,
planvalues.FinancialAccountType,
planvalues.ChartOfDepreciation,
cast('00000000' as fis_cpudt) as AccountingDocumentCreationDate,
cast('000000' as fis_cputm) as CreationTime,
cast('' as fis_usnam) as AccountingDocCreatedByUser,
planvalues.JointVentureCostRecoveryCode,
cast('' as kostl) as CostCenter,
cast('' as werks_d) as Plant,
cast('' as gsber) as BusinessArea,
cast('' as pernr_d) as PersonnelNumber,
cast('' as fikrs) as FinancialManagementArea,
cast('' as bp_geber) as Fund,
cast('' as gm_grant_nbr) as GrantID,
cast('' as fm_farea) as FunctionalArea,
cast('' as fm_budget_period) as BudgetPeriod,
cast('' as prctr) as ProfitCenter,
cast('' as fb_segment) as Segment,
cast('' as fistl) as FundsCenter,
cast('' as bwasl) as AssetTransactionType,
/* Dedicated properties which moved with the redesign of the asset master from ANLA to FAAT_MD_LD */
/* -> I_FixedAssetForLedger selects based on the business function from the correct table */
_FixedAssetForLedger.AssetDeactivationDate,
cast('' as fins_awitem) as ReferenceDocumentItem,
cast('' as fis_awtyp) as ReferenceDocumentType,
cast('' as awsys) as LogicalSystem,
cast('' as awref) as ReferenceDocument,
cast('' as aworg) as ReferenceDocumentContext,
cast('' as fis_stblg) as ReversalReferenceDocument,
cast('' as aworg_rev) as ReversalReferenceDocumentCntxt,
cast('' as fins_subta_rev) as ReversalTransactionSubitem,
cast('' as fins_xreversing) as IsReversal,
cast('' as fins_xreversed) as IsReversed,
cast('00000000' as bldat) as DocumentDate,
cast('00000000' as budat) as PostingDate,
cast('00000000' as bzdat) as AssetValueDate,
cast('' as fis_blart) as AccountingDocumentType,
cast('' as dzuonr) as AssignmentReference,
cast('' as sgtxt) as DocumentItemText,
cast('' as boolean preserving type) as IsStatisticalDocument,
cast('' as vorgn) as GLBusinessTransactionType,
cast('' as panl1) as PartnerMasterFixedAsset,
cast('' as panl2) as PartnerFixedAsset,
@Semantics.currencyCode:true
planvalues.CompanyCodeCurrency,
@Semantics.currencyCode:true
planvalues.GlobalCurrency,
@Semantics.currencyCode:true
planvalues.FreeDefinedCurrency1,
@Semantics.currencyCode:true
planvalues.FreeDefinedCurrency2,
@Semantics.currencyCode:true
planvalues.FreeDefinedCurrency3,
@Semantics.currencyCode:true
planvalues.FreeDefinedCurrency4,
@Semantics.currencyCode:true
planvalues.FreeDefinedCurrency5,
@Semantics.currencyCode:true
planvalues.FreeDefinedCurrency6,
@Semantics.currencyCode:true
planvalues.FreeDefinedCurrency7,
@Semantics.currencyCode:true
planvalues.FreeDefinedCurrency8,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
cast('0' as fins_vhcur12) as ActualAmountInCompanyCodeCrcy,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
cast('0' as fins_vhcur12) as ActualAmountInGlobalCurrency,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
cast('0' as fins_vhcur12) as ActualAmountInFreeDfndCrcy1,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
cast('0' as fins_vhcur12) as ActualAmountInFreeDfndCrcy2,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
cast('0' as fins_vhcur12) as ActualAmountInFreeDfndCrcy3,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
cast('0' as fins_vhcur12) as ActualAmountInFreeDfndCrcy4,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
cast('0' as fins_vhcur12) as ActualAmountInFreeDfndCrcy5,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
cast('0' as fins_vhcur12) as ActualAmountInFreeDfndCrcy6,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
cast('0' as fins_vhcur12) as ActualAmountInFreeDfndCrcy7,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
cast('0' as fins_vhcur12) as ActualAmountInFreeDfndCrcy8,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
cast(planvalues.AmountInCompanyCodeCurrency as fins_vhcur12) as PlanAmountInCompanyCodeCrcy,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
cast(planvalues.AmountInGlobalCurrency as fins_vhcur12) as PlanAmountInGlobalCurrency,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
cast(planvalues.AmountInFreeDefinedCurrency1 as fins_vhcur12) as PlanAmountInFreeDefinedCrcy1,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
cast(planvalues.AmountInFreeDefinedCurrency2 as fins_vhcur12) as PlanAmountInFreeDefinedCrcy2,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
cast(planvalues.AmountInFreeDefinedCurrency3 as fins_vhcur12) as PlanAmountInFreeDefinedCrcy3,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
cast(planvalues.AmountInFreeDefinedCurrency4 as fins_vhcur12) as PlanAmountInFreeDefinedCrcy4,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
cast(planvalues.AmountInFreeDefinedCurrency5 as fins_vhcur12) as PlanAmountInFreeDefinedCrcy5,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
cast(planvalues.AmountInFreeDefinedCurrency6 as fins_vhcur12) as PlanAmountInFreeDefinedCrcy6,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
cast(planvalues.AmountInFreeDefinedCurrency7 as fins_vhcur12) as PlanAmountInFreeDefinedCrcy7,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
cast(planvalues.AmountInFreeDefinedCurrency8 as fins_vhcur12) as PlanAmountInFreeDefinedCrcy8,
@ObjectModel.foreignKey.association: '_BaseUnit'
@Semantics.unitOfMeasure:true
cast ('' as meins) as BaseUnit,
@DefaultAggregation: #SUM
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
cast (0 as quan1_12) as Quantity,
cast ('X' as boolean) as IsPlanningDocument
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSETKEYFIGURETRANSTYPEDETN",
"I_FIXEDASSETFORLEDGER",
"I_FIXEDASSETLINEITEM",
"I_FIXEDASSETPLANVALUE"
],
"ASSOCIATED":
[
"I_FIXEDASSETFORLEDGER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/