P_ASSETCLASS

CDS View

P_ASSETCLASS is a CDS View in S/4HANA. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_AssetClass view from BASIC Asset Class 
@AbapCatalog: { sqlViewName: 'PFIASSETCL', preserveKey: true, compiler.compareFilter: true }
@VDM.viewType: #BASIC
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view P_AssetClass
  as select from anka
    inner join   P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = ''
{
  key anlkl                            as AssetClass,
  
      ktogr                            as AssetAccountDetermination,
      gsber                            as BusinessArea,
      werks                            as Plant,
      kostl                            as CostCenter,
      aneqs                            as FixedAssetFinDataCmpltns,
      land1                            as AssetCountryOfOrigin,
      lifnr                            as Supplier,
      anlue                            as FixedAssetGroup,
      eigkz                            as FixedAssetPropertyType,
      vmgli                            as PropertyClass,
      invsl                            as InvestmentSupportMeasure,
      ord41                            as Group1AssetEvaluationKey,
      ord42                            as Group2AssetEvaluationKey,
      ord43                            as Group3AssetEvaluationKey,
      ord44                            as Group4AssetEvaluationKey,
      izwek                            as InvestmentReason,
      cast('CLASSIC' as faa_authcntxt) as AssetAuthorizationContext
}

union all select from faac_acls0
  inner join          P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = 'X'
{
  key asset_class                  as AssetClass,
  
      gl_account_det               as AssetAccountDetermination,
      cast('' as gsber)            as BusinessArea,
      cast('' as werks_d)          as Plant,
      cast('' as kostl)            as CostCenter,
      cast('' as aneqs)            as FixedAssetFinDataCmpltns,
      cast('' as am_land1)         as AssetCountryOfOrigin,
      cast('' as am_lifnr)         as Supplier,
      cast('' as anlue)            as FixedAssetGroup,
      cast('' as eigkz)            as FixedAssetPropertyType,
      cast('' as vmgli)            as PropertyClass,
      cast('' as invsl)            as InvestmentSupportMeasure,
      cast('' as ord41)            as Group1AssetEvaluationKey,
      cast('' as ord42)            as Group2AssetEvaluationKey,
      cast('' as ord43)            as Group3AssetEvaluationKey,
      cast('' as ord44)            as Group4AssetEvaluationKey,
      cast('' as izwek)            as InvestmentReason,
      cast('NEW' as faa_authcntxt) as AssetAuthorizationContext
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ANKA",
"FAAC_ACLS0"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More