P_CADOCUMENTSUMBPITEM

CDS View

Summarized Business Partner Items

P_CADOCUMENTSUMBPITEM is a CDS View in S/4HANA. Summarized Business Partner Items. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CADocumentSumBPItem view_entity from CONSUMPTION Summarized Business Partner Items 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Summarized Business Partner Items'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #P,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}


@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_CADocumentSumBPItem
  as select from I_CADocumentBPItem


  association [0..1] to I_CAClearingReason as _ClearingReason on $projection.CAClearingReason = _ClearingReason.CAClearingReason
{
      @ObjectModel.foreignKey.association: '_DocHeader'
  key CADocumentNumber,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
  key BusinessPartner,
      @ObjectModel.foreignKey.association: '_CAPartner'
  key ContractAccount,
      @ObjectModel.foreignKey.association: '_CompCode'
  key CompanyCode,
  key CAApplicationArea,
      @ObjectModel.foreignKey.association: '_MainTransaction'
  key CAMainTransaction,
      @ObjectModel.foreignKey.association: '_SubTransaction'
  key CASubTransaction,
      @ObjectModel.foreignKey.association: '_Currency'
  key TransactionCurrency,

      @ObjectModel.foreignKey.association: '_ClearingReason'
      cast(max(CAClearingReason) as augrd_kk )             as CAClearingReason,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(sum(CAAmountInTransactionCurrency) as betrw_kk) as CAAmountInTransactionCurrency,

      @EndUserText.label: 'Number'
      count(*)                                             as NumberOfCADocumentBPItems,


      cast(max(CANetDueDate) as faedn_kk)                  as CANetDueDate,

      cast(max(CACashDiscountDueDate) as faeds_kk )        as CACashDiscountDueDate,
      
      cast(max(CABPItemNumber) as opupk_kk ) as CABPItemNumber,
      cast(max(CASubItemNumber) as opupz_kk ) as CASubItemNumber,
      cast(max(CARepetitionItemNumber) as opupw_kk ) as CARepetitionItemNumber,


      //Associations

      _BusinessPartner,
      _CAPartner,
      _MainTransaction,
      _SubTransaction,
      _Currency,
      _ClearingReason,
      _DocHeader,
      _CompCode

}
group by
  CADocumentNumber,
  BusinessPartner,
  ContractAccount,
  CompanyCode,
  CAApplicationArea,
  CAMainTransaction,
  CASubTransaction,
  TransactionCurrency
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CADOCUMENTBPITEM"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CACLEARINGREASON",
"I_CADOCUMENTHEADER",
"I_CAMAINTRANSACTION",
"I_CASUBTRANSACTION",
"I_COMPANYCODE",
"I_CONTRACTACCOUNTPARTNER",
"I_CURRENCY"
],
"BASE":
[
"I_CADOCUMENTBPITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More