P_DDPURCHASEREQUISITION

@AbapCatalog.sqlViewName: 'PDDPURREQDET'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Purchase Requisition Basic Details'

@VDM.viewType: #COMPOSITE
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XL, dataClass: #MASTER}
define view P_DDPurchaseRequisition
  with parameters
    P_MRPElementCategory : delkz
  as select from I_Purchaserequisitionitem
{

  key PurchaseRequisition,
  key PurchaseRequisitionItem,
      Material,
      _Material._Text[1:Language = $session.system_language].MaterialName,
      Plant,

      case $parameters.P_MRPElementCategory
      when 'BA'
      then Plant
      when 'U2'
      then SupplyingPlant
      end                                                                                                      as MRPPlant,

      case $parameters.P_MRPElementCategory
      when 'BA'
      then SupplyingPlant
      when 'U2'
      then Plant
      end                                                                                                      as SupplyingPlant,

      PurchasingDocumentItemCategory                                                                           as MaterialProcurementCategory,
      MRPController,

      PurchasingDocumentCategory,
      PurchaseRequisitionType,

      // Purchasing Related Data

      PurchaseRequisitionIsFixed,
      PurchasingInfoRecord,
      PurchasingOrganization,
      case SupplierMaterialNumber
        when '' then _PurchasingInfoRecord.SupplierMaterialNumber
        else SupplierMaterialNumber
      end                                                                                                      as SupplierMaterialNumber,
      MaterialPlannedDeliveryDurn,
      MaterialGoodsReceiptDuration,
      PurchaseRequisitionReleaseDate                                                                           as ReleaseDate,
      DeliveryDate,
      PurchaseContract                                                                                         as PurchaseOutlineAgreement,
      PurchaseContractItem                                                                                     as PurchaseOutlineAgreementItem,

      // Quantities and UoM

      @Semantics.quantity.unitOfMeasure: 'PurchaseRequisitionUnit'
      @DefaultAggregation: #NONE
      RequestedQuantity                                                                                        as TotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'PurchaseRequisitionUnit'
      @DefaultAggregation: #NONE
      OrderedQuantity,
      @Semantics.quantity.unitOfMeasure: 'PurchaseRequisitionUnit'
      @DefaultAggregation: #NONE
      RequestedQuantity - OrderedQuantity                                                                      as OpenQuantity,
      @Semantics.unitOfMeasure: true
      BaseUnit                                                                                                 as PurchaseRequisitionUnit,

      PurchasingGroup,
      _PurchasingGroup.PurchasingGroupName,
      _PurchasingGroup.PurchasingGroupPhoneNumber,
      _PurchasingGroup.EmailAddress                                                                            as PurchasingGroupEmailAddress,

      case
      when FixedSupplier is not null and FixedSupplier <> ' ' and FixedSupplier <> ''
      then FixedSupplier
      else Supplier
      end                                                                                                      as Supplier,

      FixedSupplier,

      case
      when FixedSupplier = ''
      then ''
      else 'X'
      end                                                                                                      as SupplierIsFixed,
      MaterialOrderUnit                                                                                        as OrderUnit
}
where
  IsDeleted = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALTEXT",
"I_PURCHASEREQUISITIONITEM",
"I_PURCHASINGGROUP",
"I_PURCHASINGINFORECORD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/