I_WORKFLOWREUSESTEP

CDS View

Exposes workflow scenario reusable steps

I_WORKFLOWREUSESTEP is a CDS View in S/4HANA. Exposes workflow scenario reusable steps. It contains 1 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 1 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_WorkflowStepType view from COMPOSITE Workflow Step Type
I_WorkflowStepTypeNode view from COMPOSITE Exposes reusable step type nodes

Fields (1)

KeyField CDS FieldsUsed in Views
KEY WorkflowStepType WorkflowStepType 1 
@AbapCatalog.sqlViewName: 'IWRKFLWRUSTP'
@EndUserText.label: 'Exposes workflow scenario reusable steps'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType : {
  dataClass: #META,
  sizeCategory: #M,
  serviceQuality: #B
}

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_WorkflowReuseStep
  as select from    swd_flxruse as WorkflowReuseStep
    left outer join swd_steps   as WorkflowStep on  WorkflowReuseStep.wfd_id        = WorkflowStep.wfd_id
                                                and WorkflowReuseStep.version       = WorkflowStep.version
                                                and WorkflowReuseStep.exetyp        = WorkflowStep.exetyp
                                                and WorkflowReuseStep.ruse_keyvalue = WorkflowStep.nodeid
  association [0..*] to I_WorkflowStepTypeText    as _WorkflowTaskStepTypeText  on  $projection.WrkflwScen       = _WorkflowTaskStepTypeText.WrkflwScen
                                                                                and $projection.WrkflwScenVers   = _WorkflowTaskStepTypeText.WrkflwScenVers
                                                                                and $projection.WorkflowStepType = _WorkflowTaskStepTypeText.WorkflowStepType
  association [0..*] to I_WorkflowStepResult      as _WorkflowTaskStepResult    on  $projection.WrkflwScen       = _WorkflowTaskStepResult.WorkflowScenarioDefinition
                                                                                and $projection.WrkflwScenVers   = _WorkflowTaskStepResult.WorkflowScenarioDefinitionVers
                                                                                and $projection.WorkflowStepType = _WorkflowTaskStepResult.WorkflowStepType
  association [0..1] to I_WrkflwStepTypeClassfctn as _WorkflowStepTypeClassfctn on  $projection.WorkflowStepTypeClassfctn = _WorkflowStepTypeClassfctn.WorkflowStepTypeClassfctn
{
  key WorkflowReuseStep.wfd_id        as WrkflwScen,
  key WorkflowReuseStep.version       as WrkflwScenVers,
  key WorkflowReuseStep.ruse_label    as WorkflowStepType,
      WorkflowReuseStep.ruse_keyvalue as WorkflowStepNodeId,
      case
        when WorkflowStep.batch_task = 'X'
            then 'YES'
            else 'NO'
      end                             as WorkflowStepIsSystemTask,
      WorkflowStep.classification     as WorkflowStepTypeClassfctn,

      _WorkflowTaskStepTypeText,
      _WorkflowTaskStepResult,
      _WorkflowStepTypeClassfctn
}
where
      WorkflowReuseStep.ruse_type  = 'STEP'
  and WorkflowReuseStep.ruse_stype = 'WF'
  and WorkflowReuseStep.nodeid     = '0000000002'
  and WorkflowReuseStep.exetyp     = 'E'
  and WorkflowReuseStep.version    < '9999'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"SWD_FLXRUSE",
"SWD_STEPS"
],
"ASSOCIATED":
[
"I_WORKFLOWSTEPRESULT",
"I_WORKFLOWSTEPTYPETEXT",
"I_WRKFLWSTEPTYPECLASSFCTN"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More