P_EBOC_WIP1

@AbapCatalog.sqlViewName: 'PEBOCWIP1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true

define view P_EBOC_WIP1
  with parameters
    P_OrderID              : fis_order_number,
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper,
    P_Ledger               : fins_ledger
  as select from I_JournalEntryItem
{
  key CompanyCode,
  key Plant,
  key ControllingArea,
  key cast(GLAccount as fis_racct)      as CostElement,
  key BusinessTransactionCategory,
  key OriginCtrlgDebitCreditCode        as ControllingDebitCreditCode,
  key OriginSenderObject,
  key OrderID,
  key OrderItem,
  key AccountAssignmentType,
  key PartnerAccountAssignment,
  key PartnerAccountAssignmentType,
  key PartnerCostCenter,
  key PartnerCostCtrActivityType,
  key PartnerBusinessProcess,
  key PartnerOrder_2                    as PartnerOrder,
      @Semantics.unitOfMeasure: true
  key cast(BaseUnit as meins)           as UnitOfMeasure,
  key Material,
  key CostOriginGroup,
  key SubLedgerAcctLineItemType,
  key OriginCostCenter,
  key OriginCostCtrActivityType,


      // Actual Amounts from ACDOCA

      sum(AmountInCompanyCodeCurrency)  as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)       as AmountInGlobalCurrency,
      sum(FixedAmountInGlobalCrcy)      as FixedAmountInGlobalCrcy,

      sum(AmountInFreeDefinedCurrency1) as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2) as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3) as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4) as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5) as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6) as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7) as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8) as AmountInFreeDefinedCurrency8,

      sum(Quantity)                     as TotalQuantity
}
where
  (
       SubLedgerAcctLineItemType   =  '09100'
    or SubLedgerAcctLineItemType   =  '09110'
  )
  and  BusinessTransactionCategory =  'EBWP'
  and  Ledger                      =  :P_Ledger
  and  OrderID                     =  :P_OrderID
  and  FiscalYearPeriod            >= :P_FromFiscalYearPeriod
  and  FiscalYearPeriod            <= :P_ToFiscalYearPeriod

group by
  CompanyCode,
  Plant,
  ControllingArea,
  GLAccount,
  BusinessTransactionCategory,
  OriginCtrlgDebitCreditCode,
  OriginSenderObject,
  OrderID,
  OrderItem,
  AccountAssignmentType,
  PartnerAccountAssignment,
  PartnerAccountAssignmentType,
  PartnerCostCenter,
  PartnerCostCtrActivityType,
  PartnerBusinessProcess,
  PartnerOrder_2,
  BaseUnit,
  Material,
  CostOriginGroup,
  SubLedgerAcctLineItemType,
  OriginCostCenter,
  OriginCostCtrActivityType
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRYITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/