P_FIXEDASSETCOUNTRYDATA

@AbapCatalog: { sqlViewName: 'PFIASTCNTRYDATA', preserveKey: true, compiler.compareFilter: true }
@VDM.viewType: #BASIC
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view P_FixedAssetCountryData
  as select from           anla
    left outer to one join glofaaassetdata                                                 on  glofaaassetdata.bukrs = anla.bukrs
                                                                                           and glofaaassetdata.anln1 = anla.anln1
                                                                                           and glofaaassetdata.anln2 = anla.anln2
    left outer to one join t001                                                            on t001.bukrs = glofaaassetdata.bukrs
    inner join             P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = ''
{
  key anla.bukrs                                             as CompanyCode,
  key anla.anln1                                             as MasterFixedAsset,
  key anla.anln2                                             as FixedAsset,

      glofaaassetdata.glo_natl_clfn_code                     as NationalClassification,
      glofaaassetdata.glo_tax_depr_grp                       as TaxDepreciationGroup,
      t001.land1                                             as Country,
      glofaaassetdata.glo_rus_sernr                          as RU_LongSerialNumber,
      glofaaassetdata.glo_rus_matnr                          as RU_WorkwearMaterial,
      cast('' as glo_ru_retired_asset_number)                as RU_RetiredMasterFixedAsset,
      cast('' as glo_ru_retired_asset_subnumber)             as RU_RetiredFixedAsset,
      glofaaassetdata.glo_rus_trc_begd                       as RU_ProdTraceabilityStartDate,
      glofaaassetdata.glo_rus_trc_endd                       as RU_ProdTraceabilityEndDate,
      glofaaassetdata.glo_rus_trc_tnved                      as RU_AssetTNVED,
      glofaaassetdata.glo_rus_ttx_type                       as RU_AssetTransportType,
      glofaaassetdata.glo_rus_ttx_vin                        as RU_VehicleIdNumber,
      glofaaassetdata.glo_rus_ttx_mnfd                       as RU_ManufacturingDate,
      glofaaassetdata.glo_rus_eco_cls                        as RU_VehicleEcologicalClass,
      glofaaassetdata.glo_rus_prt_addr                       as RU_PropertyAddress,
      glofaaassetdata.glo_rus_ltx_owrd                       as RU_PropertyOwnershipRegnDate,
      glofaaassetdata.glo_rus_ltx_owtd                       as RU_PropertyOwnershipTermnDate,
      glofaaassetdata.glo_jp_ax16_strc                       as JP_Annex16AssetStructure,
      glofaaassetdata.glo_jp_ax16_item                       as JP_Annex16AssetItem,
      cast(anla.lvdat as glo_anx16_lease_agreement_date)     as JP_Annex16LeasingAgrmtDate,
      cast(anla.gdlgrp as glo_jp_city_code)                  as JP_PrptyTxRptCity,
      cast(anla.vmgli  as glo_jp_ptx_classification_key)     as JP_PrptyTxRptClassfctnKey,
      cast(anla.grund as glo_jp_sdc)                         as JP_PrptyTxRptSpclDepr,
      glofaaassetdata.glo_jp_ptx_prdcd                       as JP_PrptyTxRptAddlDepr,
      glofaaassetdata.glo_in_blk_key                         as IN_AssetBlock,
      glofaaassetdata.glo_in_ast_use                         as IN_AssetPutToUseDate,
      glofaaassetdata.glo_in_adnlblk                         as IN_AdditionalAssetBlock,
      glofaaassetdata.glo_in_r_d_asset                       as IN_AssetIsResearchAndDev,
      glofaaassetdata.glo_in_prior_yr                        as IN_AssetIsPriorYear,
      glofaaassetdata.glo_pt_vehicletype                     as PT_VehicleTypeByEnergy,
      glofaaassetdata.glo_pt_isvehiclewolimit                as PT_VehicleIsWithoutLimit,
      glofaaassetdata.glo_pt_repairassetlink                 as PT_BigRepairAssetLink,
      glofaaassetdata.glo_pt_landassetlink                   as PT_LandAssetLink,
      glofaaassetdata.glo_pt_assetrepformcat                 as PT_AssetReportFormCategory,
      glofaaassetdata.glo_pt_isamassetreval                  as PT_AmortizedAssetIsReevaluated,
      cast(anla.internal_code as glo_il_internal_code)       as IL_InvmtCtrInternalCode,
      cast(anla.approval_number as glo_il_approval_number)   as IL_InvmtCtrApprovalDocNmbr,
      cast(anla.approval_version as glo_il_approval_version) as IL_InvmtCtrApprovalVersion,
      cast(anla.bogus_anln1 as glo_il_bogus_anln1)           as IL_InvmtCtrBogusAssetNumber,
      cast(anla.asset_version as glo_il_asset_version)       as IL_InvmtCtrAssetVersion,
      cast('0000' as glo_rs_exclusion_year)                  as RS_GroupDeprExclusionYear,
      cast('00000000' as glo_rs_last_invoice_date)           as RS_AssetLastInvoiceDate
         
}

