P_AR_PURCHASETAXITEMAGGRGD

@AbapCatalog.sqlViewName: 'PARPURTXITMAGG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_AR_PurchaseTaxItemAggrgd
  with parameters
    P_AccrualCalculationMethod : fiar_vat_compcredit,
    P_RptgAmountIsInTransCrcy  : fiar_use_transaction_currency
  as select from P_AR_PurTxItmAggrgdByTxCode ( P_AccrualCalculationMethod : $parameters.P_AccrualCalculationMethod,
                                         P_RptgAmountIsInTransCrcy  : $parameters.P_RptgAmountIsInTransCrcy ) as PurTxItmAggrgdByTxCode

     inner join P_AR_PurchaseNumberOfVATRates as PurchaseNumberOfVATRates on  PurTxItmAggrgdByTxCode.CompanyCode        = PurchaseNumberOfVATRates.CompanyCode
                                                                          and PurTxItmAggrgdByTxCode.AccountingDocument = PurchaseNumberOfVATRates.AccountingDocument
                                                                          and PurTxItmAggrgdByTxCode.FiscalYear         = PurchaseNumberOfVATRates.FiscalYear

{
  key PurTxItmAggrgdByTxCode.CompanyCode,
  key PurTxItmAggrgdByTxCode.FiscalYear,
  key PurTxItmAggrgdByTxCode.AccountingDocument,

      PurTxItmAggrgdByTxCode.CompanyCodeCountry,
      PurTxItmAggrgdByTxCode.FiscalPeriod,
      PurTxItmAggrgdByTxCode.DocumentDate,
      PurTxItmAggrgdByTxCode.PostingDate,
      PurTxItmAggrgdByTxCode.ReportingDate,
      PurTxItmAggrgdByTxCode.IsReversal,
      PurTxItmAggrgdByTxCode.IsReversed,
      PurTxItmAggrgdByTxCode.ReverseDocument,
      PurTxItmAggrgdByTxCode.ReversalReferenceDocument,
      PurTxItmAggrgdByTxCode.OriginalReferenceDocument,
      PurTxItmAggrgdByTxCode.ReferenceDocumentType,
      PurTxItmAggrgdByTxCode.DocumentReferenceID,
      PurTxItmAggrgdByTxCode.AccountingDocumentType,
      PurTxItmAggrgdByTxCode.AR_OfficialDocumentType,
      PurTxItmAggrgdByTxCode.AR_OfficialDocumentClass,
      PurTxItmAggrgdByTxCode.AR_Branch,
      PurTxItmAggrgdByTxCode.AR_PrintCharacter,
      PurTxItmAggrgdByTxCode.AR_OfficialDocumentNumber,

      PurTxItmAggrgdByTxCode.AccountingDocumentHeaderText,

      PurTxItmAggrgdByTxCode.ExchangeRateDate,
      PurTxItmAggrgdByTxCode.ExchangeRate,

      @Semantics.currencyCode:true
      PurTxItmAggrgdByTxCode.CompanyCodeCurrency,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.TaxAmountInCoCodeCrcy ) as glo_taxamount_incompcodecrcy preserving type
      )                                    as TaxAmountInCoCodeCrcy,

      @Semantics.currencyCode:true
      PurTxItmAggrgdByTxCode.TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.TaxAmountInTransCrcy ) as fiar_taxamount_in_trans_crcy preserving type
      )                                    as TaxAmountInTransCrcy,

      @Semantics.currencyCode:true
      PurTxItmAggrgdByTxCode.ReportingCurrency,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.TaxAmountInRptgCrcy ) as glo_tax_amount_rptg_crcy preserving type
      )                                    as TaxAmountInRptgCrcy,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.TaxBaseAmountInRptgCrcy ) as glo_taxbase_amount_rptg_crcy preserving type
      )                                    as TaxBaseAmountInRptgCrcy,

      PurTxItmAggrgdByTxCode.IsDocumentBOrCAndNotDocType33,

      PurchaseNumberOfVATRates.NmbrOfVATRates,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.TaxBaseAmountInCoCodeCrcy ) as hwbas_shl preserving type
      )                                    as TaxBaseAmountInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.TaxBaseAmountInTransCrcy ) as glo_taxbase_amount_trans_crcy preserving type
      )                                    as TaxBaseAmountInTransCrcy,

      min( PurTxItmAggrgdByTxCode.AR_LowestPriorityOfZeroVATRsn ) as AR_LowestPriorityOfZeroVATRsn,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.NotTaxedAmount ) as fi_ar_nottax_amnt preserving type
      )                                    as NotTaxedAmount,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.TaxExemptionAmount ) as fiar_exempted_amount preserving type
      )                                    as TaxExemptionAmount,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      sum( PurTxItmAggrgdByTxCode.TotalCreditAmountInTransCrcy )  as TotalCreditAmountInTransCrcy,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      sum( PurTxItmAggrgdByTxCode.ForeignTaxAmount )              as ForeignTaxAmount,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.GrossIncomeTaxAmount ) as fiar_provincial_tax_amount preserving type
      )                                    as GrossIncomeTaxAmount,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.MunicipalTaxAmount ) as fi_ar_mptax_amnt preserving type
      )                                    as MunicipalTaxAmount,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      sum( PurTxItmAggrgdByTxCode.OpenTotalTaxAmount )            as OpenTotalTaxAmount,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      sum( PurTxItmAggrgdByTxCode.CalculatedTxAmtInCoCodeCrcy )   as CalculatedTxAmtInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        sum( PurTxItmAggrgdByTxCode.OtherTaxAmount ) as fiar_other_tax_amount preserving type
      )                                    as OtherTaxAmount,

      PurTxItmAggrgdByTxCode._OneTimeAccountBP
}
group by
  PurTxItmAggrgdByTxCode.CompanyCode,
  PurTxItmAggrgdByTxCode.FiscalYear,
  PurTxItmAggrgdByTxCode.AccountingDocument,
  PurTxItmAggrgdByTxCode.CompanyCodeCountry,
  PurTxItmAggrgdByTxCode.FiscalPeriod,
  PurTxItmAggrgdByTxCode.DocumentDate,
  PurTxItmAggrgdByTxCode.PostingDate,
  PurTxItmAggrgdByTxCode.ReportingDate,
  PurTxItmAggrgdByTxCode.IsReversal,
  PurTxItmAggrgdByTxCode.IsReversed,
  PurTxItmAggrgdByTxCode.ReverseDocument,
  PurTxItmAggrgdByTxCode.ReversalReferenceDocument,
  PurTxItmAggrgdByTxCode.OriginalReferenceDocument,
  PurTxItmAggrgdByTxCode.ReferenceDocumentType,
  PurTxItmAggrgdByTxCode.DocumentReferenceID,
  PurTxItmAggrgdByTxCode.AccountingDocumentType,
  PurTxItmAggrgdByTxCode.AR_OfficialDocumentType,
  PurTxItmAggrgdByTxCode.AR_OfficialDocumentClass,
  PurTxItmAggrgdByTxCode.AR_Branch,
  PurTxItmAggrgdByTxCode.AR_PrintCharacter,
  PurTxItmAggrgdByTxCode.AR_OfficialDocumentNumber,
  PurTxItmAggrgdByTxCode.ExchangeRateDate,
  PurTxItmAggrgdByTxCode.ExchangeRate,
  PurTxItmAggrgdByTxCode.CompanyCodeCurrency,
  PurTxItmAggrgdByTxCode.TransactionCurrency,
  PurTxItmAggrgdByTxCode.ReportingCurrency,
  PurTxItmAggrgdByTxCode.AccountingDocumentHeaderText,
  PurTxItmAggrgdByTxCode.IsDocumentBOrCAndNotDocType33,

  PurchaseNumberOfVATRates.NmbrOfVATRates
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_AR_PURCHASENUMBEROFVATRATES",
"P_AR_PURTXITMAGGRGDBYTXCODE"
],
"ASSOCIATED":
[
"I_ONETIMEACCOUNTBP"
],
"BASE":
[
"P_AR_PURTXITMAGGRGDBYTXCODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/