P_BSAS_BCK

@AbapCatalog.sqlViewName: 'PBSASBCK'
@VDM.viewType: #BASIC
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_BSAS_BCK as select from bsas_bck

  association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
{
  key cast( bukrs as fis_bukrs )                    as CompanyCode,
  key cast( hkont as fis_racct )                    as GLAccount,
  key cast( augdt as fis_augdt )                    as ClearingDate,
  key cast( augbl as farp_augbl preserving type )   as ClearingJournalEntry,
  key cast( zuonr as fis_zuonr )                    as AssignmentReference,
  key cast( gjahr as fis_gjahr )                    as FiscalYear,
  key cast( belnr as farp_belnr_d )                 as AccountingDocument,
  key cast( buzei as fis_buzei )                    as AccountingDocumentItem,
  
  cast( auggj as fis_auggj_no_conv preserving type )                       as ClearingJournalEntryFiscalYear,
  cast( blart as farp_blart )       as AccountingDocumentType,
  cast( bldat as fis_bldat )        as DocumentDate,
  cast( budat as fis_budat )        as PostingDate,
  cast( sgtxt as farp_sgtxt )       as DocumentItemText,
  cast( bstat as fis_bstat)         as AccountingDocumentCategory,
  cast( waers as fis_rwcur )        as TransactionCurrency,
  buzid                             as AccountingDocumentItemType,
  rfzei                             as PaymentCardItem,
  cast(case shkzg
          when 'H' then cast(-dmbtr as abap.curr(23,2))
          else          cast( dmbtr as abap.curr(23,2))
          end as fis_hsl) 
                                    as AmountInCompanyCodeCurrency,                            
   cast(case shkzg  
               when 'H' then   cast(-dmbe2 as abap.curr( 23,2))
               when 'S' then   cast( dmbe2 as abap.curr( 23,2))
               else cast( dmbe2 as abap.curr( 23,2))
        end as fis_dmbe2)                                                  as AmountInAdditionalCurrency1,
        
   cast(case shkzg  
               when 'H' then   cast(-dmbe3 as abap.curr( 23,2))
               when 'S' then   cast( dmbe3 as abap.curr( 23,2))
               else cast( dmbe3 as abap.curr( 23,2))
        end as fis_dmbe3)                                                  as AmountInAdditionalCurrency2,
                                          
  _CompanyCode
}
where xarch = 'X' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BSAS_BCK"
],
"ASSOCIATED":
[
"I_COMPANYCODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/