union all select from    glo_faat_md
  left outer to one join t001                                                            on t001.bukrs = glo_faat_md.comp_code
  inner join             P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = 'X'
{
  key glo_faat_md.comp_code                      as CompanyCode,
  key glo_faat_md.asset_no                       as Masterfixedasset,
  key glo_faat_md.asset_subno                    as FixedAsset,

      glo_faat_md.glo_natl_clfn_code             as NationalClassification,
      glo_faat_md.glo_tax_depr_grp               as TaxDepreciationGroup,
      t001.land1                                 as Country,
      glo_faat_md.glo_rus_sernr                  as RU_LongSerialNumber,
      glo_faat_md.glo_rus_matnr                  as RU_WorkwearMaterial,
      glo_faat_md.glo_rus_ret_asset_num          as RU_RetiredMasterFixedAsset,
      glo_faat_md.glo_rus_ret_asset_sub          as RU_RetiredFixedAsset,
      glo_faat_md.glo_rus_trc_begd               as RU_ProdTraceabilityStartDate,
      glo_faat_md.glo_rus_trc_endd               as RU_ProdTraceabilityEndDate,
      glo_faat_md.glo_rus_trc_tnved              as RU_AssetTNVED,
      glo_faat_md.glo_rus_ttx_type               as RU_AssetTransportType,
      glo_faat_md.glo_rus_ttx_vin                as RU_VehicleIdNumber,
      glo_faat_md.glo_rus_ttx_mnfd               as RU_ManufacturingDate,
      glo_faat_md.glo_rus_eco_cls                as RU_VehicleEcologicalClass,
      glo_faat_md.glo_rus_prt_addr               as RU_PropertyAddress,
      glo_faat_md.glo_rus_prt_owrd               as RU_PropertyOwnershipRegnDate,
      glo_faat_md.glo_rus_prt_owtd               as RU_PropertyOwnershipTermnDate,
      glo_faat_md.glo_jp_ax16_strc               as JP_Annex16AssetStructure,
      glo_faat_md.glo_jp_ax16_item               as JP_Annex16AssetItem,
      glo_faat_md.glo_jp_ax16_lease_agreement_da as JP_Annex16LeasingAgrmtDate,
      glo_faat_md.glo_jp_ptx_city_code           as JP_PrptyTxRptCity,
      glo_faat_md.glo_jp_ptx_classification_key  as JP_PrptyTxRptClassfctnKey,
      glo_faat_md.glo_jp_ptx_special_dep_code    as JP_PrptyTxRptSpclDepr,
      glo_faat_md.glo_jp_ptx_additional_depr_cod as JP_PrptyTxRptAddlDepr,
      glo_faat_md.glo_in_blk_key                 as IN_AssetBlock,
      glo_faat_md.glo_in_ast_use                 as IN_AssetPutToUseDate,
      glo_faat_md.glo_in_adnlblk                 as IN_AdditionalAssetBlock,
      glo_faat_md.glo_in_r_d_asset               as IN_AssetIsResearchAndDev,
      glo_faat_md.glo_in_prior_yr                as IN_AssetIsPriorYear,
      glo_faat_md.glo_pt_vehicletype             as PT_VehicleTypeByEnergy,
      glo_faat_md.glo_pt_isvehiclewolimit        as PT_VehicleIsWithoutLimit,
      glo_faat_md.glo_pt_repairassetlink         as PT_BigRepairAssetLink,
      glo_faat_md.glo_pt_landassetlink           as PT_LandAssetLink,
      glo_faat_md.glo_pt_assetrepformcat         as PT_AssetReportFormCategory,
      glo_faat_md.glo_pt_isamassetreval          as PT_AmortizedAssetIsReevaluated,
      glo_faat_md.glo_il_internal_code           as IL_InvmtCtrInternalCode,
      glo_faat_md.glo_il_approval_number         as IL_InvmtCtrApprovalDocNmbr,
      glo_faat_md.glo_il_approval_version        as IL_InvmtCtrApprovalVersion,
      glo_faat_md.glo_il_bogus_anln1             as IL_InvmtCtrBogusAssetNumber,
      glo_faat_md.glo_il_asset_version           as IL_InvmtCtrAssetVersion,
      glo_faat_md.glo_rs_exclusion_year          as RS_GroupDeprExclusionYear,
      glo_faat_md.glo_rs_last_invoice_date       as RS_AssetLastInvoiceDate   
          
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ANLA",
"GLOFAAASSETDATA",
"GLO_FAAT_MD",
"T001"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/