P_BSQPMSRVCDOCFLLWUPDOC

CDS View

P_BSQPMSRVCDOCFLLWUPDOC is a CDS View in S/4HANA. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
P_BSQPMSolnQtanItmProcFlw view_entity union COMPOSITE
P_BSQPMSolnQtanProcFlw view_entity union COMPOSITE 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_BSQPMSrvcDocFllwUpDoc
  as select from           I_ServiceDocumentItemEnhcd     as ServiceDocument
    inner join             I_ServiceDocumentItemSuccssr_2 as ServDocItemSuccssr          on ServDocItemSuccssr.ServiceDocumentItemCharUUID = ServiceDocument.ServiceDocumentItemCharUUID
    inner join             I_ServiceDocumentItemEnhcd     as _ServDocSuccssr             on _ServDocSuccssr.ServiceDocumentItemCharUUID = ServDocItemSuccssr.ServiceDocItmSuccssrCharUUID
    left outer to one join I_BusSolutionQuotationType     as BusSolutionQuotationType    on ServiceDocument.ServiceDocumentType = BusSolutionQuotationType.BusSolutionQuotationType
    left outer to one join I_BusSolutionQuotationType     as SucBusSolutionQuotationType on _ServDocSuccssr.ServiceDocumentType = SucBusSolutionQuotationType.BusSolutionQuotationType
    left outer to one join P_BSQPMSrvcDocCatMappg         as ServiceDocCatMapping        on ServiceDocCatMapping.BusinessCategory      = ServiceDocument.ServiceObjectType
                                                                                         and(
                                                                                           ServiceDocCatMapping.ServiceDocumentType    = ServiceDocument.ServiceDocumentType
                                                                                           or ServiceDocCatMapping.ServiceDocumentType is initial
                                                                                         )
    left outer to one join P_BSQPMSrvcDocCatMappg         as SuccessorCatMapping         on SuccessorCatMapping.BusinessCategory      = _ServDocSuccssr.ServiceObjectType
                                                                                         and(
                                                                                           SuccessorCatMapping.ServiceDocumentType    = _ServDocSuccssr.ServiceDocumentType
                                                                                           or SuccessorCatMapping.ServiceDocumentType is initial
                                                                                         )
{

  key ServiceDocument.ServiceDocument     as PrecedingDocument,
  key ServiceDocument.ServiceDocumentItem as PrecedingDocumentItem,
  key _ServDocSuccssr.ServiceDocument     as SubsequentDocument,
  key _ServDocSuccssr.ServiceDocumentItem as SubsequentDocumentItem,
      case
        when BusSolutionQuotationType.BusSolutionQuotationType is null
          then ServiceDocCatMapping.DocumentCategory
        else
          'SQ'
        end                              as PrecedingDocumentCategory,
      case
        when SucBusSolutionQuotationType.BusSolutionQuotationType is null
          then SuccessorCatMapping.DocumentCategory
        else
          'SQ'
        end                           as SubsequentDocumentCategory


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSSOLUTIONQUOTATIONTYPE",
"I_SERVICEDOCUMENTITEMENHCD",
"I_SERVICEDOCUMENTITEMSUCCSSR_2",
"P_BSQPMSRVCDOCCATMAPPG"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More