I_WORKPACKAGEALL
All Work Package
I_WORKPACKAGEALL is a CDS View in S/4HANA. All Work Package. It contains 7 fields. 3 CDS views read from this table.
CDS Views using this table (3)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_EngmntProjTmeExpnBillgCube | view | left_outer | COMPOSITE | Tme and Expn Cap in Engmnt Proj - Cube |
| I_WorkPackageAllStdVH | view | from | COMPOSITE | All Work Package |
| P_EngmntProjReviewData | view | left_outer | COMPOSITE |
Fields (7)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| IsDeleted | IsDeleted | 1 | |
| SalesOrder | SalesOrder | 2 | |
| SalesOrderItem | SalesOrderItem | 2 | |
| WorkPackageEndDate | WorkPackageEndDate | 1 | |
| WorkPackageName | WorkPackageName | 1 | |
| WorkPackageStartDate | WorkPackageStartDate | 1 | |
| WorkPackageType | WorkPackageType | 1 |
@EndUserText.label: 'All Work Package'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'WorkPackage'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IWORKPCKGALL'
@Metadata.allowExtensions: true
define view I_WorkPackageAll
as select from /cpd/d_pfp_ps as WorkPackage
association [1] to I_EngagementProjFinancialPlan as _EngagementProjFinancialPlan on $projection.EngagementProjFinPlanUUID = _EngagementProjFinancialPlan.EngagementProjFinPlanUUID
association [0..1] to I_WBSElementBasicData as _WBSElement on $projection.WBSElementObject = _WBSElement.WBSElementObject
association [0..1] to I_SalesOrder as _SalesOrder on $projection.SalesOrder = _SalesOrder.SalesOrder
association [0..1] to I_SalesOrderItem as _SalesOrderItem on $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
and $projection.SalesOrder = _SalesOrderItem.SalesOrder
association [0..*] to I_EngmntProjectPlnDataVersion as _EngagementProjectPlanData on $projection.EngagementProjFinPlanUUID = _EngagementProjectPlanData.EngagementProjFinPlanUUID
and $projection.WorkPackage = _EngagementProjectPlanData.WorkPackage
association [0..*] to I_WorkPackageWorkItemAll as _WorkPackageWorkItem on $projection.WorkPackage = _WorkPackageWorkItem.WorkPackage
and $projection.EngagementProjFinPlanUUID = _WorkPackageWorkItem.EngagementProjFinPlanUUID
// association [0..1] to E_Workpackage as _Extension on $projection.WorkPackageUUID = _Extension.WorkPackageUUID
association [1..1] to I_EngmntProjAssgmtToSessionUsr as _EngagementProject on _EngagementProjFinancialPlan.EngagementProjectUUID = _EngagementProject.EngagementProjectUUID
{
@ObjectModel.text.element: 'WorkPackageName'
key WorkPackage.plan_item_id as WorkPackage,
cast( WorkPackage.db_key as /cpd/wp_db_key preserving type ) as WorkPackageUUID,
cast(WorkPackage.parent_key as /cpd/eng_pfp_db_key preserving type ) as EngagementProjFinPlanUUID,
@Semantics.text: true
WorkPackage.plan_item_name as WorkPackageName,
WorkPackage.start_date as WorkPackageStartDate,
WorkPackage.end_date as WorkPackageEndDate,
WorkPackage.mapped_item_id as WBSElementObject,
WorkPackage.mapped_item_desc as WBSDescription,
@ObjectModel.foreignKey.association: '_SalesOrder'
WorkPackage.sales_order_hdr as SalesOrder,
@ObjectModel.foreignKey.association: '_SalesOrderItem'
WorkPackage.so_item_id as SalesOrderItem,
WorkPackage.changed_by as LastChangedByUser,
@Semantics.dateTime:true
@Semantics.systemDateTime.lastChangedAt:true
cast( WorkPackage.changed_on as /cpd/cpm_changedon ) as LastChangeDateTime,
WorkPackage.is_deleted as IsDeleted,
WorkPackage.plan_item_type as WorkPackageType,
_EngagementProjFinancialPlan.EngagementProjectUUID,
/* Associations */
_EngagementProjFinancialPlan,
_EngagementProjectPlanData,
_EngagementProject,
_WBSElement,
_SalesOrder,
_SalesOrderItem,
_WorkPackageWorkItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENGAGEMENTPROJFINANCIALPLAN",
"/CPD/D_PFP_PS"
],
"ASSOCIATED":
[
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_ENGMNTPROJASSGMTTOSESSIONUSR",
"I_ENGMNTPROJECTPLNDATAVERSION",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_WBSELEMENTBASICDATA",
"I_WORKPACKAGEWORKITEMALL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/